1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
#!/usr/bin/perl
use v5.14;
use warnings;
use Test2::V0;
use Future;
use Future::AsyncAwait;
use List::Util qw( sum );
# single scalar
{
async sub with_scalar
{
my $scalar = "true";
await $_[0];
return $scalar;
}
my $f1 = Future->new;
my $fret = with_scalar( $f1 );
ok( !$fret->is_ready, '$fret is not immediate with_scalar' );
$f1->done;
is( scalar $fret->get, "true", '$fret now ready after done' );
}
# single array
{
async sub with_array
{
my @array = (1, 2, 3);
await $_[0];
return sum @array;
}
my $f1 = Future->new;
my $fret = with_array( $f1 );
ok( !$fret->is_ready, '$fret is not immediate with_array' );
$f1->done;
is( scalar $fret->get, 6, '$fret now ready after done' );
}
# Captured outside
{
{
# Ensure the captured lexical lives in its own scope that is ended before
# the tests run
my $capture = "outer";
async sub inner
{
await $_[0];
return $capture;
}
}
my $f1 = Future->new;
my $fret = inner( $f1 );
ok( !$fret->is_ready, '$fret is not immediate with capture' );
$f1->done;
is( scalar $fret->get, "outer", '$fret now ready after done' );
}
# Closure with outside
# Make sure to test this twice because of pad lexical sharing - see RT124026
{
my $capture = "outer";
my $closure = async sub {
$capture .= "X";
await $_[0];
return $capture;
};
my $f1 = Future->new;
my $f2 = Future->new;
my $fret = Future->needs_all(
$closure->( $f1 ),
$closure->( $f2 ),
);
$f1->done;
$f2->done;
is( [ $fret->get ], [ "outerXX", "outerXX" ],
'$fret now ready after done for closure'
);
}
# Closure with `our` capture (RT132945)
{
our $capture = "outer";
my $closure = async sub {
$capture .= "X";
await $_[0];
return $capture;
};
my $f1 = Future->new;
my $fret = $closure->( $f1 );
$f1->done;
is( $fret->get, "outerX", '$fret now ready after done for closure with our capture' );
}
done_testing;
|
