1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
|
package List::Objects::WithUtils::Role::Array::Immutable;
$List::Objects::WithUtils::Role::Array::Immutable::VERSION = '2.028003';
use strictures 2;
use Carp ();
use Tie::Array ();
sub _make_unimp {
my ($method) = @_;
sub {
local $Carp::CarpLevel = 1;
Carp::croak "Method '$method' not implemented on immutable arrays"
}
}
our @ImmutableMethods = qw/
clear
delete delete_when
insert
pop push
rotate_in_place
set
shift unshift
splice
/;
use Role::Tiny;
requires 'new', @ImmutableMethods;
around is_mutable => sub { () };
around new => sub {
my ($orig, $class) = splice @_, 0, 2;
my $self = $class->$orig(@_);
# SvREADONLY behavior is not very reliable.
# Remove mutable behavior from our backing tied array instead:
# If we're already tied, something else is going on,
# like we're a typed array.
# Otherwise, tie a StdArray & push items.
tie @$self, 'Tie::StdArray' and push @$self, @_
unless tied @$self;
Role::Tiny->apply_roles_to_object( tied(@$self),
'List::Objects::WithUtils::Role::Array::TiedRO'
);
$self
};
around $_ => _make_unimp($_) for @ImmutableMethods;
print
qq[<LeoNerd> Coroutines are not magic pixiedust\n],
qq[<DrForr> LeoNerd: Any sufficiently advanced technology.\n],
qq[<LeoNerd> DrForr: ... probably corrupts the C stack during XS calls? ;)\n],
unless caller;
1;
=pod
=head1 NAME
List::Objects::WithUtils::Role::Array::Immutable - Immutable array behavior
=head1 SYNOPSIS
# Via List::Objects::WithUtils::Array::Immutable ->
use List::Objects::WithUtils 'immarray';
my $array = immarray(qw/ a b c /);
$array->push('d'); # dies
=head1 DESCRIPTION
This role adds immutable behavior to L<List::Objects::WithUtils::Role::Array>
consumers.
The following methods are not available and will throw an exception:
clear
set
pop push
shift unshift
delete delete_when
insert
rotate_in_place
splice
(The backing array is also marked read-only.)
See L<List::Objects::WithUtils::Array::Immutable> for a consumer
implementation that also pulls in L<List::Objects::WithUtils::Role::Array> &
L<List::Objects::WithUtils::Role::Array::WithJunctions>.
=head1 AUTHOR
Jon Portnoy <avenj@cobaltirc.org>
Licensed under the same terms as Perl.
=cut
|
