1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
|
# Copyright (C) 2008-2010, Sebastian Riedel.
package Mojolicious::Command::Generate::App;
use strict;
use warnings;
use base 'Mojo::Command';
__PACKAGE__->attr(description => <<'EOF');
Generate application directory structure.
EOF
__PACKAGE__->attr(usage => <<"EOF");
usage: $0 generate app [NAME]
EOF
# Why can't she just drink herself happy like a normal person?
sub run {
my ($self, $class) = @_;
$class ||= 'MyMojoliciousApp';
my $name = $self->class_to_file($class);
# Script
$self->render_to_rel_file('mojo', "$name/script/$name", $class);
$self->chmod_file("$name/script/$name", 0744);
# Appclass
my $app = $self->class_to_path($class);
$self->render_to_rel_file('appclass', "$name/lib/$app", $class);
# Controller
my $controller = "${class}::Example";
my $path = $self->class_to_path($controller);
$self->render_to_rel_file('controller', "$name/lib/$path", $controller);
# Test
$self->render_to_rel_file('test', "$name/t/basic.t", $class);
# Log
$self->create_rel_dir("$name/log");
# Static
$self->render_to_rel_file('static', "$name/public/index.html");
# Layout and Templates
$self->renderer->line_start('%%');
$self->renderer->tag_start('<%%');
$self->renderer->tag_end('%%>');
$self->render_to_rel_file('not_found',
"$name/templates/not_found.html.ep");
$self->render_to_rel_file('exception',
"$name/templates/exception.html.ep");
$self->render_to_rel_file('layout',
"$name/templates/layouts/default.html.ep");
$self->render_to_rel_file('welcome',
"$name/templates/example/welcome.html.ep");
}
1;
__DATA__
@@ mojo
% my $class = shift;
#!/usr/bin/env perl
use strict;
use warnings;
use FindBin;
use lib "$FindBin::Bin/../lib";
use lib "$FindBin::Bin/../../lib";
# Check if Mojo is installed
eval 'use Mojolicious::Commands';
die <<EOF if $@;
It looks like you don't have the Mojo Framework installed.
Please visit http://mojolicious.org for detailed installation instructions.
EOF
# Application
$ENV{MOJO_APP} ||= '<%= $class %>';
# Start commands
Mojolicious::Commands->start;
@@ appclass
% my $class = shift;
package <%= $class %>;
use strict;
use warnings;
use base 'Mojolicious';
# This method will run once at server start
sub startup {
my $self = shift;
# Routes
my $r = $self->routes;
# Default route
$r->route('/:controller/:action/:id')->to('example#welcome', id => 1);
}
1;
@@ controller
% my $class = shift;
package <%= $class %>;
use strict;
use warnings;
use base 'Mojolicious::Controller';
# This action will render a template
sub welcome {
my $self = shift;
# Render template "example/welcome.html.ep" with message
$self->render(message => 'Welcome to the Mojolicious Web Framework!');
}
1;
@@ static
<!doctype html><html>
<head><title>Welcome to the Mojolicious Web Framework!</title></head>
<body>
<h2>Welcome to the Mojolicious Web Framework!</h2>
This is the static document "public/index.html",
<a href="/">click here</a> to get back to the start.
</body>
</html>
@@ test
% my $class = shift;
#!/usr/bin/env perl
use strict;
use warnings;
use Test::More tests => 5;
use Test::Mojo;
use_ok('<%= $class %>');
# Test
my $t = Test::Mojo->new(app => '<%= $class %>');
$t->get_ok('/')->status_is(200)->content_type_is('text/html')
->content_like(qr/Mojolicious Web Framework/i);
@@ not_found
<!doctype html><html>
<head><title>Not Found</title></head>
<body>
The page you were requesting
"<%= $self->req->url->path || '/' %>"
could not be found.
</body>
</html>
@@ exception
<!doctype html><html>
% my $s = $self->stash;
% my $e = $self->stash('exception');
% delete $s->{inner_template};
% delete $s->{exception};
% my $dump = dumper $s;
% $s->{exception} = $e;
<head>
<title>Exception</title>
<style type="text/css">
body {
font: 0.9em Verdana, "Bitstream Vera Sans", sans-serif;
}
.snippet {
font: 115% Monaco, "Courier New", monospace;
}
</style>
</head>
<body>
<% if ($self->app->mode eq 'development') { %>
<div>
This page was generated from the template
"templates/exception.html.ep".
</div>
<div class="snippet"><pre><%= $e->message %></pre></div>
<div>
<% for my $line (@{$e->lines_before}) { %>
<div class="snippet">
<%= $line->[0] %>: <%= $line->[1] %>
</div>
<% } %>
<% if ($e->line->[0]) { %>
<div class="snippet">
<b><%= $e->line->[0] %>: <%= $e->line->[1] %></b>
</div>
<% } %>
<% for my $line (@{$e->lines_after}) { %>
<div class="snippet">
<%= $line->[0] %>: <%= $line->[1] %>
</div>
<% } %>
</div>
<div class="snippet"><pre><%= $dump %></pre></div>
<% } else { %>
<div>Page temporarily unavailable, please come back later.</div>
<% } %>
</body>
</html>
@@ layout
<!doctype html><html>
<head><title>Welcome</title></head>
<body><%== content %></body>
</html>
@@ welcome
% layout 'default';
<h2><%= $message %></h2>
This page was generated from the template
"templates/example/welcome.html.ep" and the layout
"templates/layouts/default.html.ep",
<a href="<%== url_for %>">click here</a>
to reload the page or
<a href="/index.html">here</a>
to move forward to a static page.
__END__
=head1 NAME
Mojolicious::Command::Generate::App - App Generator Command
=head1 SYNOPSIS
use Mojolicious::Command::Generate::App;
my $app = Mojolicious::Command::Generate::App->new;
$app->run(@ARGV);
=head1 DESCRIPTION
L<Mojolicious::Command::Generate::App> is a application generator.
=head1 ATTRIBUTES
L<Mojolicious::Command::Generate::App> inherits all attributes from
L<Mojo::Command> and implements the following new ones.
=head2 C<description>
my $description = $app->description;
$app = $app->description('Foo!');
Short description of this command, used for the command list.
=head2 C<usage>
my $usage = $app->usage;
$app = $app->usage('Foo!');
Usage information for this command, used for the help screen.
=head1 METHODS
L<Mojolicious::Command::Generate::App> inherits all methods from
L<Mojo::Command> and implements the following new ones.
=head2 C<run>
$app->run(@ARGV);
Run this command.
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicious.org>.
=cut
|
