1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
|
package Test::HTML::Tidy5;
use 5.010001;
use warnings;
use strict;
use Test::Builder;
use Exporter;
use HTML::Tidy5;
use parent 'Exporter';
our @EXPORT_OK = qw(
html_tidy_ok
html_fragment_tidy_ok
);
our @EXPORT = @EXPORT_OK;
=head1 NAME
Test::HTML::Tidy5 - Test::More-style wrapper around HTML::Tidy5
=head1 VERSION
Version 1.06
=cut
our $VERSION = '1.06';
my $TB = Test::Builder->new;
=head1 SYNOPSIS
use Test::HTML::Tidy5 tests => 4;
my $table = build_display_table();
html_tidy_ok( $table, 'Built display table properly' );
=head1 DESCRIPTION
This module provides a few convenience methods for testing exception
based code. It is built with L<Test::Builder> and plays happily with
L<Test::More> and friends.
If you are not already familiar with L<Test::More> now would be the time
to go take a look.
=head1 EXPORT
C<html_tidy_ok>
=cut
sub import {
my $self = shift;
my $pack = caller;
$TB->exported_to($pack);
$TB->plan(@_);
$self->export_to_level(1, $self, @EXPORT);
return;
}
=head2 html_tidy_ok( [$tidy, ] $html, $name )
Checks to see if C<$html> is a valid HTML document.
If you pass an HTML::Tidy5 object, C<html_tidy_ok()> will use that for its
settings.
my $tidy = HTML::Tidy5->new( {config_file => 'path/to/config'} );
$tidy->ignore( type => TIDY_WARNING, type => TIDY_INFO );
html_tidy_ok( $tidy, $content, "Web page is OK, ignoring warnings and info' );
Otherwise, it will use the default rules.
html_tidy_ok( $content, "Web page passes ALL tests" );
=cut
sub html_tidy_ok {
my $tidy = (ref($_[0]) eq 'HTML::Tidy5') ? shift : HTML::Tidy5->new;
my $html = shift;
my $name = shift;
my $ok = defined $html;
if ( !$ok ) {
$TB->ok( 0, $name );
$TB->diag( 'Error: html_tidy_ok() got undef' );
}
else {
$ok = _parse_and_complain( $tidy, $html, $name, 0 );
}
return $ok;
}
=head2 html_fragment_tidy_ok( [$tidy, ] $html, $name )
Works the same as C<html_tidy_ok>, but first wraps it up an HTML document.
This is useful for when want to validate self-contained snippets of HTML,
such as from templates or an HTML feed from a third party, and check
that it is valid.
=cut
sub html_fragment_tidy_ok {
my $tidy = (ref($_[0]) eq 'HTML::Tidy5') ? shift : HTML::Tidy5->new;
my $html = shift;
my $name = shift;
my $ok = defined $html;
if ( !$ok ) {
$TB->ok( 0, $name );
$TB->diag( 'Error: html_fragment_tidy_ok() got undef' );
}
else {
$html = <<"HTML";
<!DOCTYPE html>
<html>
<head>
<title> </title>
</head>
<body>
$html
</body>
</html>
HTML
$ok = _parse_and_complain( $tidy, $html, $name, 6 );
}
return $ok;
}
sub _parse_and_complain {
local $Test::Builder::Level = $Test::Builder::Level + 1;
my $tidy = shift;
my $html = shift;
my $name = shift;
my $offset = shift;
$tidy->clear_messages();
$tidy->parse( undef, $html );
my @messages = $tidy->messages;
my $nmessages = @messages;
my $ok = !$nmessages;
$TB->ok( $ok, $name );
if ( !$ok ) {
if ( $offset ) {
$_->{_line} -= $offset for @messages;
}
my $msg = 'Errors:';
$msg .= " $name" if $name;
$TB->diag( $msg );
$TB->diag( $_->as_string ) for @messages;
my $s = $nmessages == 1 ? '' : 's';
$TB->diag( "$nmessages message$s on the page" );
}
return $ok;
}
=head1 BUGS
All bugs and requests are now being handled through GitHub.
https://github.com/petdance/html-lint/issues
DO NOT send bug reports to http://rt.cpan.org/.
=head1 COPYRIGHT & LICENSE
Copyright 2005-2018 Andy Lester.
This program is free software; you can redistribute it and/or modify
it under the terms of the Artistic License v2.0.
http://www.opensource.org/licenses/Artistic-2.0
Please note that these modules are not products of or supported by the
employers of the various contributors to the code.
=head1 AUTHOR
Andy Lester, C<andy@petdance.com>
=cut
1;
|
