File: gtk-container.adb

package info (click to toggle)
libgtkada2 2.8.1-6lenny3
  • links: PTS, VCS
  • area: main
  • in suites: lenny
  • size: 13,496 kB
  • ctags: 3,886
  • sloc: ada: 103,189; ansic: 45,411; perl: 5,500; sh: 2,812; makefile: 1,169; xml: 19
file content (617 lines) | stat: -rw-r--r-- 19,013 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
-----------------------------------------------------------------------
--               GtkAda - Ada95 binding for Gtk+/Gnome               --
--                                                                   --
--   Copyright (C) 1998-2000 E. Briot, J. Brobecker and A. Charlet   --
--                Copyright (C) 2000-2006 AdaCore                    --
--                                                                   --
-- This library is free software; you can redistribute it and/or     --
-- modify it under the terms of the GNU General Public               --
-- License as published by the Free Software Foundation; either      --
-- version 2 of the License, or (at your option) any later version.  --
--                                                                   --
-- This library is distributed in the hope that it will be useful,   --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of    --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU --
-- General Public License for more details.                          --
--                                                                   --
-- You should have received a copy of the GNU General Public         --
-- License along with this library; if not, write to the             --
-- Free Software Foundation, Inc., 59 Temple Place - Suite 330,      --
-- Boston, MA 02111-1307, USA.                                       --
--                                                                   --
-----------------------------------------------------------------------

with System;         use System;
with Glib.Values;    use Glib.Values;
with Gtk.Adjustment; use Gtk.Adjustment;
with Gtk.Enums;      use Gtk.Enums;
with Gtk.Widget;     use Gtk.Widget;

package body Gtk.Container is

   procedure Internal_Gtk_Callback
     (Widget : System.Address; Data : Gtk_Callback);
   pragma Convention (C, Internal_Gtk_Callback);
   --  Proxy for a Gtk callback

   ---------
   -- Add --
   ---------

   procedure Add
     (Container : access Gtk_Container_Record;
      Widget    : access Gtk.Widget.Gtk_Widget_Record'Class)
   is
      procedure Internal
        (Container : System.Address;
         Widget    : System.Address);
      pragma Import (C, Internal, "gtk_container_add");

   begin
      Internal (Get_Object (Container), Get_Object (Widget));
   end Add;

   ------------------
   -- Check_Resize --
   ------------------

   procedure Check_Resize (Container : access Gtk_Container_Record) is
      procedure Internal (Container : System.Address);
      pragma Import (C, Internal, "gtk_container_check_resize");

   begin
      Internal (Get_Object (Container));
   end Check_Resize;

   ----------------
   -- Child_Type --
   ----------------

   function Child_Type
     (Container : access Gtk_Container_Record) return Gtk.Gtk_Type
   is
      function Internal (Container : System.Address) return Gtk.Gtk_Type;
      pragma Import (C, Internal, "gtk_container_child_type");

   begin
      return Internal (Get_Object (Container));
   end Child_Type;

   ---------------------------
   -- Internal_Gtk_Callback --
   ---------------------------

   procedure Internal_Gtk_Callback
     (Widget : System.Address;
      Data   : Gtk_Callback)
   is
      Stub : Gtk_Widget_Record;
   begin
      Data (Gtk_Widget (Get_User_Data (Widget, Stub)));
   end Internal_Gtk_Callback;

   ------------
   -- Forall --
   ------------

   procedure Forall
     (Container : access Gtk_Container_Record;
      Func      : Gtk_Callback)
   is
      procedure Internal
        (Container : System.Address;
         Func      : System.Address;
         Data      : Gtk_Callback);
      pragma Import (C, Internal, "gtk_container_forall");
   begin
      Internal (Get_Object (Container), Internal_Gtk_Callback'Address, Func);
   end Forall;

   -------------
   -- Foreach --
   -------------

   procedure Foreach
     (Container : access Gtk_Container_Record;
      Func      : Gtk_Callback)
   is
      procedure Internal
        (Container : System.Address;
         Func      : System.Address;
         Data      : Gtk_Callback);
      pragma Import (C, Internal, "gtk_container_foreach");
   begin
      Internal (Get_Object (Container), Internal_Gtk_Callback'Address, Func);
   end Foreach;

   -------------
   -- For_Pkg --
   -------------

   package body For_Pkg is

      type Data_Type_Access is access all Data_Type;

      type Internal_Data is record
         Data : Data_Type_Access;
         Func : Gtk_Callback;
      end record;
      type Internal_Data_Access is access all Internal_Data;

      procedure Internal_Func
        (Widget : System.Address; Data : Internal_Data_Access);
      pragma Convention (C, Internal_Func);

      -------------------
      -- Internal_Func --
      -------------------

      procedure Internal_Func
        (Widget : System.Address; Data : Internal_Data_Access)
      is
         Stub : Gtk_Widget_Record;
      begin
         Data.Func (Gtk_Widget (Get_User_Data (Widget, Stub)), Data.Data.all);
      end Internal_Func;

      ------------
      -- Forall --
      ------------

      procedure Forall
        (Container : access Gtk_Container_Record;
         Func      : Gtk_Callback;
         Data      : Data_Type)
      is
         procedure Internal
           (Container : System.Address;
            Func      : System.Address;
            Data      : System.Address);
         pragma Import (C, Internal, "gtk_container_forall");
         Local : aliased Data_Type := Data;
         D : aliased Internal_Data := (Local'Unchecked_Access, Func);
      begin
         Internal (Get_Object (Container), Internal_Func'Address, D'Address);
      end Forall;

      -------------
      -- Foreach --
      -------------

      procedure Foreach
        (Container : access Gtk_Container_Record;
         Func      : Gtk_Callback;
         Data      : Data_Type)
      is
         procedure Internal
           (Container : System.Address;
            Func      : System.Address;
            Data      : System.Address);
         pragma Import (C, Internal, "gtk_container_foreach");
         Local : aliased Data_Type := Data;
         D : aliased Internal_Data := (Local'Unchecked_Access, Func);
      begin
         Internal (Get_Object (Container), Internal_Func'Address, D'Address);
      end Foreach;
   end For_Pkg;

   ----------------------
   -- Get_Border_Width --
   ----------------------

   function Get_Border_Width
     (Container : access Gtk_Container_Record) return Guint
   is
      function Internal (Container : System.Address) return Guint;
      pragma Import (C, Internal, "gtk_container_get_border_width");

   begin
      return Internal (Get_Object (Container));
   end Get_Border_Width;

   ------------------
   -- Get_Children --
   ------------------

   function Get_Children
     (Container : access Gtk_Container_Record)
      return Gtk.Widget.Widget_List.Glist
   is
      function Internal (Container : System.Address) return System.Address;
      pragma Import (C, Internal, "gtk_container_get_children");

      List : Gtk.Widget.Widget_List.Glist;

   begin
      Gtk.Widget.Widget_List.Set_Object
        (List, Internal (Get_Object (Container)));
      return List;
   end Get_Children;

   ---------------------
   -- Get_Resize_Mode --
   ---------------------

   function Get_Resize_Mode
     (Container : access Gtk_Container_Record)
      return Gtk_Resize_Mode
   is
      function Internal (Container : System.Address) return Gtk_Resize_Mode;
      pragma Import (C, Internal, "gtk_container_get_resize_mode");

   begin
      return Internal (Get_Object (Container));
   end Get_Resize_Mode;

   ----------------------
   -- Propagate_Expose --
   ----------------------

   procedure Propagate_Expose
     (Container : access Gtk_Container_Record;
      Child     : access Gtk.Widget.Gtk_Widget_Record'Class;
      Event     : Gdk.Event.Gdk_Event_Expose)
   is
      procedure Internal
        (Container : System.Address;
         Child     : System.Address;
         Event     : Gdk.Event.Gdk_Event_Expose);
      pragma Import (C, Internal, "gtk_container_propagate_expose");

   begin
      Internal (Get_Object (Container), Get_Object (Child), Event);
   end Propagate_Expose;

   ------------
   -- Remove --
   ------------

   procedure Remove
     (Container : access Gtk_Container_Record;
      Widget : access Gtk.Widget.Gtk_Widget_Record'Class)
   is
      procedure Internal (Container : System.Address; Widget : System.Address);
      pragma Import (C, Internal, "gtk_container_remove");

   begin
      Internal (Get_Object (Container), Get_Object (Widget));
   end Remove;

   ---------------------
   -- Resize_Children --
   ---------------------

   procedure Resize_Children (Container : access Gtk_Container_Record) is
      procedure Internal (Container : System.Address);
      pragma Import (C, Internal, "gtk_container_resize_children");

   begin
      Internal (Get_Object (Container));
   end Resize_Children;

   ----------------------
   -- Set_Border_Width --
   ----------------------

   procedure Set_Border_Width
     (Container    : access Gtk_Container_Record;
      Border_Width : Guint)
   is
      procedure Internal
        (Container     : System.Address;
         Border_Widget : Guint);
      pragma Import (C, Internal, "gtk_container_set_border_width");

   begin
      Internal (Get_Object (Container), Border_Width);
   end Set_Border_Width;

   ---------------------
   -- Set_Focus_Chain --
   ---------------------

   procedure Set_Focus_Chain
     (Container         : access Gtk_Container_Record;
      Focusable_Widgets : Gtk.Widget.Widget_List.Glist)
   is
      procedure Internal
        (Container         : System.Address;
         Focusable_Widgets : System.Address);
      pragma Import (C, Internal, "gtk_container_set_focus_chain");

      use Gtk.Widget.Widget_List;

   begin
      Internal (Get_Object (Container), Get_Object (Focusable_Widgets));
   end Set_Focus_Chain;

   ---------------------
   -- Get_Focus_Chain --
   ---------------------

   procedure Get_Focus_Chain
     (Container         : access Gtk_Container_Record;
      Focusable_Widgets : out Gtk.Widget.Widget_List.Glist;
      Success           : out Boolean)
   is
      use Widget_List;
      function Internal
        (Container : System.Address;
         List      : access System.Address)
         return Gboolean;
      pragma Import (C, Internal, "gtk_container_get_focus_chain");
      L : aliased System.Address;
   begin
      Success := Boolean'Val (Internal (Get_Object (Container), L'Access));
      Set_Object (Focusable_Widgets, L);
   end Get_Focus_Chain;

   ---------------------
   -- Set_Focus_Child --
   ---------------------

   procedure Set_Focus_Child
     (Container : access Gtk_Container_Record;
      Child     : access Gtk.Widget.Gtk_Widget_Record'Class)
   is
      procedure Internal
        (Container : System.Address;
         Child     : System.Address);
      pragma Import (C, Internal, "gtk_container_set_focus_child");

   begin
      Internal (Get_Object (Container), Get_Object (Child));
   end Set_Focus_Child;

   ---------------------------
   -- Set_Focus_Hadjustment --
   ---------------------------

   procedure Set_Focus_Hadjustment
     (Container  : access Gtk_Container_Record;
      Adjustment : Gtk.Adjustment.Gtk_Adjustment)
   is
      procedure Internal
        (Container  : System.Address;
         Adjustment : System.Address);
      pragma Import (C, Internal, "gtk_container_set_focus_hadjustment");

      use type Gtk.Adjustment.Gtk_Adjustment;

   begin
      if Adjustment = null then
         Internal (Get_Object (Container), System.Null_Address);
      else
         Internal (Get_Object (Container), Get_Object (Adjustment));
      end if;
   end Set_Focus_Hadjustment;

   ---------------------------
   -- Set_Focus_Vadjustment --
   ---------------------------

   procedure Set_Focus_Vadjustment
     (Container  : access Gtk_Container_Record;
      Adjustment : Gtk.Adjustment.Gtk_Adjustment)
   is
      procedure Internal
        (Container  : System.Address;
         Adjustment : System.Address);
      pragma Import (C, Internal, "gtk_container_set_focus_vadjustment");

      use type Gtk.Adjustment.Gtk_Adjustment;

   begin
      if Adjustment = null then
         Internal (Get_Object (Container), System.Null_Address);
      else
         Internal (Get_Object (Container), Get_Object (Adjustment));
      end if;
   end Set_Focus_Vadjustment;

   ----------------------------
   -- Set_Reallocate_Redraws --
   ----------------------------

   procedure Set_Reallocate_Redraws
     (Container : access Gtk_Container_Record;
      Needs_Redraws : Boolean := False)
   is
      procedure Internal
        (Container     : System.Address;
         Needs_Redraws : Gint);
      pragma Import (C, Internal, "gtk_container_set_reallocate_redraws");

   begin
      Internal (Get_Object (Container), Boolean'Pos (Needs_Redraws));
   end Set_Reallocate_Redraws;

   ---------------------
   -- Set_Resize_Mode --
   ---------------------

   procedure Set_Resize_Mode
     (Container   : access Gtk_Container_Record;
      Resize_Mode : Gtk_Resize_Mode)
   is
      procedure Internal
        (Container : System.Address; Mode : Gtk_Resize_Mode);
      pragma Import (C, Internal, "gtk_container_set_resize_mode");

   begin
      Internal (Get_Object (Container), Resize_Mode);
   end Set_Resize_Mode;

   -----------------------
   -- Unset_Focus_Chain --
   -----------------------

   procedure Unset_Focus_Chain (Container : access Gtk_Container_Record) is
      procedure Internal (Container : System.Address);
      pragma Import (C, Internal, "gtk_container_unset_focus_chain");

   begin
      Internal (Get_Object (Container));
   end Unset_Focus_Chain;

   ---------------------
   -- Get_Focus_Child --
   ---------------------

   function Get_Focus_Child
     (Container : access Gtk_Container_Record) return Gtk.Widget.Gtk_Widget
   is
      function Internal (Container : System.Address) return System.Address;
      pragma Import (C, Internal, "ada_gtk_container_get_focus_child");

      Child : constant System.Address := Internal (Get_Object (Container));
   begin
      if Child = System.Null_Address then
         return null;
      else
         return Convert (Child);
      end if;
   end Get_Focus_Child;

   ---------------------------
   -- Get_Focus_Hadjustment --
   ---------------------------

   function Get_Focus_Hadjustment
     (Container : access Gtk_Container_Record)
      return Gtk_Adjustment
   is
      function Internal (Container : System.Address) return System.Address;
      pragma Import (C, Internal, "gtk_container_get_focus_hadjustment");
      Stub : Gtk_Adjustment_Record;
   begin
      return Gtk_Adjustment
        (Get_User_Data (Internal (Get_Object (Container)), Stub));
   end Get_Focus_Hadjustment;

   ---------------------------
   -- Get_Focus_Vadjustment --
   ---------------------------

   function Get_Focus_Vadjustment
     (Container : access Gtk_Container_Record)
      return Gtk_Adjustment
   is
      function Internal (Container : System.Address) return System.Address;
      pragma Import (C, Internal, "gtk_container_get_focus_vadjustment");
      Stub : Gtk_Adjustment_Record;
   begin
      return Gtk_Adjustment
        (Get_User_Data (Internal (Get_Object (Container)), Stub));
   end Get_Focus_Vadjustment;

   -------------------------------
   -- Class_Find_Child_Property --
   -------------------------------

   function Class_Find_Child_Property
     (Cclass        : GObject_Class;
      Property_Name : String)
      return Glib.Param_Spec
   is
      function Internal
        (Cclass        : GObject_Class;
         Property_Name : String)
         return Param_Spec;
      pragma Import (C, Internal, "gtk_container_class_find_child_property");
   begin
      return Internal (Cclass, Property_Name & ASCII.NUL);
   end Class_Find_Child_Property;

   ----------------------------------
   -- Class_Install_Child_Property --
   ----------------------------------

   procedure Class_Install_Child_Property
     (Cclass      : GObject_Class;
      Property_Id : Guint;
      Pspec       : Param_Spec)
   is
      procedure Internal
        (Cclass      : GObject_Class;
         Property_Id : Guint;
         Pspec       : Param_Spec);
      pragma Import
        (C, Internal, "gtk_container_class_install_child_property");
   begin
      Internal (Cclass, Property_Id, Pspec);
   end Class_Install_Child_Property;

   ------------------------
   -- Child_Get_Property --
   ------------------------

   procedure Child_Get_Property
     (Container     : access Gtk_Container_Record;
      Child         : access Gtk_Widget_Record'Class;
      Property_Name : String;
      Value         : out GValue)
   is
      procedure Internal
        (Container     : System.Address;
         Child         : System.Address;
         Property_Name : String;
         Value         : out GValue);
      pragma Import (C, Internal, "gtk_container_child_get_property");
   begin
      Internal (Get_Object (Container), Get_Object (Child),
                Property_Name & ASCII.NUL, Value);
   end Child_Get_Property;

   ------------------------
   -- Child_Set_Property --
   ------------------------

   procedure Child_Set_Property
     (Container     : access Gtk_Container_Record;
      Child         : access Gtk_Widget_Record'Class;
      Property_Name : String;
      Value         : GValue)
   is
      procedure Internal
        (Container     : System.Address;
         Child         : System.Address;
         Property_Name : String;
         Value         : GValue);
      pragma Import (C, Internal, "gtk_container_child_set_property");
   begin
      Internal (Get_Object (Container), Get_Object (Child),
                Property_Name & ASCII.NUL, Value);
   end Child_Set_Property;

   ---------------------------------
   -- Class_List_Child_Properties --
   ---------------------------------

   function Class_List_Child_Properties
     (Cclass : GObject_Class) return Param_Spec_Array
   is
      type Big_Pspec_Array is array (Positive) of Param_Spec;
      type Big_Pspec is access all Big_Pspec_Array;
      pragma Convention (C, Big_Pspec);

      function Internal
        (Cclass       : GObject_Class;
         N_Properties : access Guint) return Big_Pspec;
      pragma Import (C, Internal, "gtk_container_class_list_child_properties");

      Num     : aliased Guint;
      C_Array : constant Big_Pspec := Internal (Cclass, Num'Access);

   begin
      --  Implementation is the same as
      --  Gtk.Widget.Class_List_Style_Properties

      if C_Array = null then
         return (1 .. 0 => null);
      else
         return Param_Spec_Array (C_Array (1 .. Natural (Num)));
      end if;
   end Class_List_Child_Properties;

end Gtk.Container;