1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
|
------------------------------------------------------------------------------
-- G N A T C O L L --
-- --
-- Copyright (C) 2016-2017, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify it --
-- under terms of the GNU General Public License as published by the Free --
-- Software Foundation; either version 3, or (at your option) any later --
-- version. This library is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- --
-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- As a special exception under Section 7 of GPL version 3, you are granted --
-- additional permissions described in the GCC Runtime Library Exception, --
-- version 3.1, as published by the Free Software Foundation. --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
------------------------------------------------------------------------------
package body GNATCOLL.SQL.Ranges is
package body Impl is
use Base_Fields;
------------------
-- Create_Range --
------------------
function Create_Range
(Min, Max : Base_Fields.Field'Class;
Min_Included : Boolean := True;
Max_Included : Boolean := True) return Ada_Range
is
Min_Null : constant Boolean :=
Base_Fields.Field (Min) = Base_Fields.Null_Field;
Mi : constant SQL_Field_Pointer :=
(if Min_Null then No_Field_Pointer else +Min);
Min_I : constant Boolean := Min_Null or else Min_Included;
Max_Null : constant Boolean :=
Base_Fields.Field (Max) = Base_Fields.Null_Field;
Ma : constant SQL_Field_Pointer :=
(if Max_Null then No_Field_Pointer else +Max);
Max_I : constant Boolean := Max_Null or else Max_Included;
begin
return Ada_Range'
(Min => Mi,
Max => Ma,
Min_Included => Min_I,
Max_Included => Max_I);
end Create_Range;
--------------------------------
-- Create_Min_Unbounded_Range --
--------------------------------
function Create_Min_Unbounded_Range
(Max : Base_Fields.Field'Class;
Max_Included : Boolean := True) return Ada_Range is
begin
return Create_Range
(Min => Base_Fields.Null_Field,
Max => Max,
Max_Included => Max_Included);
end Create_Min_Unbounded_Range;
--------------------------------
-- Create_Max_Unbounded_Range --
--------------------------------
function Create_Max_Unbounded_Range
(Min : Base_Fields.Field'Class;
Min_Included : Boolean := True) return Ada_Range is
begin
return Create_Range
(Max => Base_Fields.Null_Field,
Min => Min,
Min_Included => Min_Included);
end Create_Max_Unbounded_Range;
------------------
-- Range_To_SQL --
------------------
function Range_To_SQL
(Self : Formatter'Class; Value : Ada_Range; Quote : Boolean)
return String
is
pragma Unreferenced (Quote);
Min_Null : constant Boolean := Value.Min = No_Field_Pointer;
Max_Null : constant Boolean := Value.Max = No_Field_Pointer;
begin
if Min_Null and then Max_Null then
if not Value.Min_Included and then not Value.Max_Included then
return "'empty'";
else
return "'(,)'";
end if;
else
return SQL_Type & "(" -- cast
& (if Min_Null
then "null"
else To_String (Value.Min, Self, Long => True))
& ","
& (if Max_Null
then "null"
else To_String (Value.Max, Self, Long => True))
& (if not Min_Null and then Value.Min_Included
then ",'[" else ",'(")
& (if not Max_Null and then Value.Max_Included
then "]')" else ")')");
end if;
end Range_To_SQL;
end Impl;
-----------------
-- Range_Value --
-----------------
function Range_Value
(Self : Forward_Cursor'Class;
Field : Field_Index)
return Ada_Range
is
V : constant String := Self.Value (Field);
Comma : Integer := Integer'Last;
begin
if V = "empty" then
return Empty_Range;
end if;
for S in V'Range loop
if V (S) = ',' then
Comma := S;
exit;
end if;
end loop;
if Comma = Integer'Last then
-- Invalid range
return Empty_Range;
elsif Comma = V'First + 1 then
if Comma = V'Last - 1 then
return Doubly_Unbounded_Range;
else
return Impl.Create_Min_Unbounded_Range
(Max => Base_Fields.From_String (V (Comma + 1 .. V'Last - 1)),
Max_Included => V (V'Last) = ']');
end if;
elsif Comma = V'Last - 1 then
return Impl.Create_Max_Unbounded_Range
(Min => Base_Fields.From_String (V (V'First + 1 .. Comma - 1)),
Min_Included => V (V'First) = '[');
else
return Impl.Create_Range
(Min => Base_Fields.From_String (V (V'First + 1 .. Comma - 1)),
Max => Base_Fields.From_String (V (Comma + 1 .. V'Last - 1)),
Min_Included => V (V'First) = '[',
Max_Included => V (V'Last) = ']');
end if;
end Range_Value;
end GNATCOLL.SQL.Ranges;
|
