File: test_canonicalization.pl

package info (click to toggle)
libmail-dkim-perl 0.54-1
  • links: PTS, VCS
  • area: main
  • in suites: bullseye, buster
  • size: 1,412 kB
  • sloc: perl: 5,855; makefile: 10
file content (83 lines) | stat: -rwxr-xr-x 1,484 bytes parent folder | download | duplicates (7)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
#!/usr/bin/perl -I../../..

use strict;
use warnings;

use Getopt::Long;

my $headers;
GetOptions(
		"headers=s" => \$headers
	) or die "Error: invalid argument(s)\n";

my $canon_method = $ARGV[0]
	or die "Error: no canonicalization method specified\n";

use Mail::DKIM::Canonicalization::nowsp;
use Mail::DKIM::Canonicalization::relaxed;
use Mail::DKIM::Canonicalization::simple;
use Mail::DKIM::Signature;

my $crlf = "\015\012";

# read in headers
my @headers;
my @header_names;
while (<STDIN>)
{
	# standardize line terminators
	chomp;
	$_ .= $crlf;

	last if ($_ eq $crlf);

	if (/^\s/ && @headers)
	{
		# continues last header
		$headers[@headers - 1] .= $_;
	}
	else
	{
		# starts a new header
		push @headers, $_;
		if (/^(\S[^:\s]*)\s*:/)
		{
			push @header_names, $1;
		}
	}
}

# determine value of h= tag
unless (defined $headers)
{
	$headers = join(":", @header_names);
}

# create a dummy signature
my $signature = new Mail::DKIM::Signature(
		Algorithm => "rsa-sha1",
		Method => $canon_method,
		Domain => "example.org",
		Selector => "selector");
$signature->headerlist($headers);

# create a canonicalization object
my $canon_class = "Mail::DKIM::Canonicalization::$canon_method";
my $can = $canon_class->new(
				Signature => $signature,
				output_fh => *STDOUT);

# repeat the headers
foreach my $header (@headers)
{
	$can->add_header($header);
}
$can->finish_header;

# read the body
while (<STDIN>)
{
	chomp;
	$can->add_body("$_\015\012");
}
$can->finish_body;