1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
|
# Copyright (C) 2008-2010, Sebastian Riedel.
package Mojo::Server::CGI;
use strict;
use warnings;
use base 'Mojo::Server';
use IO::Poll 'POLLIN';
use constant CHUNK_SIZE => $ENV{MOJO_CHUNK_SIZE} || 8192;
__PACKAGE__->attr(nph => 0);
# Lisa, you're a Buddhist, so you believe in reincarnation.
# Eventually, Snowball will be reborn as a higher lifeform... like a snowman.
sub run {
my $self = shift;
my $tx = $self->build_tx_cb->($self);
my $req = $tx->req;
# Environment
$req->parse(\%ENV);
# Store connection information
$tx->remote_address($ENV{REMOTE_ADDR});
$tx->local_port($ENV{SERVER_PORT});
# Request body
my $poll = IO::Poll->new;
$poll->mask(\*STDIN, POLLIN);
while (!$req->is_finished) {
$poll->poll(1);
my @readers = $poll->handles(POLLIN);
last unless @readers;
my $read = STDIN->sysread(my $buffer, CHUNK_SIZE, 0);
$req->parse($buffer);
}
# Handle
$self->handler_cb->($self, $tx);
my $res = $tx->res;
# Response start line
my $offset = 0;
if ($self->nph) {
while (1) {
my $chunk = $res->get_start_line_chunk($offset);
# No start line yet, try again
unless (defined $chunk) {
sleep 1;
next;
}
# End of start line
last unless length $chunk;
# Start line
return unless STDOUT->opened;
my $written = STDOUT->syswrite($chunk);
return unless defined $written;
$offset += $written;
}
}
# Status
if (my $code = $res->code) {
my $message = $res->message || $res->default_message;
$res->headers->header(Status => "$code $message") unless $self->nph;
}
# Response headers
$offset = 0;
while (1) {
my $chunk = $res->get_header_chunk($offset);
# No headers yet, try again
unless (defined $chunk) {
sleep 1;
next;
}
# End of headers
last unless length $chunk;
# Headers
return unless STDOUT->opened;
my $written = STDOUT->syswrite($chunk);
return unless defined $written;
$offset += $written;
}
# Response body
$offset = 0;
while (1) {
my $chunk = $res->get_body_chunk($offset);
# No content yet, try again
unless (defined $chunk) {
sleep 1;
next;
}
# End of content
last unless length $chunk;
# Content
return unless STDOUT->opened;
my $written = STDOUT->syswrite($chunk);
return unless defined $written;
$offset += $written;
}
return $res->code;
}
1;
__END__
=head1 NAME
Mojo::Server::CGI - CGI Server
=head1 SYNOPSIS
use Mojo::Server::CGI;
my $cgi = Mojo::Server::CGI->new;
$cgi->run;
=head1 DESCRIPTION
L<Mojo::Server::CGI> is a simple and portable implementation of RFC 3875.
=head1 ATTRIBUTES
L<Mojo::Server::CGI> inherits all attributes from L<Mojo::Server> and
implements the following new ones.
=head2 C<nph>
my $nph = $cgi->nph;
$cgi = $cgi->nph(1);
Activate non parsed header mode.
=head1 METHODS
L<Mojo::Server::CGI> inherits all methods from L<Mojo::Server> and
implements the following new ones.
=head2 C<run>
$cgi->run;
Process CGI.
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicious.org>.
=cut
|
