1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
|
# Pegex grammar for the Swim markup language
#
# Copyright 2014-2015. Ingy döt Net <ingy@ingy.net>
#
%grammar swim
%version 0.0.2
document: block-top*
block-top:
| block-func
| block-blank
| block-comment
| line-comment
| block-rule
| block-meta
| block-head
| block-code
| block-pref
| block-list
| block-title
| block-verse
| block-para
block-blank: line-blank
block-func: /
LANGLE LANGLE LANGLE SPACE*
( [ WORD DASH ]+ ) SPACE*
(:
( ANY*?) SPACE*
|
EOL ( (: ANY* EOL )*? )
)
RANGLE RANGLE RANGLE EOL
/
block-comment: /
HASH{3} EOL
( line*? )
HASH{3} END
line-blank?
/
line-comment: /
HASH SPACE? ( ANY*? ) END
line-blank?
/
block-rule: /
DASH{4} END
line-blank?
/
block-meta: /
DASH{3} EOL
( ALL*? EOL | )
DOT{3} END
line-blank?
/
block-head: /
( EQUAL{1,4} ) SPACE+ (:
( ANY+? ) SPACE+ EQUAL+ END
| ( ANY+ EOL (: [^ WS ] ANY* EOL )* [^ WS ] ANY*? ) SPACE+ EQUAL+ END
| ( ANY+ EOL (: [^ WS ] ANY* EOL )*) (= [ marker-block-start ] | END )
) line-blank?
/
block-code: /
BACK{3} EOL
( line*? )
BACK{3} END
line-blank?
/
block-pref: /
(
(:
line-blank*
SPACE SPACE ANY* END
)+
)
line-blank?
/
block-list:
| block-list-bullet
| block-list-number
| block-list-data
block-list-bullet: /(
line-list-item-bullet
(: line-list-item-bullet | line-blank | line-indented )*
)/
block-list-number: /(
line-list-item-number
(: line-list-item-number | line-blank | line-indented )*
)/
block-list-data: /(
line-list-item-data
(: line-list-item-data | line-blank | line-indented )*
)/
line-list-item-bullet: /
STAR SPACE ANY* END
/
line-list-item-number: /
PLUS SPACE ANY* END
/
line-list-item-data: /
DASH SPACE ANY* END
/
block-list-item: (
| block-blank
| block-comment
| line-comment
| block-head
| block-pref
| block-list
| block-title
| block-verse
| block-para
)*
line-indented: /
SPACE{2} ANY* END
/
block-title: /
( text-line )
EQUAL{3,} EOL
(:
line-blank
( text-line )
(= line-blank )
)?
line-blank?
/
block-verse: /
DOT EOL
( text-line+ )
line-blank?
/
block-para: /
( text-line+ )
line-blank?
/
text-markup: phrase-markup+
phrase-markup:
| phrase-text
| marker-escape
| phrase-meta
| phrase-func
| phrase-code
| phrase-bold
| phrase-emph
| phrase-del
| phrase-under
| phrase-hyper
| phrase-link
| marker-next
marker-escape: / BACK ( ANY ) /
phrase-text: /
(
(: (! [ marker-phrase-start ] |https? COLON ) ALL)+
)
/
phrase-code: /
marker-code
( [^ marker-code]*? )
marker-code
/
# This is just a special case of phrase-func.
# Should be removed and handled there.
phrase-meta: /
marker-pfunc-start '$'
( [^ marker-pfunc-end]+ )
marker-pfunc-end
/
phrase-func: /
marker-pfunc-start
( [^ marker-pfunc-end]+ )
marker-pfunc-end
/
phrase-bold:
/ marker-bold (= NS) (! marker-bold) /
( !marker-bold phrase-markup )+
marker-bold
phrase-emph:
/ marker-emph (= NS) (! marker-emph) /
( !marker-emph phrase-markup )+
marker-emph
phrase-del:
/ marker-del (= NS) (! marker-del) /
( !marker-del phrase-markup )+
marker-del
phrase-under:
/ marker-under (= NS) (! marker-under) /
( !marker-under phrase-markup )+
marker-under
phrase-hyper:
| phrase-hyper-named
| phrase-hyper-explicit
| phrase-hyper-implicit
phrase-hyper-named: /
DOUBLE ( [^ DOUBLE ]+ ) DOUBLE
LSQUARE (https?: NS*? ) RSQUARE
/
phrase-hyper-explicit: /
LSQUARE (https?: NS*? ) RSQUARE
/
phrase-hyper-implicit: /(https? COLON NS+)/
phrase-link:
| phrase-link-named
| phrase-link-plain
phrase-link-named: /
DOUBLE ( [^ DOUBLE ]+ ) DOUBLE
LSQUARE ( NS*? ) RSQUARE
/
phrase-link-plain: /
LSQUARE ( NS*? ) RSQUARE
/
marker-next: / ( ALL ) /
line: / (: ANY* END ) /
text-line: / (: (! [ marker-block-start NL ] SPACE) ANY* NS ANY* END ) /
line-blank: / (: SPACE+ END | EOL ) /
END: / (: EOL | EOS ) /
marker-block-start: /
marker-pref
marker-list
marker-head
marker-comment
/
marker-phrase-start: /
marker-pfunc-start
marker-code
marker-bold
marker-emph
marker-del
marker-under
marker-link
marker-esc
/
marker-pref: / SPACE /
marker-list: / STAR /
marker-head: / EQUAL /
marker-comment: / HASH /
marker-pfunc-start: / LANGLE /
marker-pfunc-end: / RANGLE /
marker-code: / GRAVE /
marker-bold: / STAR /
marker-emph: / SLASH /
marker-del: / DASH DASH /
marker-under: / UNDER /
marker-link: / DOUBLE LSQUARE /
marker-esc: / BACK /
# vim: set lisp sw=2:
|
