1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
|
SUBROUTINE DTIMQ3( LINE, NM, MVAL, NVAL, NNB, NBVAL, NXVAL, NLDA,
$ LDAVAL, TIMMIN, A, COPYA, TAU, WORK, IWORK,
$ RESLTS, LDR1, LDR2, NOUT )
*
* -- LAPACK timing routine (version 3.0) --
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
* Courant Institute, Argonne National Lab, and Rice University
* December 22, 1999
*
* Rewritten to time qp3 code.
*
* .. Scalar Arguments ..
CHARACTER*80 LINE
INTEGER LDR1, LDR2, NLDA, NM, NNB, NOUT
DOUBLE PRECISION TIMMIN
* ..
* .. Array Arguments ..
INTEGER IWORK( * ), LDAVAL( * ), MVAL( * ), NBVAL( * ),
$ NVAL( * ), NXVAL( * )
DOUBLE PRECISION A( * ), COPYA( * ), RESLTS( LDR1, LDR2, * ),
$ TAU( * ), WORK( * )
* ..
*
* Purpose
* =======
*
* DTIMQ3 times the routines to perform the Rank-Revealing QR
* factorization of a DOUBLE PRECISION general matrix.
*
* Two matrix types may be used for timing. The number of types is
* set in the parameter NMODE and the matrix types are set in the vector
* MODES, using the following key:
* 2. BREAK1 D(1:N-1)=1 and D(N)=1.0/COND in DLATMS
* 3. GEOM D(I)=COND**(-(I-1)/(N-1)) in DLATMS
* These numbers are chosen to correspond with the matrix types in the
* test code.
*
* Arguments
* =========
*
* LINE (input) CHARACTER*80
* The input line that requested this routine. The first six
* characters contain either the name of a subroutine or a
* generic path name. The remaining characters may be used to
* specify the individual routines to be timed. See ATIMIN for
* a full description of the format of the input line.
*
* NM (input) INTEGER
* The number of values of M and N contained in the vectors
* MVAL and NVAL. The matrix sizes are used in pairs (M,N).
*
* MVAL (input) INTEGER array, dimension (NM)
* The values of the matrix row dimension M.
*
* NVAL (input) INTEGER array, dimension (NM)
* The values of the matrix column dimension N.
*
* NNB (input) INTEGER
* The number of values of NB and NX contained in the
* vectors NBVAL and NXVAL. The blocking parameters are used
* in pairs (NB,NX).
*
* NBVAL (input) INTEGER array, dimension (NNB)
* The values of the blocksize NB.
*
* NXVAL (input) INTEGER array, dimension (NNB)
* The values of the crossover point NX.
*
* NLDA (input) INTEGER
* The number of values of LDA contained in the vector LDAVAL.
*
* LDAVAL (input) INTEGER array, dimension (NLDA)
* The values of the leading dimension of the array A.
*
* TIMMIN (input) DOUBLE PRECISION
* The minimum time a subroutine will be timed.
*
* A (workspace) DOUBLE PRECISION array, dimension (LDAMAX*NMAX)
* where LDAMAX and NMAX are the maximum values of LDA and N.
*
* COPYA (workspace) DOUBLE PRECISION array, dimension (LDAMAX*NMAX)
*
* TAU (workspace) DOUBLE PRECISION array, dimension (MINMN)
*
* WORK (workspace) DOUBLE PRECISION array, dimension (3*NMAX)
*
* IWORK (workspace) INTEGER array, dimension (2*NMAX)
*
* RESLTS (workspace) DOUBLE PRECISION array, dimension
* (LDR1,LDR2,NLDA)
* The timing results for each subroutine over the relevant
* values of MODE, (M,N), and LDA.
*
* LDR1 (input) INTEGER
* The first dimension of RESLTS. LDR1 >= max(1,NM).
*
* LDR2 (input) INTEGER
* The second dimension of RESLTS. LDR2 >= max(1,NM).
*
* NOUT (input) INTEGER
* The unit number for output.
*
* =====================================================================
*
* .. Parameters ..
*
*
INTEGER NSUBS, NMODE
PARAMETER ( NSUBS = 1, NMODE = 2 )
DOUBLE PRECISION ONE
PARAMETER ( ONE = 1.0D+0 )
* ..
* .. Local Scalars ..
CHARACTER*3 PATH
CHARACTER*6 CNAME
INTEGER I, IC, ICL, ILDA, IM, IMODE, INB, INFO, LDA,
$ LW, M, MINMN, MODE, N, NB, NX
DOUBLE PRECISION COND, DMAX, OPS, S1, S2, TIME, UNTIME
* ..
* .. Local Arrays ..
LOGICAL TIMSUB( NSUBS )
CHARACTER*6 SUBNAM( NSUBS )
INTEGER ISEED( 4 ), MODES( NMODE )
* ..
* .. External Functions ..
DOUBLE PRECISION DLAMCH, DMFLOP, DOPLA, DSECND
EXTERNAL DLAMCH, DMFLOP, DOPLA, DSECND
* ..
* .. External Subroutines ..
EXTERNAL ATIMCK, ATIMIN, DGEQP3, DLACPY, DLATMS, DPRTB4,
$ ICOPY, XLAENV
* ..
* .. Intrinsic Functions ..
INTRINSIC DBLE, MAX, MIN
* ..
* .. Data statements ..
DATA SUBNAM / 'DGEQP3' /
DATA MODES / 2, 3 /
DATA ISEED / 0, 0, 0, 1 /
* ..
* .. Executable Statements ..
*
* Extract the timing request from the input line.
*
PATH( 1: 1 ) = 'Double precision'
PATH( 2: 3 ) = 'QP'
CALL ATIMIN( PATH, LINE, NSUBS, SUBNAM, TIMSUB, NOUT, INFO )
IF( .NOT.TIMSUB( 1 ) .OR. INFO.NE.0 )
$ GO TO 90
*
* Check that M <= LDA for the input values.
*
CNAME = LINE( 1: 6 )
CALL ATIMCK( 1, CNAME, NM, MVAL, NLDA, LDAVAL, NOUT, INFO )
IF( INFO.GT.0 ) THEN
WRITE( NOUT, FMT = 9996 )CNAME
GO TO 90
END IF
*
* Set the condition number and scaling factor for the matrices
* to be generated.
*
DMAX = ONE
COND = ONE / DLAMCH( 'Precision' )
*
* Do for each type of matrix:
*
DO 80 IMODE = 1, NMODE
MODE = MODES( IMODE )
*
*
* *****************
* * Timing xGEQP3 *
* *****************
*
* Do for each value of LDA:
*
DO 60 ILDA = 1, NLDA
LDA = LDAVAL( ILDA )
*
* Do for each pair of values (M,N):
*
DO 50 IM = 1, NM
M = MVAL( IM )
N = NVAL( IM )
MINMN = MIN( M, N )
*
* Generate a test matrix of size m by n using the
* singular value distribution indicated by MODE.
*
CALL DLATMS( M, N, 'Uniform', ISEED, 'Nonsymm', TAU,
$ MODE, COND, DMAX, M, N, 'No packing', COPYA,
$ LDA, WORK, INFO )
*
* Do for each pair of values (NB,NX) in NBVAL and NXVAL:
*
DO 40 INB = 1, NNB
NB = NBVAL( INB )
CALL XLAENV( 1, NB )
NX = NXVAL( INB )
CALL XLAENV( 3, NX )
*
*
* DGEQP3
*
LW = MAX( 1, 2*N+( N+1 )*NB )
DO 10 I = 1, N
IWORK( N+I ) = 0
10 CONTINUE
*
CALL DLACPY( 'All', M, N, COPYA, LDA, A, LDA )
CALL ICOPY( N, IWORK( N+1 ), 1, IWORK, 1 )
IC = 0
S1 = DSECND( )
20 CONTINUE
CALL DGEQP3( M, N, A, LDA, IWORK, TAU, WORK, LW,
$ INFO )
S2 = DSECND( )
*
IF( INFO.NE.0 ) THEN
WRITE( *, FMT = * )'>>>Warning: INFO returned by ',
$ 'DGEQPX is:', INFO
INFO = 0
END IF
*
TIME = S2 - S1
IC = IC + 1
IF( TIME.LT.TIMMIN ) THEN
CALL DLACPY( 'All', M, N, COPYA, LDA, A, LDA )
CALL ICOPY( N, IWORK( N+1 ), 1, IWORK, 1 )
GO TO 20
END IF
*
* Subtract the time used in DLACPY.
*
ICL = 1
S1 = DSECND( )
30 CONTINUE
S2 = DSECND( )
UNTIME = S2 - S1
ICL = ICL + 1
IF( ICL.LE.IC ) THEN
CALL DLACPY( 'All', M, N, COPYA, LDA, A, LDA )
CALL ICOPY( N, IWORK( N+1 ), 1, IWORK, 1 )
GO TO 30
END IF
*
* The number of flops of xGEQP3 is approximately the
* the number of flops of xGEQPF.
*
TIME = ( TIME-UNTIME ) / DBLE( IC )
*
OPS = DOPLA( 'DGEQPF', M, N, 0, 0, NB )
RESLTS( INB, IM, ILDA ) = DMFLOP( OPS, TIME, INFO )
*
40 CONTINUE
50 CONTINUE
60 CONTINUE
*
* Print the results for each matrix type.
*
WRITE( NOUT, FMT = 9999 )SUBNAM( 1 )
WRITE( NOUT, FMT = 9998 )IMODE
DO 70 I = 1, NLDA
WRITE( NOUT, FMT = 9997 )I, LDAVAL( I )
70 CONTINUE
WRITE( NOUT, FMT = * )
CALL DPRTB4( '( NB, NX)', 'M', 'N', NNB, NBVAL, NXVAL, NM,
$ MVAL, NVAL, NLDA, RESLTS( 1, 1, 1 ), LDR1, LDR2,
$ NOUT )
*
80 CONTINUE
*
9999 FORMAT( / ' *** Speed of ', A6, ' in megaflops ***' )
9998 FORMAT( 5X, 'type of matrix:', I4 )
9997 FORMAT( 5X, 'line ', I4, ' with LDA = ', I4 )
9996 FORMAT( 1X, A6, ' timing run not attempted', / )
*
90 CONTINUE
RETURN
*
* End of DTIMQ3
*
END
|
