1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
|
# This code is part of Perl distribution Mail-Box version 4.01.
# The POD got stripped from this file by OODoc version 3.05.
# For contributors see file ChangeLog.
# This software is copyright (c) 2001-2025 by Mark Overmeer.
# This is free software; you can redistribute it and/or modify it under
# the same terms as the Perl 5 programming language system itself.
# SPDX-License-Identifier: Artistic-1.0-Perl OR GPL-1.0-or-later
package Mail::Box::Dir::Message;{
our $VERSION = '4.01';
}
use parent 'Mail::Box::Message';
use strict;
use warnings;
use Log::Report 'mail-box', import => [ qw/__x error fault trace/ ];
use File::Copy qw/move/;
#--------------------
sub init($)
{ my ($self, $args) = @_;
$self->SUPER::init($args);
$self->filename($args->{filename}) if $args->{filename};
$self->{MBDM_fix_header} = $args->{fix_header};
$self;
}
#--------------------
sub filename(;$)
{ my $self = shift;
@_ ? ($self->{MBDM_filename} = shift) : $self->{MBDM_filename};
}
sub fixHeader() { $_[0]->{MBDM_fix_header} }
#--------------------
sub print(;$)
{ my $self = shift;
my $out = shift || select;
return $self->SUPER::print($out)
if $self->isModified;
my $filename = $self->filename;
if($filename && -r $filename)
{ if(open my $in, '<:raw', $filename)
{ local $_;
print $out $_ while <$in>;
close $in;
return $self;
}
}
$self->SUPER::print($out);
1;
}
BEGIN { *write = \&print } # simply alias
#--------------------
# Asking the filesystem for the size is faster counting (in
# many situations. It even may be lazy.
sub size()
{ my $self = shift;
unless($self->isModified)
{ my $filename = $self->filename;
if(defined $filename)
{ my $size = -s $filename;
return $size if defined $size;
}
}
$self->SUPER::size;
}
sub diskDelete()
{ my $self = shift;
$self->SUPER::diskDelete;
my $filename = $self->filename;
unlink $filename if $filename;
$self;
}
sub parser()
{ my $self = shift;
Mail::Box::Parser->new(
filename => $self->filename,
mode => 'r',
fix_header_errors => $self->fixHeader,
);
}
sub loadHead()
{ my $self = shift;
my $head = $self->head;
$head->isDelayed or return $head;
my $folder = $self->folder;
$folder->lazyPermitted(1);
my $parser = $self->parser or return;
$self->readFromParser($parser);
$parser->stop;
$folder->lazyPermitted(0);
trace "Loaded delayed head.";
$self->head;
}
sub loadBody()
{ my $self = shift;
my $body = $self->body;
$body->isDelayed or return $body;
my $parser = $self->parser;
my $msgid = $self->messageId;
my $head = $self->head;
if($head->isDelayed)
{ $head = $self->readHead($parser)
or error __x"unable to read delayed head for message {msgid}.", msgid => $msgid;
trace "Loaded delayed head for $msgid.";
$self->head($head);
}
else
{ my ($begin, $end) = $body->fileLocation;
$parser->filePosition($begin);
}
my $newbody = $self->readBody($parser, $head)
or error __x"unable to read delayed body for message {msgid}.", msgid => $msgid;
$parser->stop;
trace "Loaded delayed body for $msgid";
$self->storeBody($newbody->contentInfoFrom($head));
}
sub create($)
{ my ($self, $filename) = @_;
my $old = $self->filename || '';
return $self if $filename eq $old && !$self->isModified;
# Write the new data to a new file.
my $new = $filename . '.new';
open my $newfh, '>:raw', $new
or fault __x"cannot write message to {file}", file => $new;
$self->write($newfh);
$newfh->close;
unlink $old if $old;
move $new, $filename
or error __x"failed to rename file {from} to {to}", from => $new, to => $filename;
$self->modified(0);
# Do not affect flags for Maildir (and some other) which keep it
# in there. Flags will be processed later.
$self->Mail::Box::Dir::Message::filename($filename);
$self;
}
1;
|
