1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427
|
-----------------------------------------------------------------------
-- GtkAda - Ada95 binding for Gtk+/Gnome --
-- --
-- Copyright (C) 1998-2000 E. Briot, J. Brobecker and A. Charlet --
-- Copyright (C) 2000-2006 AdaCore --
-- --
-- This library is free software; you can redistribute it and/or --
-- modify it under the terms of the GNU General Public --
-- License as published by the Free Software Foundation; either --
-- version 2 of the License, or (at your option) any later version. --
-- --
-- This library is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. --
-- --
-- You should have received a copy of the GNU General Public --
-- License along with this library; if not, write to the --
-- Free Software Foundation, Inc., 59 Temple Place - Suite 330, --
-- Boston, MA 02111-1307, USA. --
-- --
-----------------------------------------------------------------------
with System;
with Glib.Type_Conversion_Hooks;
pragma Elaborate_All (Glib.Type_Conversion_Hooks);
with Interfaces.C.Strings; use Interfaces.C.Strings;
with Gtk.Widget; use Gtk.Widget;
package body Gtk.Button is
-----------------------
-- Local Subprograms --
-----------------------
function Type_Conversion (Type_Name : String) return GObject;
-- This function is used to implement a minimal automated type conversion
-- without having to drag the whole Gtk.Type_Conversion package for the
-- most common widgets.
-------------
-- Clicked --
-------------
procedure Clicked (Button : access Gtk_Button_Record) is
procedure Internal (W : in System.Address);
pragma Import (C, Internal, "gtk_button_clicked");
begin
Internal (Get_Object (Button));
end Clicked;
-----------
-- Enter --
-----------
procedure Enter (Button : access Gtk_Button_Record) is
procedure Internal (W : System.Address);
pragma Import (C, Internal, "gtk_button_enter");
begin
Internal (Get_Object (Button));
end Enter;
---------------
-- Get_Label --
---------------
function Get_Label
(Button : access Gtk_Button_Record) return UTF8_String
is
function Internal (Button : System.Address) return chars_ptr;
pragma Import (C, Internal, "gtk_button_get_label");
begin
return Value (Internal (Get_Object (Button)));
end Get_Label;
----------------
-- Get_Relief --
----------------
function Get_Relief
(Button : access Gtk_Button_Record)
return Gtk.Enums.Gtk_Relief_Style
is
function Internal (Button : System.Address) return Gint;
pragma Import (C, Internal, "gtk_button_get_relief");
begin
return Gtk.Enums.Gtk_Relief_Style'Val (Internal (Get_Object (Button)));
end Get_Relief;
-----------------------
-- Get_Use_Underline --
-----------------------
function Get_Use_Underline
(Button : access Gtk_Button_Record) return Boolean
is
function Internal (Button : System.Address) return Gboolean;
pragma Import (C, Internal, "gtk_button_get_use_underline");
begin
return Internal (Get_Object (Button)) /= 0;
end Get_Use_Underline;
-------------------
-- Get_Use_Stock --
-------------------
function Get_Use_Stock
(Button : access Gtk_Button_Record) return Boolean
is
function Internal (Button : System.Address) return Gboolean;
pragma Import (C, Internal, "gtk_button_get_use_stock");
begin
return Internal (Get_Object (Button)) /= 0;
end Get_Use_Stock;
-------------
-- Gtk_New --
-------------
procedure Gtk_New (Button : out Gtk_Button; Label : UTF8_String := "") is
begin
Button := new Gtk_Button_Record;
Initialize (Button, Label);
end Gtk_New;
------------------------
-- Gtk_New_From_Stock --
------------------------
procedure Gtk_New_From_Stock
(Button : out Gtk_Button; Stock_Id : String) is
begin
Button := new Gtk_Button_Record;
Initialize_From_Stock (Button, Stock_Id);
end Gtk_New_From_Stock;
---------------------------
-- Gtk_New_With_Mnemonic --
---------------------------
procedure Gtk_New_With_Mnemonic
(Button : out Gtk_Button; Label : UTF8_String) is
begin
Button := new Gtk_Button_Record;
Initialize_With_Mnemonic (Button, Label);
end Gtk_New_With_Mnemonic;
----------------
-- Initialize --
----------------
procedure Initialize
(Button : access Gtk_Button_Record'Class;
Label : UTF8_String)
is
function Internal (S : String) return System.Address;
pragma Import (C, Internal, "gtk_button_new_with_label");
function Internal2 return System.Address;
pragma Import (C, Internal2, "gtk_button_new");
begin
if Label = "" then
Set_Object (Button, Internal2);
else
Set_Object (Button, Internal (Label & ASCII.NUL));
end if;
end Initialize;
---------------------------
-- Initialize_From_Stock --
---------------------------
procedure Initialize_From_Stock
(Button : access Gtk_Button_Record'Class;
Stock_Id : String)
is
function Internal (Stock_Id : String) return System.Address;
pragma Import (C, Internal, "gtk_button_new_from_stock");
begin
Set_Object (Button, Internal (Stock_Id & ASCII.NUL));
end Initialize_From_Stock;
------------------------------
-- Initialize_With_Mnemonic --
------------------------------
procedure Initialize_With_Mnemonic
(Button : access Gtk_Button_Record'Class;
Label : UTF8_String)
is
function Internal (Label : String) return System.Address;
pragma Import (C, Internal, "gtk_button_new_with_mnemonic");
begin
Set_Object (Button, Internal (Label & ASCII.NUL));
end Initialize_With_Mnemonic;
-----------
-- Leave --
-----------
procedure Leave (Button : access Gtk_Button_Record) is
procedure Internal (W : System.Address);
pragma Import (C, Internal, "gtk_button_leave");
begin
Internal (Get_Object (Button));
end Leave;
-------------
-- Pressed --
-------------
procedure Pressed (Button : access Gtk_Button_Record) is
procedure Internal (W : System.Address);
pragma Import (C, Internal, "gtk_button_pressed");
begin
Internal (Get_Object (Button));
end Pressed;
--------------
-- Released --
--------------
procedure Released (Button : access Gtk_Button_Record) is
procedure Internal (W : System.Address);
pragma Import (C, Internal, "gtk_button_released");
begin
Internal (Get_Object (Button));
end Released;
---------------
-- Set_Label --
---------------
procedure Set_Label
(Button : access Gtk_Button_Record;
Label : UTF8_String)
is
procedure Internal
(Button : System.Address;
Label : String);
pragma Import (C, Internal, "gtk_button_set_label");
begin
Internal (Get_Object (Button), Label & ASCII.NUL);
end Set_Label;
----------------
-- Set_Relief --
----------------
procedure Set_Relief
(Button : access Gtk_Button_Record;
New_Style : Gtk.Enums.Gtk_Relief_Style)
is
procedure Internal
(Button : System.Address;
New_Style : Gtk.Enums.Gtk_Relief_Style);
pragma Import (C, Internal, "gtk_button_set_relief");
begin
Internal (Get_Object (Button), New_Style);
end Set_Relief;
-----------------------
-- Set_Use_Underline --
-----------------------
procedure Set_Use_Underline
(Button : access Gtk_Button_Record;
Use_Underline : Boolean)
is
procedure Internal
(Button : System.Address;
Use_Underline : Gboolean);
pragma Import (C, Internal, "gtk_button_set_use_underline");
begin
Internal (Get_Object (Button), Boolean'Pos (Use_Underline));
end Set_Use_Underline;
-------------------
-- Set_Use_Stock --
-------------------
procedure Set_Use_Stock
(Button : access Gtk_Button_Record;
Use_Stock : Boolean)
is
procedure Internal
(Button : System.Address;
Use_Stock : Gboolean);
pragma Import (C, Internal, "gtk_button_set_use_stock");
begin
Internal (Get_Object (Button), Boolean'Pos (Use_Stock));
end Set_Use_Stock;
-------------------
-- Get_Alignment --
-------------------
procedure Get_Alignment
(Button : access Gtk_Button_Record;
Xalign : out Gfloat;
Yalign : out Gfloat)
is
procedure Internal
(Button : System.Address;
Xalign : out Gfloat;
Yalign : out Gfloat);
pragma Import (C, Internal, "gtk_button_get_alignment");
begin
Internal (Get_Object (Button), Xalign, Yalign);
end Get_Alignment;
------------------------
-- Get_Focus_On_Click --
------------------------
function Get_Focus_On_Click
(Button : access Gtk_Button_Record)
return Boolean
is
function Internal
(Button : System.Address)
return Gboolean;
pragma Import (C, Internal, "gtk_button_get_focus_on_click");
begin
return Boolean'Val (Internal (Get_Object (Button)));
end Get_Focus_On_Click;
---------------
-- Get_Image --
---------------
function Get_Image
(Button : access Gtk_Button_Record)
return Gtk_Widget
is
function Internal
(Button : System.Address)
return System.Address;
pragma Import (C, Internal, "gtk_button_get_image");
Stub : Gtk_Widget_Record;
begin
return Gtk_Widget
(Get_User_Data
(Internal (Get_Object (Button)), Stub));
end Get_Image;
-------------------
-- Set_Alignment --
-------------------
procedure Set_Alignment
(Button : access Gtk_Button_Record;
Xalign : Gfloat := 0.5;
Yalign : Gfloat := 0.5)
is
procedure Internal
(Button : System.Address;
Xalign : Gfloat;
Yalign : Gfloat);
pragma Import (C, Internal, "gtk_button_set_alignment");
begin
Internal (Get_Object (Button), Xalign, Yalign);
end Set_Alignment;
------------------------
-- Set_Focus_On_Click --
------------------------
procedure Set_Focus_On_Click
(Button : access Gtk_Button_Record;
Focus_On_Click : Boolean := True)
is
procedure Internal
(Button : System.Address;
Focus_On_Click : Gboolean);
pragma Import (C, Internal, "gtk_button_set_focus_on_click");
begin
Internal (Get_Object (Button), Boolean'Pos (Focus_On_Click));
end Set_Focus_On_Click;
---------------
-- Set_Image --
---------------
procedure Set_Image
(Button : access Gtk_Button_Record;
Image : access Gtk_Widget_Record'Class)
is
procedure Internal
(Button : System.Address;
Image : System.Address);
pragma Import (C, Internal, "gtk_button_set_image");
begin
Internal (Get_Object (Button), Get_Object (Image));
end Set_Image;
---------------------
-- Type_Conversion --
---------------------
function Type_Conversion (Type_Name : String) return GObject is
begin
if Type_Name = "GtkButton" then
return new Gtk_Button_Record;
else
return null;
end if;
end Type_Conversion;
begin
Glib.Type_Conversion_Hooks.Add_Hook (Type_Conversion'Access);
end Gtk.Button;
|