1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
|
use strict;
use warnings;
use lib 't';
use Test::More;
use Test::Git;
use Test::Requires::Git;
use File::Temp qw( tempdir );
use File::Spec;
use Cwd qw( cwd abs_path );
use Git::Repository;
test_requires_git '1.5.0.rc1';
my $version = Git::Repository->version;
diag "git version $version";
# setup the environment
my %env = (
# ensure local configs won't interfere
GIT_CONFIG_NOSYSTEM => 1,
XDG_CONFIG_HOME => undef,
HOME => undef,
# no locale
LC_ALL => 'C',
# author / committer
GIT_AUTHOR_NAME => 'Test Author',
GIT_AUTHOR_EMAIL => 'test.author@example.com',
GIT_COMMITTER_NAME => 'Test Committer',
GIT_COMMITTER_EMAIL => 'test.committer@example.com',
);
plan tests => my $tests;
# first create a new empty repository
my $r = test_repository( git => { env => \%env } );
my $dir = $r->work_tree;
my $gitdir = $r->git_dir;
# extra options to the commit command:
# - skip commit hooks that might be included in the template
my @opts = qw( --no-verify );
# some test data
my %commit = (
1 => {
tree => 'df2b8fc99e1c1d4dbc0a854d9f72157f1d6ea078',
parent => [],
subject => 'empty file',
body => '',
extra => '',
},
2 => {
tree => '6820ead72140bd33a7a821965a05f9a1e89bf3c8',
parent => [],
subject => 'one line',
body => "of data\n",
extra => '',
},
);
sub check_commit {
my ( $id, $log, %more ) = @_;
my $commit = { %{ $commit{$id} }, %more };
is( $log->tree, $commit->{tree}, "commit $id tree" );
is_deeply( [ $log->parent ], $commit->{parent}, "commit $id parent" );
is( $log->subject, $commit->{subject}, "commit $id subject" );
is( $log->body, $commit->{body}, "commit $id body" );
is( $log->extra, $commit->{extra}, "commit $id extra" );
}
local $/ = chr rand 128;
# no log method yet
BEGIN { $tests += 3 }
ok( !eval { $r->log('-1') }, 'no log() method' );
# load the log method
use_ok( 'Git::Repository', 'Log' );
ok( eval { $r->log('-1') }, 'log() method exists now' );
# create an empty file and commit it
BEGIN { $tests += 2 }
my $file = File::Spec->catfile( $dir, 'file' );
do { open my $fh, '>', $file; };
$r->run( add => 'file' );
$r->run( commit => @opts, '-m', $commit{1}{subject} );
my @log = $r->log();
is( scalar @log, 1, '1 commit' );
isa_ok( $_, 'Git::Repository::Log' ) for @log;
# check some log details
BEGIN { $tests += 5 }
check_commit( 1 => $log[0] );
push @{ $commit{2}{parent} }, $log[0]->commit;
# create another commit
BEGIN { $tests += 3 }
do { open my $fh, '>', $file; print $fh 'line 1'; };
$r->run( add => 'file' );
$r->run( commit => @opts, '-m', "$commit{2}{subject}\n\n$commit{2}{body}" );
@log = $r->log();
is( scalar @log, 2, '2 commits' );
isa_ok( $_, 'Git::Repository::Log' ) for @log;
# check some log details
BEGIN { $tests += 5 }
check_commit( 2 => $log[0] );
# try as a class method
BEGIN { $tests += 8 }
my $home = cwd;
chdir $dir;
@log = Git::Repository->log();
is( scalar @log, 2, '2 commits' );
isa_ok( $_, 'Git::Repository::Log' ) for @log;
check_commit( 2 => $log[0] );
chdir $home;
# try a command that fails (fatal)
BEGIN { $tests += 2 }
ok( !eval { @log = $r->log('zlonk') }, q{log('zlonk') failed} );
like(
$@,
qr/^fatal: ambiguous argument 'zlonk': unknown revision or path not in/,
'unknown revision or path'
);
# try a command that returns a git error (usage)
BEGIN { $tests += 2 }
ok( !eval { @log = $r->log('--bam') }, q{log('--bam') failed} );
like(
$@,
qr/^fatal: unrecognized argument: --bam at/,
'unknown revision or path'
);
# various options combinations
my @options;
BEGIN {
@options = (
[ [qw( -p -- file )], [ <<'DIFF', << 'DIFF'] ],
diff --git a/file b/file
index e69de29..dcf168c 100644
--- a/file
+++ b/file
@@ -0,0 +1 @@
+line 1
\ No newline at end of file
DIFF
diff --git a/file b/file
new file mode 100644
index 0000000..e69de29
DIFF
[ [qw( file )], [ '', '' ] ],
[ [qw( --decorate file )], [ '', '' ], '1.5.2.rc0' ],
[ [qw( --pretty=raw )], [ '', '' ] ],
);
$tests += 13 * @options;
}
for my $o (@options) {
my ( $args, $extra, $minver ) = @$o;
SKIP: {
skip "git log @$args needs $minver, we only have $version", 13
if $minver && Git::Repository->version_lt($minver);
@log = $r->log(@$args);
is( scalar @log, 2, "2 commits for @$args" );
isa_ok( $_, 'Git::Repository::Log' ) for @log;
check_commit( 2 => $log[0], extra => $extra->[0] );
check_commit( 1 => $log[1], extra => $extra->[1] );
}
}
my @badopts;
BEGIN {
@badopts = (
[qw( --pretty=oneline )],
[qw( --graph )],
[qw( --format=medium )],
[qw( --oneline)],
);
$tests += 2 * @badopts;
}
for my $badopt (@badopts) {
ok( !eval { $r->log(@$badopt) }, "bad options: @$badopt" );
like( $@, qr/^log\(\) cannot parse @$badopt/, '... expected error' );
}
|
