1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
|
dnl Checks for libhmac required headers and functions
dnl
dnl Version: 20240520
dnl Function to detect if libhmac is available
dnl ac_libhmac_dummy is used to prevent AC_CHECK_LIB adding unnecessary -l<library> arguments
AC_DEFUN([AX_LIBHMAC_CHECK_LIB],
[AS_IF(
[test "x$ac_cv_enable_shared_libs" = xno || test "x$ac_cv_with_libhmac" = xno],
[ac_cv_libhmac=no],
[ac_cv_libhmac=check
dnl Check if the directory provided as parameter exists
dnl For both --with-libhmac which returns "yes" and --with-libhmac= which returns ""
dnl treat them as auto-detection.
AS_IF(
[test "x$ac_cv_with_libhmac" != x && test "x$ac_cv_with_libhmac" != xauto-detect && test "x$ac_cv_with_libhmac" != xyes],
[AX_CHECK_LIB_DIRECTORY_EXISTS([libhmac])],
[dnl Check for a pkg-config file
AS_IF(
[test "x$cross_compiling" != "xyes" && test "x$PKGCONFIG" != "x"],
[PKG_CHECK_MODULES(
[libhmac],
[libhmac >= 20200104],
[ac_cv_libhmac=yes],
[ac_cv_libhmac=check])
])
AS_IF(
[test "x$ac_cv_libhmac" = xyes],
[ac_cv_libhmac_CPPFLAGS="$pkg_cv_libhmac_CFLAGS"
ac_cv_libhmac_LIBADD="$pkg_cv_libhmac_LIBS"])
])
AS_IF(
[test "x$ac_cv_libhmac" = xcheck],
[dnl Check for headers
AC_CHECK_HEADERS([libhmac.h])
AS_IF(
[test "x$ac_cv_header_libhmac_h" = xno],
[ac_cv_libhmac=no],
[ac_cv_libhmac=yes
AX_CHECK_LIB_FUNCTIONS(
[libhmac],
[hmac],
[[libhmac_get_version],
[libhmac_md5_initialize],
[libhmac_md5_update],
[libhmac_md5_finalize],
[libhmac_md5_free],
[libhmac_sha1_initialize],
[libhmac_sha1_update],
[libhmac_sha1_finalize],
[libhmac_sha1_free],
[libhmac_sha224_initialize],
[libhmac_sha224_update],
[libhmac_sha224_finalize],
[libhmac_sha224_free],
[libhmac_sha256_initialize],
[libhmac_sha256_update],
[libhmac_sha256_finalize],
[libhmac_sha256_free],
[libhmac_sha512_initialize],
[libhmac_sha512_update],
[libhmac_sha512_finalize],
[libhmac_sha512_free]])
ac_cv_libhmac_LIBADD="-lhmac"])
])
AX_CHECK_LIB_DIRECTORY_MSG_ON_FAILURE([libhmac])
])
AS_IF(
[test "x$ac_cv_libhmac" = xyes],
[AC_DEFINE(
[HAVE_LIBHMAC],
[1],
[Define to 1 if you have the `hmac' library (-lhmac).])
])
AS_IF(
[test "x$ac_cv_libhmac" = xyes],
[ac_cv_libhmac_md5=libhmac
ac_cv_libhmac_sha1=libhmac
ac_cv_libhmac_sha224=libhmac
ac_cv_libhmac_sha256=libhmac
ac_cv_libhmac_sha512=libhmac],
[ac_cv_libhmac_md5=no
ac_cv_libhmac_sha1=no
ac_cv_libhmac_sha224=no
ac_cv_libhmac_sha256=no
ac_cv_libhmac_sha512=no])
AS_IF(
[test "x$ac_cv_libhmac" = xyes],
[AC_SUBST(
[HAVE_LIBHMAC],
[1]) ],
[AC_SUBST(
[HAVE_LIBHMAC],
[0])
])
])
dnl Function to detect if libhmac dependencies are available
AC_DEFUN([AX_LIBHMAC_CHECK_LOCAL],
[dnl Check for libcrypto (openssl) support
AX_LIBCRYPTO_CHECK_ENABLE
AS_IF(
[test "x$ac_cv_libcrypto" != xno],
[AX_LIBCRYPTO_CHECK_MD5
AX_LIBCRYPTO_CHECK_SHA1
AX_LIBCRYPTO_CHECK_SHA224
AX_LIBCRYPTO_CHECK_SHA256
AX_LIBCRYPTO_CHECK_SHA512])
dnl Fallback to local versions if necessary
AS_IF(
[test "x$ac_cv_libcrypto" = xno || test "x$ac_cv_libcrypto_md5" = xno],
[ac_cv_libhmac_md5=local],
[ac_cv_libhmac_md5=$ac_cv_libcrypto_md5])
AS_IF(
[test "x$ac_cv_libcrypto" = xno || test "x$ac_cv_libcrypto_sha1" = xno],
[ac_cv_libhmac_sha1=local],
[ac_cv_libhmac_sha1=$ac_cv_libcrypto_sha1])
AS_IF(
[test "x$ac_cv_libcrypto" = xno || test "x$ac_cv_libcrypto_sha224" = xno],
[ac_cv_libhmac_sha224=local],
[ac_cv_libhmac_sha224=$ac_cv_libcrypto_sha224])
AS_IF(
[test "x$ac_cv_libcrypto" = xno || test "x$ac_cv_libcrypto_sha256" = xno],
[ac_cv_libhmac_sha256=local],
[ac_cv_libhmac_sha256=$ac_cv_libcrypto_sha256])
AS_IF(
[test "x$ac_cv_libcrypto" = xno || test "x$ac_cv_libcrypto_sha512" = xno],
[ac_cv_libhmac_sha512=local],
[ac_cv_libhmac_sha512=$ac_cv_libcrypto_sha512])
ac_cv_libhmac_CPPFLAGS="-I../libhmac -I\$(top_srcdir)/libhmac";
ac_cv_libhmac_LIBADD="../libhmac/libhmac.la";
ac_cv_libhmac=local
])
dnl Function to detect how to enable libhmac
AC_DEFUN([AX_LIBHMAC_CHECK_ENABLE],
[AX_COMMON_ARG_WITH(
[libhmac],
[libhmac],
[search for libhmac in includedir and libdir or in the specified DIR, or no if to use local version],
[auto-detect],
[DIR])
dnl Check for a shared library version
AX_LIBHMAC_CHECK_LIB
dnl Check if the dependencies for the local library version
AS_IF(
[test "x$ac_cv_libhmac" != xyes],
[AX_LIBHMAC_CHECK_LOCAL
AC_DEFINE(
[HAVE_LOCAL_LIBHMAC],
[1],
[Define to 1 if the local version of libhmac is used.])
AC_SUBST(
[HAVE_LOCAL_LIBHMAC],
[1])
])
AM_CONDITIONAL(
[HAVE_LOCAL_LIBHMAC],
[test "x$ac_cv_libhmac" = xlocal])
AS_IF(
[test "x$ac_cv_libhmac_CPPFLAGS" != "x"],
[AC_SUBST(
[LIBHMAC_CPPFLAGS],
[$ac_cv_libhmac_CPPFLAGS])
])
AS_IF(
[test "x$ac_cv_libhmac_LIBADD" != "x"],
[AC_SUBST(
[LIBHMAC_LIBADD],
[$ac_cv_libhmac_LIBADD])
])
AS_IF(
[test "x$ac_cv_libhmac" = xyes],
[AC_SUBST(
[ax_libhmac_pc_libs_private],
[-lhmac])
])
AS_IF(
[test "x$ac_cv_libhmac" = xyes],
[AC_SUBST(
[ax_libhmac_spec_requires],
[libhmac])
AC_SUBST(
[ax_libhmac_spec_build_requires],
[libhmac-devel])
])
])
|
