1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
|
package HTML::FormHandler::Widget::Field::Select;
# ABSTRACT: select field rendering widget
use Moose::Role;
use namespace::autoclean;
use HTML::FormHandler::Render::Util ('process_attrs');
sub render {
my ( $self, $result ) = @_;
$result ||= $self->result;
die "No result for form field '" . $self->full_name . "'. Field may be inactive." unless $result;
my $output = $self->render_element( $result );
return $self->wrap_field( $result, $output );
}
sub render_element {
my ( $self, $result ) = @_;
$result ||= $self->result;
# create select element
my $output = $self->render_select_start( $result );
# create empty select
if( defined $self->empty_select ) {
$output .= $self->render_empty_select;
}
# loop through options
foreach my $option ( @{ $self->{options} } ) {
if ( my $label = $option->{group} ) {
$label = $self->_localize( $label ) if $self->localize_labels;
$output .= qq{\n<optgroup label="$label">};
foreach my $group_opt ( @{ $option->{options} } ) {
$output .= $self->render_option( $group_opt, $result );
}
$output .= qq{\n</optgroup>};
}
else {
$output .= $self->render_option( $option, $result );
}
}
$self->reset_options_index;
$output .= '</select>';
return $output;
}
sub render_select_start {
my ( $self, $result ) = @_;
$result ||= $self->result;
my $id = $self->id;
my $output = '<select name="' . $self->html_name . qq{" id="$id"};
$output .= ' multiple="multiple"' if $self->multiple;
$output .= ' size="' . $self->size . '"' if defined $self->size;
$output .= process_attrs($self->element_attributes($result));
$output .= '>';
return $output;
}
sub render_empty_select {
my $self = shift;
my $label = $self->_localize($self->empty_select);
my $id = $self->id . "." . $self->options_index;
my $output .= qq{\n<option value="" id="$id">$label</option>};
$self->inc_options_index;
return $output;
}
sub render_option {
my ( $self, $option, $result ) = @_;
$result ||= $self->result;
# current values
my $fif = $result->fif;
my %fif_lookup;
@fif_lookup{@$fif} = () if $self->multiple;
# not sure why the value of an option would be undef, but just in case,
# set to empty string because of 'eq' below
my $value = defined $option->{value} ? $option->{value} : '';
my $id = $self->id . '.' . $self->options_index;
my $output .= qq{\n<option value="} . $self->html_filter($value) . '"';
$output .= qq{ id="$id"};
# handle option attributes
my $attrs = $option->{attributes} || {};
if( defined $option->{disabled} && $option->{disabled} ) {
$attrs->{disabled} = 'disabled';
}
if ( defined $fif &&
( ( $self->multiple && exists $fif_lookup{$value} ) ||
( $fif eq $value ) ) ) {
$attrs->{selected} = 'selected';
}
$output .= process_attrs($attrs);
# handle label
my $label = $option->{label};
$label = $self->_localize($label) if $self->localize_labels;
$output .= '>' . ( $self->html_filter($label) ) . '</option>';
$self->inc_options_index;
return $output;
}
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
HTML::FormHandler::Widget::Field::Select - select field rendering widget
=head1 VERSION
version 0.40057
=head1 DESCRIPTION
Renders single and multiple selects. Options hashrefs must
have 'value' and 'label' keys, and may have an 'attributes' key.
See L<HTML::FormHandler::Field::Select> for documentation on
select fields and options.
=head1 NAME
HTML::FormHandler::Widget::Field::Select
=head1 AUTHOR
FormHandler Contributors - see HTML::FormHandler
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2014 by Gerda Shank.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|
