File: 031_delegation_and_modifiers.t

package info (click to toggle)
libmoose-perl 1.09-2
  • links: PTS, VCS
  • area: main
  • in suites: squeeze
  • size: 3,004 kB
  • ctags: 1,472
  • sloc: perl: 25,387; makefile: 2
file content (57 lines) | stat: -rw-r--r-- 979 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
#!/usr/bin/perl

use strict;
use warnings;

use Test::More;
use Test::Exception;

{
    package Bar;
    use Moose;

    sub baz   { 'Bar::baz' }
    sub gorch { 'Bar::gorch' }

    package Foo;
    use Moose;

    has 'bar' => (
        is      => 'ro',
        isa     => 'Bar',
        lazy    => 1,
        default => sub { Bar->new },
        handles => [qw[ baz gorch ]]
    );

    package Foo::Extended;
    use Moose;

    extends 'Foo';

    has 'test' => (
        is      => 'rw',
        isa     => 'Bool',
        default => sub { 0 },
    );

    around 'bar' => sub {
        my $next = shift;
        my $self = shift;

        $self->test(1);
        $self->$next();
    };
}

my $foo = Foo::Extended->new;
isa_ok($foo, 'Foo::Extended');
isa_ok($foo, 'Foo');

ok(!$foo->test, '... the test value has not been changed');

is($foo->baz, 'Bar::baz', '... got the right delegated method');

ok($foo->test, '... the test value has now been changed');

done_testing;