File: versioning.t

package info (click to toggle)
libkiokudb-perl 0.57-3
  • links: PTS, VCS
  • area: main
  • in suites: bookworm, forky, sid, trixie
  • size: 1,396 kB
  • sloc: perl: 13,314; makefile: 12
file content (142 lines) | stat: -rw-r--r-- 3,894 bytes parent folder | download | duplicates (3)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
#!/usr/bin/perl

use strict;
use warnings;

use Test::More;
use Test::Exception;

use KiokuDB;

{
    package KiokuDB_Test_VersionedPerson;
    use Moose;

    extends qw(KiokuDB::Test::Person);

    with qw(KiokuDB::Role::Upgrade::Handlers::Table);

    use constant kiokudb_upgrade_handlers_table => {

        # like the individual entries in class_version_table

        "0.01" => "0.02",
        "0.02" => sub {
            my ( $class, %args ) = @_;

            $args{entry}->derive(
                class_version => "0.03",
                data => {
                    %{ $args{entry}->data },
                    name => "new name",
                },
            );
        },
    };
}

foreach my $format ( qw(memory storable json), eval { require YAML::XS; "yaml" } ) {
    my $dir = KiokuDB->connect("hash",
        check_class_versions => 1,
        serializer           => $format,
    );

    local $KiokuDB_Test_VersionedPerson::VERSION = "0.01";

    $dir->txn_do( scope => 1, body => sub {
        my $p = KiokuDB_Test_VersionedPerson->new(
            name => "blah blah",
        );

        $dir->insert( person => $p );

        is( $dir->live_objects->object_to_entry($p)->class_version, $KiokuDB_Test_VersionedPerson::VERSION, "Class version set" );
    });

    $dir->typemap_resolver->clear_compiled;
    KiokuDB::TypeMap::Entry::MOP->clear_version_cache;

    $dir->txn_do( scope => 1, body => sub {
        my $p = $dir->lookup("person");

        is( $p->name, "blah blah", "no upgrade" );

        is( $dir->live_objects->object_to_entry($p)->class_version, $KiokuDB_Test_VersionedPerson::VERSION, "Class version set" );

        $dir->update($p);
    });

    $dir->typemap_resolver->clear_compiled;
    KiokuDB::TypeMap::Entry::MOP->clear_version_cache;

    local $KiokuDB_Test_VersionedPerson::VERSION = "0.02";

    $dir->txn_do( scope => 1, body => sub {
        my $p = $dir->lookup("person");

        is( $p->name, "blah blah", "upgrade to 0.02 is noop" );

        is( $dir->live_objects->object_to_entry($p)->class_version, "0.01", "Class version not changed due to noop" );

        $dir->update($p);
    });

    $dir->typemap_resolver->clear_compiled;
    KiokuDB::TypeMap::Entry::MOP->clear_version_cache;

    $dir->txn_do( scope => 1, body => sub {
        my $p = $dir->lookup("person");

        is( $p->name, "blah blah", "upgrade to 0.02 is noop" );

        is( $dir->live_objects->object_to_entry($p)->class_version, $KiokuDB_Test_VersionedPerson::VERSION, "Class version updated in storage" );
    });

    $dir->typemap_resolver->clear_compiled;
    KiokuDB::TypeMap::Entry::MOP->clear_version_cache;

    local $KiokuDB_Test_VersionedPerson::VERSION = "0.03";

    $dir->txn_do( scope => 1, body => sub {
        my $p = $dir->lookup("person");

        is( $p->name, "new name", "class upgraded to 0.03" );

        is( $dir->live_objects->object_to_entry($p)->class_version, $KiokuDB_Test_VersionedPerson::VERSION, "Class version set" );

        $p->name("foobar");

        $dir->update($p);
    });

    $dir->typemap_resolver->clear_compiled;
    KiokuDB::TypeMap::Entry::MOP->clear_version_cache;

    $dir->txn_do( scope => 1, body => sub {
        my $p = $dir->lookup("person");

        is( $p->name, "foobar", "upgrade handler did not fire twice" );

        is( $dir->live_objects->object_to_entry($p)->class_version, $KiokuDB_Test_VersionedPerson::VERSION, "Class version set" );

        $dir->update($p);
    });

    $dir->typemap_resolver->clear_compiled;
    KiokuDB::TypeMap::Entry::MOP->clear_version_cache;

    local $KiokuDB_Test_VersionedPerson::VERSION = "0.04";

    throws_ok {
        $dir->txn_do( scope => 1, body => sub {
            $dir->lookup("person");
        });
    } qr/0\.03/, "no handler for 0.03";

    KiokuDB::TypeMap::Entry::MOP->clear_version_cache;
}

done_testing;

# ex: set sw=4 et: