1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
|
package Hash::Merge::Simple;
use strict;
use warnings;
our $VERSION = '0.052';
use Exporter ();
our @ISA = qw/ Exporter /;
our @EXPORT_OK = qw/ merge clone_merge dclone_merge /;
# This was stoled from Catalyst::Utils... thanks guys!
sub merge (@);
sub merge (@) {
shift unless ref $_[0]; # Take care of the case we're called like Hash::Merge::Simple->merge(...)
my ($left, @right) = @_;
return $left unless @right;
return merge($left, merge(@right)) if @right > 1;
my ($right) = @right;
my %merge = %$left;
for my $key (keys %$right) {
my ($hr, $hl) = map { ref $_->{$key} eq 'HASH' } $right, $left;
if ($hr and $hl){
$merge{$key} = merge($left->{$key}, $right->{$key});
}
else {
$merge{$key} = $right->{$key};
}
}
return \%merge;
}
sub clone_merge {
require Clone;
my $result = merge @_;
return Clone::clone( $result );
}
sub dclone_merge {
require Storable;
my $result = merge @_;
return Storable::dclone( $result );
}
1;
__END__
=pod
=encoding UTF-8
=for :stopwords Robert Krimen ACKNOWLEDGEMENTS Yuval Kogman Riedel
=head1 NAME
Hash::Merge::Simple - Recursively merge two or more hashes, simply
=head1 SYNOPSIS
use Hash::Merge::Simple qw/ merge /;
my $a = { a => 1 };
my $b = { a => 100, b => 2};
# Merge with righthand hash taking precedence
my $c = merge $a, $b;
# $c is { a => 100, b => 2 } ... Note: a => 100 has overridden => 1
# Also, merge will take care to recursively merge any subordinate hashes found
my $a = { a => 1, c => 3, d => { i => 2 }, r => {} };
my $b = { b => 2, a => 100, d => { l => 4 } };
my $c = merge $a, $b;
# $c is { a => 100, b => 2, c => 3, d => { i => 2, l => 4 }, r => {} }
# You can also merge more than two hashes at the same time
# The precedence increases from left to right (the rightmost has the most precedence)
my $everything = merge $this, $that, $mine, $yours, $kitchen_sink, ...;
=head1 DESCRIPTION
Hash::Merge::Simple will recursively merge two or more hashes and return the result as a new hash reference. The merge function will descend and merge
hashes that exist under the same node in both the left and right hash, but doesn't attempt to combine arrays, objects, scalars, or anything else. The rightmost hash
also takes precedence, replacing whatever was in the left hash if a conflict occurs.
This code was pretty much taken straight from L<Catalyst::Utils>, and modified to handle more than 2 hashes at the same time.
=head1 USAGE
=head2 Hash::Merge::Simple->merge( <hash1>, <hash2>, <hash3>, ..., <hashN> )
=head2 Hash::Merge::Simple::merge( <hash1>, <hash2>, <hash3>, ..., <hashN> )
Merge <hash1> through <hashN>, with the nth-most (rightmost) hash taking precedence.
Returns a new hash reference representing the merge.
NOTE: The code does not currently check for cycles, so infinite loops are possible:
my $a = {};
$a->{b} = $a;
merge $a, $a;
NOTE: If you want to avoid giving/receiving side effects with the merged result, use C<clone_merge> or C<dclone_merge>
An example of this problem (thanks Uri):
my $left = { a => { b => 2 } } ;
my $right = { c => 4 } ;
my $result = merge( $left, $right ) ;
$left->{a}{b} = 3 ;
$left->{a}{d} = 5 ;
# $result->{a}{b} == 3 !
# $result->{a}{d} == 5 !
=head2 Hash::Merge::Simple->clone_merge( <hash1>, <hash2>, <hash3>, ..., <hashN> )
=head2 Hash::Merge::Simple::clone_merge( <hash1>, <hash2>, <hash3>, ..., <hashN> )
Perform a merge, clone the merge, and return the result
This is useful in cases where you need to ensure that the result can be tweaked without fear
of giving/receiving any side effects
This method will use L<Clone> to do the cloning
=head2 Hash::Merge::Simple->dclone_merge( <hash1>, <hash2>, <hash3>, ..., <hashN> )
=head2 Hash::Merge::Simple::dclone_merge( <hash1>, <hash2>, <hash3>, ..., <hashN> )
Perform a merge, clone the merge, and return the result
This is useful in cases where you need to ensure that the result can be tweaked without fear
of giving/receiving any side effects
This method will use L<Storable> (C<dclone>) to do the cloning
=head1 SEE ALSO
L<Hash::Merge>
L<Catalyst::Utils>
L<Clone>
L<Storable>
=head1 ACKNOWLEDGEMENTS
This code was pretty much taken directly from L<Catalyst::Utils>:
Sebastian Riedel C<sri@cpan.org>
Yuval Kogman C<nothingmuch@woobling.org>
=head1 BUGS
Please report any bugs or feature requests on the bugtracker website
L<https://rt.cpan.org/Public/Dist/Display.html?Name=Hash-Merge-Simple> or
by email to
L<bug-Hash-Merge-Simple@rt.cpan.org|mailto:bug-Hash-Merge-Simple@rt.cpan.org>.
When submitting a bug or request, please include a test-file or a
patch to an existing test-file that illustrates the bug or desired
feature.
=head1 AUTHOR
Robert Krimen <robertkrimen@gmail.com>
=head1 CONTRIBUTOR
=for stopwords Graham Knop
Graham Knop <haarg@haarg.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2008 by Robert Krimen.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|
