1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
|
# Copyrights 2001-2025 by [Mark Overmeer <markov@cpan.org>].
# For other contributors see ChangeLog.
# See the manual pages for details on the licensing terms.
# Pod stripped from pm file by OODoc 2.03.
# This code is part of distribution Mail-Message. Meta-POD processed with
# OODoc into POD and HTML manual-pages. See README.md
# Copyright Mark Overmeer. Licensed under the same terms as Perl itself.
package Mail::Message::Body::Lines;{
our $VERSION = '3.017';
}
use base 'Mail::Message::Body';
use strict;
use warnings;
use Mail::Box::Parser;
use IO::Lines;
use Carp;
sub _data_from_filename(@)
{ my ($self, $filename) = @_;
local *IN;
unless(open IN, '<', $filename)
{ $self->log(ERROR =>
"Unable to read file $filename for message body lines: $!");
return;
}
$self->{MMBL_array} = [ <IN> ];
close IN;
$self;
}
sub _data_from_filehandle(@)
{ my ($self, $fh) = @_;
$self->{MMBL_array} =
ref $fh eq 'Mail::Box::FastScalar' ? $fh->getlines : [ $fh->getlines ];
$self
}
sub _data_from_glob(@)
{ my ($self, $fh) = @_;
$self->{MMBL_array} = [ <$fh> ];
$self;
}
sub _data_from_lines(@)
{ my ($self, $lines) = @_;
$lines = [ split /^/, $lines->[0] ] # body passed in one string.
if @$lines==1;
$self->{MMBL_array} = $lines;
$self;
}
#------------------------------------------
sub clone()
{ my $self = shift;
ref($self)->new(data => [ $self->lines ], based_on => $self);
}
#------------------------------------------
sub nrLines() { scalar @{shift->{MMBL_array}} }
#------------------------------------------
# Optimized to be computed only once.
sub size()
{ my $self = shift;
return $self->{MMBL_size} if exists $self->{MMBL_size};
my $size = 0;
$size += length $_ foreach @{$self->{MMBL_array}};
$self->{MMBL_size} = $size;
}
#------------------------------------------
sub string() { join '', @{shift->{MMBL_array}} }
#------------------------------------------
sub lines() { wantarray ? @{shift->{MMBL_array}} : shift->{MMBL_array} }
#------------------------------------------
sub file() { IO::Lines->new(shift->{MMBL_array}) }
#------------------------------------------
sub print(;$)
{ my $self = shift;
my $fh = shift || select;
if(ref $fh eq 'GLOB') { print $fh @{$self->{MMBL_array}} }
else { $fh->print(@{$self->{MMBL_array}}) }
$self;
}
#------------------------------------------
sub read($$;$@)
{ my ($self, $parser, $head, $bodytype) = splice @_, 0, 4;
my ($begin, $end, $lines) = $parser->bodyAsList(@_);
$lines or return undef;
$self->fileLocation($begin, $end);
$self->{MMBL_array} = $lines;
$self;
}
#------------------------------------------
sub endsOnNewline()
{ my $last = shift->{MMBL_array}[-1];
!defined $last || $last =~ m/\n$/;
}
#------------------------------------------
1;
|
