1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150
|
# Configure.in
#
# This file tests for various compiler features needed to configure
# the gtkmm package. Original skeleton was provided by Stephan Kulow.
# All tests were written by Tero Pulkkinen, Mirko Streckenbach, and
# Karl Nelson.
#
#
# Copyright 2001 Free Software Foundation
# Copyright 1999 gtkmm Development Team
# Copyright 1998 Stephan Kulow
#
AC_INIT(libgnome/libgnomemmconfig.h.in)
#########################################################################
# Version and initialization
#########################################################################
LIBGNOMEMM_MAJOR_VERSION=2
LIBGNOMEMM_MINOR_VERSION=14
LIBGNOMEMM_MICRO_VERSION=0
#
# +1 : ? : +1 == new interface that does not break old one
# +1 : ? : 0 == new interface that breaks old one
# ? : ? : 0 == no new interfaces, but breaks apps
# ? :+1 : ? == just some internal changes, nothing breaks but might work
# better
# CURRENT : REVISION : AGE
LIBGNOMEMM_SO_VERSION=1:5:0
LIBGNOMEMM_VERSION=$LIBGNOMEMM_MAJOR_VERSION.$LIBGNOMEMM_MINOR_VERSION.$LIBGNOMEMM_MICRO_VERSION
LIBGNOMEMM_RELEASE=$LIBGNOMEMM_MAJOR_VERSION.$LIBGNOMEMM_MINOR_VERSION
AC_DEFINE_UNQUOTED(LIBGNOMEMM_MAJOR_VERSION, $LIBGNOMEMM_MAJOR_VERSION)
AC_DEFINE_UNQUOTED(LIBGNOMEMM_MINOR_VERSION, $LIBGNOMEMM_MINOR_VERSION)
AC_DEFINE_UNQUOTED(LIBGNOMEMM_MICRO_VERSION, $LIBGNOMEMM_MICRO_VERSION)
AC_DEFINE_UNQUOTED(LIBGNOMEMM_VERSION, "$LIBGNOMEMM_VERSION")
AC_SUBST(LIBGNOMEMM_VERSION)
AC_SUBST(LIBGNOMEMM_RELEASE)
AC_SUBST(LIBGNOMEMM_SO_VERSION)
AC_CONFIG_AUX_DIR(scripts)
dnl For automake.
VERSION=$LIBGNOMEMM_VERSION
PACKAGE=libgnomemm
dnl Initialize automake stuff
AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
dnl Specify a configuration file (no autoheader)
AM_CONFIG_HEADER(libgnome/libgnomemmconfig.h)
AM_MAINTAINER_MODE
AL_ACLOCAL_INCLUDE(scripts)
#########################################################################
# Configure arguments
#########################################################################
#########################################################################
# Environment Checks
#########################################################################
AC_PROG_CC
AC_PROG_CPP
AC_PROG_MAKE_SET
AC_CANONICAL_HOST
AM_DISABLE_STATIC
AM_PROG_LIBTOOL
AL_PROG_GNU_M4(AC_MSG_ERROR([dnl
SUN m4 does not work for building gtkmm.
Please install GNU m4.]))
AL_PROG_GNU_MAKE(AC_MSG_ERROR([dnl
SUN make does not work for building gtkmm.
Please install GNU make.]))
#########################################################################
# Dependancy checks
#########################################################################
# Make these available to both PKG_CHECK_MODULES and the .pc.in file:
GTKMM_VERSION_NEEDED=2.4.0
AC_SUBST(GTKMM_VERSION_NEEDED)
LIBGNOME_VERSION_NEEDED=2.6.0
AC_SUBST(LIBGNOME_VERSION_NEEDED)
# TODO: Depend on glibmm instead of gtkmm? We only need gtkmm for Gnome::Main, which uses Gtk::Main.
PKG_CHECK_MODULES(LIBGNOMEMM, gtkmm-2.4 >= $GTKMM_VERSION_NEEDED libgnome-2.0 >= $LIBGNOME_VERSION_NEEDED)
AC_SUBST(LIBGNOMEMM_CFLAGS)
AC_SUBST(LIBGNOMEMM_LIBS)
GLIBMM_LIBDIR=`pkg-config --variable=libdir glibmm-2.4`
GMM_PROCDIR=$GLIBMM_LIBDIR/glibmm-2.4/proc
AC_SUBST(GMM_PROCDIR)
GMM_PROC=$GMM_PROCDIR/gmmproc
AC_SUBST(GMM_PROC)
#########################################################################
# C++ checks
#########################################################################
AC_PROG_CXX
AC_LANG_CPLUSPLUS
# Create a list of input directories for Doxygen. We have to check wether
# we are building in the source directory, because Doxygen doesn't like
# duplicated directories in the input list.
LIBGNOMEMM_DOXYGEN_INPUT=''
gtkmm_srcdir=`cd "$srcdir" && pwd`
gtkmm_builddir=`pwd`
for sublib in libgnome
do
LIBGNOMEMM_DOXYGEN_INPUT="$LIBGNOMEMM_DOXYGEN_INPUT $gtkmm_builddir/$sublib/$sublib""mm/"
test "x$gtkmm_builddir" = "x$gtkmm_srcdir" || \
LIBGNOMEMM_DOXYGEN_INPUT="$LIBGNOMEMM_DOXYGEN_INPUT $gtkmm_srcdir/$sublib/$sublib""mm/"
done
AC_SUBST(LIBGNOMEMM_DOXYGEN_INPUT)
# Dummy conditional just to make automake-1.4 happy.
# We need an always-false condition in docs/Makefile.am.
AM_CONDITIONAL(LIBGNOMEMM_FALSE,[false])
# HACK: Assign a dummy in order to prevent execution of autoheader by the
# maintainer-mode rules. That would fail since we aren't using autoheader.
AUTOHEADER=':'
AC_OUTPUT([
Makefile
libgnomemm.spec
libgnome/Makefile
libgnome/libgnomemm-2.6.pc
libgnome/libgnomemm-2.6-uninstalled.pc
libgnome/src/Makefile
libgnome/libgnomemm/Makefile
libgnome/libgnomemm/private/Makefile
tools/Makefile
tools/m4/Makefile
scripts/Makefile
docs/Makefile
docs/reference/Makefile
docs/reference/Doxyfile
])
|