1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
|
package Net::DNS::RR::AAAA;
# $Id: AAAA.pm,v 1.5 2000/11/19 06:02:47 mfuhr Exp mfuhr $
use strict;
use vars qw(@ISA);
use Net::DNS;
@ISA = qw(Net::DNS::RR);
sub new {
my ($class, $self, $data, $offset) = @_;
if ($self->{"rdlength"} > 0) {
my @addr = unpack("\@$offset n8", $$data);
$self->{"address"} = sprintf("%x:%x:%x:%x:%x:%x:%x:%x", @addr);
}
return bless $self, $class;
}
sub new_from_string {
my ($class, $self, $string) = @_;
if ($string) {
my @addr;
# I think this is correct, per RFC 1884 Sections 2.2 & 2.4.4.
if ($string =~ /^(.*):(\d+)\.(\d+)\.(\d+)\.(\d+)$/) {
my ($front, $a, $b, $c, $d) = ($1, $2, $3, $4, $5);
$string = $front . sprintf(":%x:%x",
($a << 8 | $b),
($c << 8 | $d));
}
if ($string =~ /^(.*)::(.*)$/) {
my ($front, $back) = ($1, $2);
my @front = split(/:/, $front);
my @back = split(/:/, $back);
my $fill = 8 - (@front ? $#front + 1 : 0)
- (@back ? $#back + 1 : 0);
my @middle = (0) x $fill;
@addr = (@front, @middle, @back);
}
else {
@addr = split(/:/, $string);
if (@addr < 8) {
@addr = ((0) x (8 - @addr), @addr);
}
}
$self->{"address"} = sprintf("%x:%x:%x:%x:%x:%x:%x:%x",
map { hex $_ } @addr);
}
return bless $self, $class;
}
sub rdatastr {
my $self = shift;
return exists $self->{"address"} && $self->{"address"}
? $self->{"address"}
: "; no data";
}
sub rr_rdata {
my $self = shift;
my $rdata = "";
if (exists $self->{"address"}) {
my @addr = split(/:/, $self->{"address"});
$rdata .= pack("n8", map { hex $_ } @addr);
}
return $rdata;
}
1;
__END__
=head1 NAME
Net::DNS::RR::AAAA - DNS AAAA resource record
=head1 SYNOPSIS
C<use Net::DNS::RR>;
=head1 DESCRIPTION
Class for DNS IPv6 Address (AAAA) resource records.
=head1 METHODS
=head2 address
print "address = ", $rr->address, "\n";
Returns the RR's address field.
=head1 BUGS
The C<string> method returns only the preferred method of address
representation ("x:x:x:x:x:x:x:x", as documented in RFC 1884,
Section 2.2, Para 1).
=head1 COPYRIGHT
Copyright (c) 1997-1998 Michael Fuhr. All rights reserved. This
program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.
=head1 SEE ALSO
L<perl(1)>, L<Net::DNS>, L<Net::DNS::Resolver>, L<Net::DNS::Packet>,
L<Net::DNS::Header>, L<Net::DNS::Question>, L<Net::DNS::RR>,
RFC 1886 Section 2, RFC 1884 Sections 2.2 & 2.4.4
=cut
|
