1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244
|
dnl $Id: configure.in,v 1.44.2.5 2007/01/16 19:50:19 cegger Exp $
dnl Process this file with autoconf to produce a configure script.
AC_PREREQ(2.59)
dnl Should perhaps add the ggi-develop ML as the 3rd argument
dnl to AC_INIT but someone has to take care of the spam...
AC_INIT([libggigcp],[1.0.2],[http://www.ggi-project.org/contact.html])
AC_CONFIG_SRCDIR([include/ggi/gcp.h])
AC_CONFIG_MACRO_DIR(m4)
dnl Put the name and version of the package here
AM_INIT_AUTOMAKE([libggigcp],[1.0.2],[-])
AM_MAINTAINER_MODE
dnl ========================================================================
dnl Set some defaults
PATHTAG="pAtHTAg"
TAGLEN="7"
gcp_conffile="libggigcp.conf"
ggi_subdir="ggi"
use_debug="yes"
dnl Targets
dnl This extension will _never_ have display-targets
dnl ========================================================================
dnl Checks for programs.
AC_PROG_AWK
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
LT_INIT([win32-dll])
dnl ========================================================================
dnl Generate libtool
LT_OUTPUT
dnl ========================================================================
dnl User selectable options
dnl Bah! autoconf hasn't set prefix to it's default value yet!
test "x$prefix" = xNONE && prefix=$ac_default_prefix
test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
GGI_INST_PATH
GGI_UNINST_PATH
GII_UNINST_PATH
AC_ARG_ENABLE(debug,
[ --disable-debug don't build with run-time debugging (speed freaks)],
use_debug=$enableval)
dnl TARGETS:
dnl Support the --with-extra-libs and --with-extra-includes command line
dnl options to 'configure'.
GGI_EXTRA_PATHS
dnl
dnl ========================================================================
dnl Checks for platform specificas
GGI_CHECK_STRING_FUNCS
GGI_CC_CHECK4_OPTION([pedantic])
GGI_CHECK_IMPLICIT_DECLARATIONS
dnl ========================================================================
dnl Checks for header files.
dnl Check for standard C headers
AC_HEADER_STDC
GGI_NEED_INTTYPES
dnl ========================================================================
dnl Checks for typedefs, structures, and compiler characteristics.
dnl Check if the compiler supports the 'const' keyword, otherwise define
dnl 'const' to empty.
AC_C_CONST
dnl Check if the compiler supports inlining. If it does define 'inline' to
dnl the apropriate keyword, otherwise define it to empty.
AC_C_INLINE
dnl Check for the extension of shared libraries (excluding the dot) and
dnl put it in the @DLLEXT@ Makefile variable.
GGI_DLLEXT
dnl ========================================================================
dnl Checks for library functions.
dnl ========================================================================
dnl LibGGI must be built
GGI_CHECKLIB([libggigcp])
dnl ========================================================================
dnl Checks for target-specific libraries and headers
DISPLAYSUBDIRS=""
DEFAULTSUBDIRS="color"
DISPLAYMODULES=""
DEFAULTMODULES=""
if test "$enable_shared" = "yes"; then
DEFAULTMODULES="$DEFAULTMODULES color_gcp.la"
fi
if test "$enable_static" = "yes"; then
AC_DEFINE(BUILTIN_DEFAULT, 1, [Support for builtin defaults])
fi
AM_CONDITIONAL(BUILTIN_DEFAULT,
test "$enable_static" = "yes")
dnl ========================================================================
dnl Check for targets
dnl ========================================================================
dnl Finally add some flags
dnl _THREAD_SAFE is used instead of _REENTRANT on some systems
CFLAGS="$CFLAGS -D_REENTRANT -D_THREAD_SAFE"
if test "x$use_debug" = "xyes"; then
CFLAGS="$CFLAGS -DDEBUG"
if test "x$ac_cv_prog_cc_g" = "xyes"; then
CFLAGS="$CFLAGS -g"
fi
fi
if test "$ac_cv_c_compiler_gnu" = "yes"; then
GGI_CC_CHECK4_OPTION([std=gnu99])
# Common warning flags
CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wsign-compare"
CFLAGS="$CFLAGS -Wstrict-prototypes -Wswitch"
CFLAGS="$CFLAGS -Wmissing-prototypes -Wreturn-type -Wshadow"
# Advanced warning flags
CFLAGS="$CFLAGS -Wnested-externs -Wredundant-decls"
CFLAGS="$CFLAGS -Wuninitialized -Wcast-qual -Wwrite-strings"
if test "x$cc_has_werror_implicit_function_declaration" = "xyes"; then
CFLAGS="$CFLAGS -Werror-implicit-function-declaration"
fi
# Buggy warning flag
# CFLAGS="$CFLAGS -Wconversion"
# Super advanced (only used for building releases)
# CFLAGS="$CFLAGS -Werror"
fi
dnl ========================================================================
dnl Write output
AC_SUBST(DISPLAYSUBDIRS)
AC_SUBST(DEFAULTSUBDIRS)
AC_SUBST(DISPLAYMODULES)
AC_SUBST(DEFAULTMODULES)
dnl Use static_* to substitute into files where values shouldn't
dnl dynamicly change. Makefiles need to be able to dynamicly change
dnl paths between build and install and shouldn't use these static_*.
dnl Files that will be installed must always show the final location where
dnl they will reside and should use these static_* values.
dnl Ensure that all static_* are fully expanded.
eval static_libdir="$libdir"
old_val=""
until test "$static_libdir" = "$old_val"; do
old_val="$static_libdir"
eval static_libdir="$static_libdir"
done
eval static_sysconfdir="$sysconfdir"
old_val=""
until test "$static_sysconfdir" = "$old_val"; do
old_val="$static_sysconfdir"
eval static_sysconfdir="$static_sysconfdir"
done
case "${host}" in
*-*-mingw*)
dnl Find a relative path that takes us from static_sysconfdir
dnl to static_libdir.
GGI_SYSCONF_TO_LIB
dnl The relative path from sysconfdir to sysconfdir is simple.
ggi_sysconfdir="."
;;
*)
dnl Usually good to use an absolute path.
ggi_sysconfdir_to_libdir="$static_libdir/$ggi_subdir"
ggi_sysconfdir="$static_sysconfdir/$ggi_subdir"
;;
esac
AC_SUBST(ggi_subdir)
AC_SUBST(ggi_sysconfdir_to_libdir)
AC_SUBST(ggi_sysconfdir)
AC_SUBST(static_libdir)
AC_SUBST(static_sysconfdir)
AC_DEFINE_UNQUOTED([GCPTAGLEN],$TAGLEN, [The length of the tag])
AC_DEFINE_UNQUOTED([GCPPATHTAG],"$PATHTAG", [Tag to identify path to $gcp_conffile])
AC_DEFINE_UNQUOTED([GCPCONFFILE],"$gcp_conffile", [Name of the gcp config file])
AC_DEFINE_UNQUOTED([GCPCONFDIR],"$PATHTAG$static_sysconfdir/$ggi_subdir",
[Tag plus path to config dir])
AM_CONFIG_HEADER([config.h])
AC_CONFIG_FILES([Makefile
include/Makefile
include/ggi/Makefile
include/ggi/internal/Makefile
gcp/Makefile
default/Makefile
default/color/Makefile
default-shared/Makefile
demos/Makefile
doc/Makefile
doc/man/Makefile
m4/Makefile
libggigcp.conf
])
AC_OUTPUT
|