1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
|
package Future::HTTP;
use strict;
use experimental 'signatures';
=head1 NAME
Future::HTTP - provide the most appropriate HTTP client with a Future API
=head1 SYNOPSIS
my $ua = Future::HTTP->new();
my $res = $ua->http_get('http://www.nethype.de/')->then(sub {
my( $body, $data ) = @_;
# ... handle the response
return $body
})->get();
This module is a wrapper combining L<Future> with the API provided
by L<AnyEvent::HTTP>. The backend used for the HTTP protocols
depends on whether one of the event loops is loaded.
=head2 Supported event loops
Currently, the following backends are supported:
=over 4
=item *
L<HTTP::Tiny>
=item *
L<HTTP::Tiny::Paranoid>
=item *
L<Mojolicious>
=item *
L<AnyEvent>
=item *
L<IO::Async>
=back
Support
is planned for L<LWP::UserAgent> and L<POE>
but has not materialized yet.
=cut
our $VERSION = '0.17';
our @loops;
push @loops, (
['IO/Async.pm' => 'Future::HTTP::NetAsync' ],
['Mojo/IOLoop.pm' => 'Future::HTTP::Mojo' ],
['AnyEvent.pm' => 'Future::HTTP::AnyEvent'],
['AE.pm' => 'Future::HTTP::AnyEvent'],
# POE support would be nice
# LWP::UserAgent support would be nice
# A threaded backend would also be nice but likely brings in other
# interesting problems. How will we load this? We have two prerequisites
# now, threads.pm and HTTP::Tiny...
#['threads.pm' => 'Future::HTTP::Tiny::threaded' ],
['HTTP/Tiny/Paranoid.pm' => 'Future::HTTP::Tiny::Paranoid'],
# The fallback, will always catch due to loading Future::HTTP
['Future/HTTP.pm' => 'Future::HTTP::Tiny'],
);
our $implementation;
our $default = 'Future::HTTP::Tiny';
=head1 METHODS
=head2 C<< Future::HTTP->new() >>
my $ua = Future::HTTP->new();
Creates a new instance of the HTTP client.
=cut
sub new($factoryclass, @args) {
$implementation ||= $factoryclass->best_implementation();
# return a new instance
$implementation->new(@args);
}
sub best_implementation( $class, @candidates ) {
if(! @candidates) {
@candidates = @loops;
};
# Find the currently running/loaded event loop(s)
#use Data::Dumper;
#warn Dumper \%INC;
#warn Dumper \@candidates;
my @applicable_implementations = map {
$_->[1]
} grep {
$INC{$_->[0]}
} @candidates;
if( ! @applicable_implementations ) {
@applicable_implementations = map {$_->[1]} @candidates;
}
# Check which one we can load:
for my $impl (@applicable_implementations) {
if( eval "require $impl; 1" ) {
return $impl;
};
};
# This will crash and burn, but that's how it is
return $default;
};
=head2 C<< $ua->is_async() >>
Returns true if the selected backend is asynchronous, false if it is
synchronous.
=cut
sub is_async {
die "method is_async must be overloaded by subclass\n";
}
# We support the L<AnyEvent::HTTP> API first
=head2 C<< $ua->http_get($url, %options) >>
my $res = $ua->http_get('http://example.com/',
headers => {
'Accept' => 'text/json',
},
)->then(sub {
my( $body, $headers ) = @_;
# ... handle the response
})->get;
Retrieves the URL and returns the body and headers, like
the function in L<AnyEvent::HTTP>.
=head2 C<< $ua->http_head($url, %options) >>
my $res = $ua->http_head('http://example.com/',
headers => {
'Accept' => 'text/json',
},
)->then(sub {
my( $body, $headers ) = @_;
...
})->get;
Retrieves the header of the URL and returns the headers,
like the function in L<AnyEvent::HTTP>.
=head2 C<< $ua->http_post($url, $body, %options) >>
my $res = $ua->http_post('http://example.com/api',
'{token:"my_json_token"}',
headers => {
'Accept' => 'text/json',
},
)->then(sub {
my( $body, $headers ) = @_;
...
})->get;
Posts the content to the URL and returns the body and headers,
like the function in L<AnyEvent::HTTP>.
=head2 C<< $ua->http_request($method, $url, %options) >>
my $res = $ua->http_request('PUT' => 'http://example.com/api',
headers => {
'Accept' => 'text/json',
},
body => '{token:"my_json_token"}',
)->then(sub {
my( $body, $headers ) = @_;
...
})->get;
Posts the content to the URL and returns the body and headers,
like the function in L<AnyEvent::HTTP>.
=head1 SEE ALSO
L<Future>
L<AnyEvent::HTTP> for the details of the API
=head1 REPOSITORY
The public repository of this module is
L<https://github.com/Corion/future-http>.
=head1 SUPPORT
The public support forum of this module is
L<https://perlmonks.org/>.
=head1 BUG TRACKER
Please report bugs in this module via the RT CPAN bug queue at
L<https://rt.cpan.org/Public/Dist/Display.html?Name=Future-HTTP>
or via mail to L<future-http-Bugs@rt.cpan.org>.
=head1 AUTHOR
Max Maischein C<corion@cpan.org>
=head1 COPYRIGHT (c)
Copyright 2016-2024 by Max Maischein C<corion@cpan.org>.
=head1 LICENSE
This module is released under the same terms as Perl itself.
=cut
# We should support more APIs like HTTP::Tiny, later
# See L<Future::HTTP::API::HTTPTiny>.
1;
|
