1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
|
package PDF::FromHTML;
use 5.006;
use strict;
use warnings;
our $VERSION = '0.34';
BEGIN {
foreach my $method ( qw( pdf twig tidy args ) ) {
no strict 'refs';
*$method = sub { $#_ ? ($_[0]{$method} = $_[1]) : $_[0]{$method} };
}
}
use Cwd;
use File::Temp;
use File::Basename;
use PDF::Writer;
use PDF::FromHTML::Twig;
use PDF::FromHTML::Template;
use constant HAS_UNICODE_SUPPORT => ($] >= 5.008);
use constant PDF_WRITER_BACKEND => do {
local $@;
# For Perl 5.6.x, we have to use pdflib
PDF::Writer->import('pdflib')
unless HAS_UNICODE_SUPPORT();
eval { ref(PDF::Writer->new) }
or die( "Please install PDF::API2 (preferred) or pdflib_pl first" );
};
use constant HAS_HTML_TIDY => do {
local $@;
eval { require HTML::Tidy5; 1 } or do {
unless ( eval { require XML::Clean; 1 } ) {
die( "Please install HTML::Tidy5 (preferred) or XML::Clean first" );
}
0; # Has XML::Clean but no HTML::Tidy5
};
};
=encoding utf8
=head1 NAME
PDF::FromHTML - Convert HTML documents to PDF
=head1 SYNOPSIS
my $pdf = PDF::FromHTML->new( encoding => 'utf-8' );
# Loading from a file:
$pdf->load_file('source.html');
# Or from a scalar reference:
# $pdf->load_file(\$input);
# Perform the actual conversion:
$pdf->convert(
# With PDF::API2, font names such as 'traditional' also works
Font => 'font.ttf',
LineHeight => 10,
Landscape => 1,
);
# Write to a file:
$pdf->write_file('target.pdf');
# Or to a scalar reference:
# $pdf->write_file(\$output);
=head1 DESCRIPTION
This module transforms HTML into PDF, using an assortment of XML
transformations implemented in L<PDF::FromHTML::Twig>.
There is also a command-line utility, L<html2pdf.pl>, that comes
with this distribution.
=head1 PUBLIC METHODS
=cut
sub new {
my $class = shift;
bless({
twig => PDF::FromHTML::Twig->new,
args => { @_ },
}, $class);
}
sub load_file {
my ($self, $file) = @_;
$self->{file} = $file;
}
sub parse_file {
my $self = shift;
my $file = $self->{file};
my $content = '';
my $dir = Cwd::getcwd();
if (!ref $file) {
open my $fh, '<', $file or die $!;
chdir File::Basename::dirname($file);
$content = do { local $/; <$fh> };
}
else {
$content = $$file;
}
my $encoding = ($self->args->{encoding} || 'utf8');
if (HAS_UNICODE_SUPPORT() and $self->args) {
require Encode;
$content = Encode::decode($encoding, $content, Encode::FB_XMLCREF());
}
$content =~ s{ }{}g;
$content =~ s{<!--.*?-->}{}gs;
if (HAS_HTML_TIDY()) {
if (HAS_UNICODE_SUPPORT()) {
$content = Encode::encode( ascii => $content, Encode::FB_XMLCREF());
}
$content = HTML::Tidy5->new->clean(
'<?xml version="1.0" encoding="UTF-8"?>',
'<html xmlns="http://www.w3.org/1999/xhtml">',
$content,
);
}
else {
$content =~ s{&#(\d+);}{chr $1}eg;
$content =~ s{&#x([\da-fA-F]+);}{chr hex $1}eg;
$content = XML::Clean::clean($content, '1.0', { encoding => 'UTF-8' });
$content =~ s{<(/?\w+)}{<\L$1}g;
}
$self->twig->parse( $content );
chdir $dir;
}
=head2 convert(%params)
Convert the loaded file to PDF. Valid parameters are:
PageWidth 640
PageResolution 540
FontBold 'HelveticaBold'
FontOblique 'HelveticaOblique'
FontBoldOblique 'HelveticaBoldOblique'
LineHeight 12
FontUnicode 'Helvetica'
Font (same as FontUnicode)
PageSize 'A4'
Landscape 0
=cut
sub convert {
my ($self, %args) = @_;
{
# import arguments into Twig parameters
no strict 'refs';
${"PDF::FromHTML::Twig::$_"} = $args{$_} foreach keys %args;
}
$self->parse_file;
my ($fh, $filename) = File::Temp::tempfile(
SUFFIX => '.xml',
UNLINK => 1,
);
binmode($fh);
if (HAS_UNICODE_SUPPORT()) {
binmode($fh, ':utf8');
}
# use File::Copy;
# copy($filename => '/tmp/foo.xml');
# XXX HACK! XXX
my $text = $self->twig->sprint;
$text =~ s{\$(__[A-Z_]+__)}{<var name='$1' />}g;
print $fh $text;
close $fh;
# print STDERR "==> Temp file written to $filename\n";
local $@;
local $^W;
$self->pdf(eval { PDF::FromHTML::Template->new( filename => $filename ) })
or die "$filename: $@";
$self->pdf->param(@_);
}
sub write_file {
my $self = shift;
local $^W;
if (@_ and ref($_[0]) eq 'SCALAR') {
${$_[0]} = $self->pdf->get_buffer;
}
else {
$self->pdf->write_file(@_);
}
}
1;
=head1 HINTS & TIPS
=head2 E<lt>imgE<gt> tags
Add the height and width attributes if you are creating the source HTML,
it keeps PDF::FromHTML from having to open and read the source image file
to get the real size. Less file I/O means faster processing.
=head1 CAVEATS
Although B<PDF::FromHTML> will work with both HTML and XHTML formats,
it is not designed to utilise CSS.
This means any HTML using external or inline CSS for design and
layout, including but not limited to: images, backgrounds, colours,
fonts etc... will not be converted into the PDF.
To get an idea of the likely resulting PDF, you may wish to use an
non-CSS capable browser for testing first.
There is currently no plan to adapt this module to utilise CSS.
(Patches welcome, though!)
=head1 SEE ALSO
L<html2pdf.pl> is a simple command-line interface to this module.
L<PDF::FromHTML::Twig>, L<PDF::Template>, L<XML::Twig>.
=head1 CONTRIBUTORS
Charleston Software Associates E<lt>info@charletonsw.comE<gt>
=head1 AUTHORS
Audrey Tang E<lt>cpan@audreyt.orgE<gt>
=head1 CC0 1.0 Universal
To the extent possible under law, 唐鳳 has waived all copyright and related
or neighboring rights to PDF-FromHTML.
This work is published from Taiwan.
L<http://creativecommons.org/publicdomain/zero/1.0>
=cut
|
