1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
|
project('libjcat', 'c',
version : '0.2.5',
license : 'LGPL-2.1+',
meson_version : '>=0.56.0',
default_options : ['warning_level=2', 'c_std=c99'],
)
libjcat_version = meson.project_version()
varr = libjcat_version.split('.')
libjcat_major_version = varr[0]
libjcat_minor_version = varr[1]
libjcat_micro_version = varr[2]
conf = configuration_data()
conf.set('JCAT_MAJOR_VERSION', libjcat_major_version)
conf.set('JCAT_MINOR_VERSION', libjcat_minor_version)
conf.set('JCAT_MICRO_VERSION', libjcat_micro_version)
conf.set_quoted('PACKAGE_VERSION', libjcat_version)
# libtool versioning - this applies to libjcat
lt_current = '1'
lt_revision = '0'
lt_age = '0'
lt_version = '@0@.@1@.@2@'.format(lt_current, lt_age, lt_revision)
configinc = include_directories('.')
# get supported warning flags
warning_flags = [
'-Wfatal-errors',
'-Wno-nonnull-compare',
'-Waggregate-return',
'-Wunused',
'-Warray-bounds',
'-Wcast-align',
'-Wclobbered',
'-Wdeclaration-after-statement',
'-Wduplicated-branches',
'-Wduplicated-cond',
'-Wempty-body',
'-Wformat=2',
'-Wformat-nonliteral',
'-Wformat-security',
'-Wformat-signedness',
'-Wignored-qualifiers',
'-Wimplicit-function-declaration',
'-Wincompatible-pointer-types-discards-qualifiers',
'-Winit-self',
'-Wlogical-op',
'-Wmaybe-uninitialized',
'-Wmissing-declarations',
'-Wmissing-format-attribute',
'-Wmissing-include-dirs',
'-Wmissing-noreturn',
'-Wmissing-parameter-type',
'-Wmissing-prototypes',
'-Wnested-externs',
'-Wno-cast-function-type',
'-Wno-error=cpp',
'-Wno-unknown-pragmas',
'-Wno-discarded-qualifiers',
'-Wno-missing-field-initializers',
'-Wno-strict-aliasing',
'-Wno-suggest-attribute=format',
'-Wno-unused-parameter',
'-Wnull-dereference',
'-Wold-style-definition',
'-Woverride-init',
'-Wpointer-arith',
'-Wredundant-decls',
'-Wreturn-type',
'-Wshadow',
'-Wsign-compare',
'-Wstrict-aliasing',
'-Wstrict-prototypes',
'-Wswitch-default',
'-Wtype-limits',
'-Wundef',
'-Wuninitialized',
'-Wunused-but-set-variable',
'-Wunused-variable',
'-Wwrite-strings'
]
cc = meson.get_compiler('c')
add_project_arguments(cc.get_supported_arguments(warning_flags), language : 'c')
if not meson.is_cross_build()
add_project_arguments('-fstack-protector-strong', language : 'c')
endif
# enable full RELRO where possible
# FIXME: until https://github.com/mesonbuild/meson/issues/1140 is fixed
global_link_args = []
test_link_args = [
'-Wl,-z,relro',
'-Wl,-z,now',
]
foreach link_arg: test_link_args
if cc.has_link_argument(link_arg)
global_link_args += link_arg
endif
endforeach
add_project_link_arguments(
global_link_args,
language: 'c'
)
prefix = get_option('prefix')
if host_machine.system() == 'windows'
bindir = get_option('bindir')
libexecdir = get_option('libexecdir')
localstatedir = get_option('localstatedir')
installed_test_bindir = get_option('libexecdir')
installed_test_datadir = get_option('datadir')
else
bindir = join_paths(prefix, get_option('bindir'))
datadir = join_paths(prefix, get_option('datadir'))
localstatedir = join_paths(prefix, get_option('localstatedir'))
libexecdir = join_paths(prefix, get_option('libexecdir'))
installed_test_bindir = join_paths(libexecdir, 'installed-tests', meson.project_name())
installed_test_datadir = join_paths(datadir, 'installed-tests', meson.project_name())
endif
mandir = join_paths(prefix, get_option('mandir'))
localedir = join_paths(prefix, get_option('localedir'))
diffcmd = find_program('diff')
gio = dependency('gio-2.0', version : '>= 2.45.8')
giounix = dependency('gio-unix-2.0', version : '>= 2.45.8', required: false)
if giounix.found()
conf.set('HAVE_GIO_UNIX', '1')
endif
libjsonglib = dependency('json-glib-1.0', version : '>= 1.1.1', fallback : ['json-glib', 'json_glib_dep'])
libjcat_deps = [
gio,
libjsonglib,
]
if get_option('gnutls_pkcs7')
gnutls = dependency('gnutls', version : '>= 3.6.0')
conf.set('HAVE_PKCS7', '1')
conf.set('HAVE_GNUTLS_PKCS7', '1')
if cc.has_header_symbol('gnutls/gnutls.h', 'GNUTLS_SIGN_MLDSA87', dependencies: gnutls)
conf.set('HAVE_GNUTLS_PQC', '1')
endif
libjcat_deps += gnutls
summary({
'gnutls': gnutls.version(),
}, section: 'Dependencies')
endif
if get_option('openssl_pkcs7')
libcrypto = dependency('libcrypto')
conf.set('HAVE_PKCS7', '1')
conf.set('HAVE_LIBCRYPTO_PKCS7', '1')
libjcat_deps += libcrypto
endif
if get_option('gnutls_ed25519')
conf.set('HAVE_ED25519', '1')
conf.set('HAVE_GNUTLS_ED25519', '1')
libjcat_deps += dependency('gnutls')
endif
if get_option('gpg')
gpgme = cc.find_library('gpgme')
gpgerror = cc.find_library('gpg-error')
conf.set('ENABLE_GPG', '1')
libjcat_deps += gpgme
libjcat_deps += gpgerror
endif
gnome = import('gnome')
conf.set('installed_test_bindir', installed_test_bindir)
conf.set('installed_test_datadir', installed_test_datadir)
conf.set_quoted('PACKAGE_NAME', meson.project_name())
conf.set_quoted('GETTEXT_PACKAGE', meson.project_name())
conf.set_quoted('JCAT_LOCALSTATEDIR', localstatedir)
conf.set_quoted('JCAT_LOCALEDIR', localedir)
conf.set_quoted('G_LOG_DOMAIN', 'Jcat')
conf.set_quoted('VERSION', meson.project_version())
configure_file(
output : 'config.h',
configuration : conf
)
subdir('data')
subdir('libjcat')
if get_option('gtkdoc')
gtkdocscan = find_program('gtkdoc-scan', required : true)
subdir('docs')
endif
|
