1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
|
=head1 NAME
Log::Handler::Output::Forward - Forward messages to routines.
=head1 SYNOPSIS
use Log::Handler::Output::Forward;
my $forwarder = Log::Handler::Output::Forward->new(
forward_to => sub { },
arguments => [ "foo" ],
);
$forwarder->log(message => $message);
=head1 DESCRIPTION
This output module makes it possible to forward messages to sub routines.
=head1 METHODS
=head2 new()
Call C<new()> to create a new Log::Handler::Output::Forward object.
The following options are possible:
=over 4
=item B<forward_to>
This option excepts a code reference.
Please note that the message is forwarded as a hash reference. If you change it
then this would have an effect to all outputs.
=item B<arguments>
With this option you can define arguments that will be passed to the sub
routine.
In the following example the arguments would be passed as a array to
C<Class::method()>.
my $forwarder = Log::Handler::Output::Forward->new(
forward_to => \&Class::method,
arguments => [ $self, "foo" ],
);
This would call intern:
Class::method(@arguments, $message);
If this option is not set then the message will be passed as first argument.
=back
=head2 log()
Call C<log()> if you want to forward messages to the subroutines.
Example:
$forwarder->log("this message will be forwarded to all sub routines");
=head2 validate()
Validate a configuration.
=head2 reload()
Reload with a new configuration.
=head2 errstr()
This function returns the last error message.
=head1 FORWARDED MESSAGE
Note that the message will be forwarded as a hash reference.
If you make changes to the reference it affects all other outputs.
The hash key C<message> contains the message.
=head1 PREREQUISITES
Carp
Params::Validate
=head1 EXPORTS
No exports.
=head1 REPORT BUGS
Please report all bugs to <jschulz.cpan(at)bloonix.de>.
If you send me a mail then add Log::Handler into the subject.
=head1 AUTHOR
Jonny Schulz <jschulz.cpan(at)bloonix.de>.
=head1 COPYRIGHT
Copyright (C) 2007-2009 by Jonny Schulz. All rights reserved.
This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.
=cut
package Log::Handler::Output::Forward;
use strict;
use warnings;
use Carp;
use Params::Validate qw();
our $VERSION = "0.03";
our $ERRSTR = "";
sub new {
my $class = shift;
my $options = $class->_validate(@_);
return bless $options, $class;
}
sub log {
my $self = shift;
my $coderef = $self->{forward_to};
my $message = @_ > 1 ? {@_} : shift;
if ($self->{arguments}) {
eval { &$coderef(@{$self->{arguments}}, $message) };
} else {
eval { &$coderef($message) };
}
if ($@) {
return $self->_raise_error($@);
}
return 1;
}
sub validate {
my $self = shift;
my $opts = ();
eval { $opts = $self->_validate(@_) };
if ($@) {
$ERRSTR = $@;
return undef;
}
return $opts;
}
sub reload {
my $self = shift;
my $opts = $self->validate(@_);
if (!$opts) {
return undef;
}
foreach my $key (keys %$opts) {
$self->{$key} = $opts->{$key};
}
return 1;
}
sub errstr {
return $ERRSTR;
}
#
# private stuff
#
sub _validate {
my $class = shift;
my %options = Params::Validate::validate(@_, {
forward_to => {
type => Params::Validate::CODEREF,
},
arguments => {
type => Params::Validate::ARRAYREF
| Params::Validate::SCALAR,
optional => 1,
},
});
if (defined $options{arguments} && !ref($options{arguments})) {
$options{arguments} = [ $options{arguments} ];
}
return \%options;
}
sub _raise_error {
my $self = shift;
$ERRSTR = shift;
return undef;
}
1;
|
