1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
package Mojolicious::Command::eval;
use Mojo::Base 'Mojolicious::Command';
use Getopt::Long qw(GetOptionsFromArray :config no_auto_abbrev no_ignore_case);
has description => 'Run code against application.';
has usage => sub { shift->extract_usage };
sub run {
my ($self, @args) = @_;
GetOptionsFromArray \@args, 'v|verbose' => \my $v1, 'V' => \my $v2;
my $code = shift @args || '';
# Run code against application
my $app = $self->app;
no warnings;
my $result = eval "package main; sub app; local *app = sub { \$app }; $code";
return $@ ? die $@ : $result unless defined $result && ($v1 || $v2);
$v2 ? print($app->dumper($result)) : say $result;
}
1;
=encoding utf8
=head1 NAME
Mojolicious::Command::eval - Eval command
=head1 SYNOPSIS
Usage: APPLICATION eval [OPTIONS] CODE
./myapp.pl eval 'say app->ua->get("/")->res->body'
./myapp.pl eval -v 'app->home'
./myapp.pl eval -V 'app->renderer->paths'
Options:
-v, --verbose Print return value to STDOUT.
-V Print returned data structure to STDOUT.
=head1 DESCRIPTION
L<Mojolicious::Command::eval> runs code against applications.
This is a core command, that means it is always enabled and its code a good
example for learning to build new commands, you're welcome to fork it.
See L<Mojolicious::Commands/"COMMANDS"> for a list of commands that are
available by default.
=head1 ATTRIBUTES
L<Mojolicious::Command::eval> inherits all attributes from
L<Mojolicious::Command> and implements the following new ones.
=head2 description
my $description = $eval->description;
$eval = $eval->description('Foo!');
Short description of this command, used for the command list.
=head2 usage
my $usage = $eval->usage;
$eval = $eval->usage('Foo!');
Usage information for this command, used for the help screen.
=head1 METHODS
L<Mojolicious::Command::eval> inherits all methods from
L<Mojolicious::Command> and implements the following new ones.
=head2 run
$eval->run(@ARGV);
Run this command.
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicio.us>.
=cut
|
