1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
|
# Copyright (C) 2008-2010, Sebastian Riedel.
package MojoX::Controller;
use strict;
use warnings;
# Scalpel... blood bucket... priest.
use base 'Mojo::Base';
use Mojo::ByteStream;
use Mojo::Cookie::Response;
__PACKAGE__->attr([qw/app tx/]);
# If we don't go back there and make that event happen,
# the entire universe will be destroyed...
# And as an environmentalist, I'm against that.
sub cookie {
my ($self, $name, $value, $options) = @_;
# Shortcut
return unless $name;
# Response cookie
if (defined $value) {
# Cookie too big
$self->app->log->error(qq/Cookie "$name" is bigger than 4096 bytes./)
if length $value > 4096;
# Create new cookie
$options ||= {};
my $cookie = Mojo::Cookie::Response->new(
name => $name,
value => $value,
%$options
);
$self->res->cookies($cookie);
return $self;
}
# Request cookie
unless (wantarray) {
return unless my $cookie = $self->req->cookie($name);
return $cookie->value;
}
# Request cookies
my @cookies = $self->req->cookie($name);
return map { $_->value } @cookies;
}
sub req { shift->tx->req }
sub res { shift->tx->res }
sub signed_cookie {
my ($self, $name, $value, $options) = @_;
# Shortcut
return unless $name;
# Secret
my $secret = $self->app->secret;
# Response cookie
if (defined $value) {
# Sign value
my $signature =
Mojo::ByteStream->new($value)->hmac_md5_sum($secret)->to_string;
$value = $value .= "--$signature";
# Create cookie
my $cookie = $self->cookie($name, $value, $options);
return $cookie;
}
# Request cookies
my @values = $self->cookie($name);
my @results;
for my $value (@values) {
# Check signature
if ($value =~ s/\-\-([^\-]+)$//) {
my $signature = $1;
my $check =
Mojo::ByteStream->new($value)->hmac_md5_sum($secret)->to_string;
# Verified
if ($signature eq $check) { push @results, $value }
# Bad cookie
else {
$self->app->log->debug(
qq/Bad signed cookie "$name", possible hacking attempt./);
}
}
# Not signed
else { $self->app->log->debug(qq/Cookie "$name" not signed./) }
}
return wantarray ? @results : $results[0];
}
sub stash {
my $self = shift;
# Initialize
$self->{stash} ||= {};
# Hash
return $self->{stash} unless @_;
# Get
return $self->{stash}->{$_[0]} unless @_ > 1 || ref $_[0];
# Set
my $values = ref $_[0] ? $_[0] : {@_};
for my $key (keys %$values) {
$self->{stash}->{$key} = $values->{$key};
}
return $self;
}
1;
__END__
=head1 NAME
MojoX::Controller - Controller Base Class
=head1 SYNOPSIS
use base 'MojoX::Controller';
=head1 DESCRIPTION
L<MojoX::Controller> is an abstract controllers base class.
=head1 ATTRIBUTES
L<MojoX::Controller> implements the following attributes.
=head2 C<app>
my $app = $c->app;
$c = $c->app(MojoSubclass->new);
A reference back to the application that dispatched to this controller.
=head2 C<tx>
my $tx = $c->tx;
The transaction that is currently being processed.
=head1 METHODS
L<MojoX::Controller> inherits all methods from L<Mojo::Base> and implements
the following new ones.
=head2 C<cookie>
$c = $c->cookie(foo => 'bar');
$c = $c->cookie(foo => 'bar', {path => '/'});
my $value = $c->cookie('foo');
my @values = $c->cookie('foo');
Access request cookie values and create new response cookies.
=head2 C<req>
my $req = $c->req;
Alias for C<$c->tx->req>.
Usually refers to a L<Mojo::Message::Request> object.
=head2 C<res>
my $res = $c->res;
Alias for C<$c->tx->res>.
Usually refers to a L<Mojo::Message::Response> object.
=head2 C<signed_cookie>
$c = $c->signed_cookie(foo => 'bar');
$c = $c->signed_cookie(foo => 'bar', {path => '/'});
my $value = $c->signed_cookie('foo');
my @values = $c->signed_cookie('foo');
Access signed request cookie values and create new signed response cookies.
Cookies failing signature verification will be automatically discarded.
=head2 C<stash>
my $stash = $c->stash;
my $foo = $c->stash('foo');
$c = $c->stash({foo => 'bar'});
$c = $c->stash(foo => 'bar');
Non persistent data storage and exchange.
$c->stash->{foo} = 'bar';
my $foo = $c->stash->{foo};
delete $c->stash->{foo};
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicious.org>.
=cut
|
