1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
|
/* abstractmultiset.vala
*
* Copyright (C) 2009 Ali Sabil
*
* This library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version.
* This library is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* Lesser General Public License for more details.
* You should have received a copy of the GNU Lesser General Public
* License along with this library; if not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
*
* Author:
* Ali Sabil <ali.sabil@gmail.com>
* Didier 'Ptitjes Villevalois <ptitjes@free.fr>
*/
/**
* Skeletal implementation of the {@link MultiSet} interface.
*
* @see HashMultiSet
* @see TreeMultiSet
*/
public abstract class Gee.AbstractMultiSet<G> : AbstractCollection<G>, MultiSet<G> {
public override int size {
get { return _nitems; }
}
protected Map<G, int> _storage_map;
private int _nitems = 0;
/**
* Constructs a new, empty abstract multi set.
*/
public AbstractMultiSet (Map<G, int> storage_map) {
this._storage_map = storage_map;
}
public int count (G item) {
int result = 0;
if (_storage_map.has_key (item)) {
result = _storage_map.get (item);
}
return result;
}
public override bool contains (G item) {
return _storage_map.has_key (item);
}
public override Gee.Iterator<G> iterator () {
return new Iterator<G> (this);
}
public override bool add (G item) {
if (_storage_map.has_key (item)) {
int current_count = _storage_map.get (item);
_storage_map.set (item, current_count + 1);
} else {
_storage_map.set (item, 1);
}
_nitems++;
return true;
}
public override bool remove (G item) {
if (_nitems > 0 && _storage_map.has_key (item)) {
int current_count = _storage_map.get (item);
if (current_count <= 1) {
_storage_map.unset (item);
} else {
_storage_map.set (item, current_count - 1);
}
_nitems--;
return true;
}
return false;
}
public override void clear () {
_storage_map.clear ();
_nitems = 0;
}
private class Iterator<G> : Object, Gee.Iterator<G> {
private AbstractMultiSet<G> _set;
private MapIterator<G, int> _iter;
private int _pending = 0;
private bool _removed = false;
public Iterator (AbstractMultiSet<G> set) {
_set = set;
_iter = _set._storage_map.map_iterator ();
}
public bool next () {
_removed = false;
if (_pending == 0) {
if (_iter.next ()) {
_pending = _iter.get_value () - 1;
return true;
}
} else {
_pending--;
return true;
}
return false;
}
public bool has_next () {
return _pending > 0 || _iter.has_next ();
}
public bool first () {
if (_set._nitems == 0) {
return false;
}
_pending = 0;
if (_iter.first ()) {
_pending = _iter.get_value () - 1;
}
return true;
}
public new G get () {
assert (! _removed);
return _iter.get_key ();
}
public void remove () {
assert (! _removed);
_iter.set_value (_pending = _iter.get_value () - 1);
if (_pending == 0) {
_iter.unset ();
}
_set._nitems--;
_removed = true;
}
}
}
|
