1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
|
/*
* Copyright (C) 1999, 2002, 2003, 2004, 2005, 2006 Free Software
* Foundation, Inc.
*
* This file is part of GNU libmatheval
*
* GNU libmatheval is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2, or (at your option)
* any later version.
*
* GNU libmatheval is distributed in the hope that it will be useful, but
* WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* General Public License for more details.
*
* You should have received a copy of the GNU General Public License along
* with program; see the file COPYING. If not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301,
* USA.
*/
%{
/*
* Copyright (C) 1999, 2002, 2003, 2004, 2005, 2006 Free Software
* Foundation, Inc.
*
* This file is part of GNU libmatheval
*
* GNU libmatheval is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2, or (at your option)
* any later version.
*
* GNU libmatheval is distributed in the hope that it will be useful, but
* WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* General Public License for more details.
*
* You should have received a copy of the GNU General Public License along
* with program; see the file COPYING. If not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301,
* USA.
*/
#if HAVE_CONFIG_H
# include "config.h"
#endif
#include <stdlib.h>
#include "node.h"
/* Variables used to communicate with code using parser. */
extern Node* root; /* Root of tree representation of function. */
extern SymbolTable *symbol_table; /* Evaluator symbol table. */
extern int ok; /* Flag representing success of parsing. */
/* Report parsing error. */
int yyerror (char *s);
/* Function used to tokenize string representing function (this function
* is generated by scanner generator). */
extern int yylex (void);
/* Function used to reset string representing function (this function is
* generated by scanner generator). */
extern void input_reset (void);
%}
/* Parser semantic values type. */
%union {
Node *node;
Record *record;
}
/* Grammar terminal symbols. */
%token <node> NUMBER CONSTANT VARIABLE
%token <record> FUNCTION
%left '-' '+'
%left '*' '/'
%left NEG
%left '^'
%token END
/* Grammar non-terminal symbols. */
%type <node> expression
/* Grammar start non-terminal. */
%start input
%%
input
: expression '\n' {
root = $1;
}
;
expression
: NUMBER
| CONSTANT
| VARIABLE
| expression '+' expression {
/* Create addition binary operation node. */
$$ = node_create ('b', '+', $1, $3);
}
| expression '-' expression {
/* Create subtraction binary operation node. */
$$ = node_create ('b', '-', $1, $3);
}
| expression '*' expression {
/* Create multiplication binary operation node. */
$$ = node_create ('b', '*', $1, $3);
}
| expression '/' expression {
/* Create division binary operation node. */
$$ = node_create ('b', '/', $1, $3);
}
| '-' expression %prec NEG {
/* Create minus unary operation node. */
$$ = node_create ('u', '-', $2);
}
| expression '^' expression {
/* Create exponentiation unary operation node. */
$$ = node_create ('b', '^', $1, $3);
}
| FUNCTION '(' expression ')' {
/* Create function node. */
$$ = node_create ('f', $1, $3);
}
| '(' expression ')' {
$$ = $2;
}
;
%%
int yyerror(char* s)
{
/* Indicate parsing error through appropriate flag, reset input
* string and stop parsing. */
ok = 0;
input_reset();
return 0;
}
|
