1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
|
package Mail::Box::Mbox;
use vars '$VERSION';
$VERSION = '2.068';
use base 'Mail::Box::File';
use strict;
use filetest 'access';
use Mail::Box::Mbox::Message;
our $default_folder_dir = exists $ENV{HOME} ? $ENV{HOME} . '/Mail' : '.';
our $default_sub_extension = '.d';
sub init($)
{ my ($self, $args) = @_;
$self->{MBM_sub_ext} # required during init
= $args->{subfolder_extension} || $default_sub_extension;
$self->SUPER::init($args);
}
#-------------------------------------------
sub create($@)
{ my ($thingy, $name, %args) = @_;
my $class = ref $thingy || $thingy;
$args{folderdir} ||= $default_folder_dir;
$args{subfolder_extension} ||= $default_sub_extension;
$class->SUPER::create($name, %args);
}
#-------------------------------------------
sub foundIn($@)
{ my $class = shift;
my $name = @_ % 2 ? shift : undef;
my %args = @_;
$name ||= $args{folder} or return;
my $folderdir = $args{folderdir} || $default_folder_dir;
my $extension = $args{subfolder_extension} || $default_sub_extension;
my $filename = $class->folderToFilename($name, $folderdir, $extension);
if(-d $filename) # fake empty folder, with sub-folders
{ return 1 unless -f File::Spec->catfile($filename, '1') # MH
|| -d File::Spec->catdir($filename, 'cur'); # Maildir
}
return 0 unless -f $filename;
return 1 if -z $filename; # empty folder is ok
open my $file, '<', $filename or return 0;
local $_;
while(<$file>)
{ next if /^\s*$/; # skip empty lines
$file->close;
return substr($_, 0, 5) eq 'From '; # found Mbox separator?
}
return 1;
}
#-------------------------------------------
sub delete(@)
{ my $self = shift;
$self->SUPER::delete(@_);
my $subfdir = $self->filename . $default_sub_extension;
rmdir $subfdir; # may fail, when there are still subfolders (no recurse)
}
#-------------------------------------------
sub writeMessages($)
{ my ($self, $args) = @_;
$self->SUPER::writeMessages($args) or return;
if($self->{MB_remove_empty})
{ # Can the sub-folder directory be removed? Don't mind if this
# doesn't work: probably no subdir or still something in it. This
# is a rather blunt approach...
rmdir $self->filename . $self->{MBM_sub_ext};
}
$self;
}
#-------------------------------------------
sub type() {'mbox'}
#-------------------------------------------
sub listSubFolders(@)
{ my ($thingy, %args) = @_;
my $class = ref $thingy || $thingy;
my $skip_empty = $args{skip_empty} || 0;
my $check = $args{check} || 0;
my $folder = exists $args{folder} ? $args{folder} : '=';
my $folderdir = exists $args{folderdir}
? $args{folderdir}
: $default_folder_dir;
my $extension = $args{subfolder_extension};
my $dir;
if(ref $thingy) # Mail::Box::Mbox
{ $extension ||= $thingy->{MBM_sub_ext};
$dir = $thingy->filename;
}
else
{ $extension ||= $default_sub_extension;
$dir = $class->folderToFilename($folder, $folderdir, $extension);
}
my $real = -d $dir ? $dir : "$dir$extension";
return () unless opendir DIR, $real;
# Some files have to be removed because they are created by all
# kinds of programs, but are no folders.
my @entries = grep { ! m/\.lo?ck$/ && ! m/^\./ } readdir DIR;
closedir DIR;
# Look for files in the folderdir. They should be readable to
# avoid warnings for usage later. Furthermore, if we check on
# the size too, we avoid a syscall especially to get the size
# of the file by performing that check immediately.
my %folders; # hash to immediately un-double names.
foreach (@entries)
{ my $entry = File::Spec->catfile($real, $_);
next unless -r $entry;
if( -f _ )
{ next if $args{skip_empty} && ! -s _;
next if $args{check} && !$class->foundIn($entry);
$folders{$_}++;
}
elsif( -d _ )
{ # Directories may create fake folders.
if($args{skip_empty})
{ opendir DIR, $entry or next;
my @sub = grep !/^\./, readdir DIR;
closedir DIR;
next unless @sub;
}
(my $folder = $_) =~ s/$extension$//;
$folders{$folder}++;
}
}
map { m/(.*)/ && $1 } keys %folders; # untained names
}
#-------------------------------------------
sub folderToFilename($$;$)
{ my ($thingy, $name, $folderdir, $extension) = @_;
$extension ||=
ref $thingy ? $thingy->{MBM_sub_ext} : $default_sub_extension;
$name =~ s#^=#$folderdir/#;
my @parts = split m!/!, $name;
my $real = shift @parts;
$real = '/' if $real eq '';
if(@parts)
{ my $file = pop @parts;
$real = File::Spec->catdir($real.(-d $real ? '' : $extension), $_)
foreach @parts;
$real = File::Spec->catfile($real.(-d $real ? '' : $extension), $file);
}
$real;
}
#-------------------------------------------
1;
|
