File: 01_policy_config.t

package info (click to toggle)
libperl-critic-perl 1.156-1
  • links: PTS, VCS
  • area: main
  • in suites: sid, trixie
  • size: 3,544 kB
  • sloc: perl: 24,092; lisp: 341; makefile: 7
file content (172 lines) | stat: -rw-r--r-- 3,985 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
#!perl

use 5.010001;
use strict;
use warnings;

use Carp qw< confess >;

use Perl::Critic::PolicyConfig;

use Test::More tests => 28;

our $VERSION = '1.156';

use Perl::Critic::TestUtils;
Perl::Critic::TestUtils::assert_version( $VERSION );


{
    my $config =
        Perl::Critic::PolicyConfig->new('Some::Policy');

    is(
        $config->get_policy_short_name(),
        'Some::Policy',
        'Policy short name gets saved.',
    );
    is(
        $config->get_set_themes(),
        undef,
        'set_themes is undef when not specified.',
    );
    is(
        $config->get_add_themes(),
        undef,
        'add_themes is undef when not specified.',
    );
    is(
        $config->get_severity(),
        undef,
        'severity is undef when not specified.',
    );
    is(
        $config->get_maximum_violations_per_document(),
        undef,
        'maximum_violations_per_document is undef when not specified.',
    );
    ok(
        $config->is_empty(),
        'is_empty() is true when there were no configuration values.',
    );

    my @parameter_names = $config->get_parameter_names();
    is(
        scalar @parameter_names,
        0,
        'There are no parameter names left.',
    );

    test_standard_parameters_undef_via_get($config);
}

{
    my $config =
        Perl::Critic::PolicyConfig->new(
            'Some::Other::Policy',
            {
                custom_parameter   => 'blargh',

                # Standard parameters
                set_themes                      => 'thingy',
                add_themes                      => 'another thingy',
                severity                        => 'harsh',
                maximum_violations_per_document => '2',
            }
        );

    is(
        $config->get_policy_short_name(),
        'Some::Other::Policy',
        'Policy short name gets saved.',
    );
    is(
        $config->get_set_themes(),
        'thingy',
        'set_themes gets saved.',
    );
    is(
        $config->get_add_themes(),
        'another thingy',
        'add_themes gets saved.',
    );
    is(
        $config->get_severity(),
        'harsh',
        'severity gets saved.',
    );
    is(
        $config->get_maximum_violations_per_document(),
        '2',
        'maximum_violations_per_document gets saved.',
    );
    is(
        $config->get('custom_parameter'),
        'blargh',
        'custom_parameter gets saved.',
    );
    ok(
        ! $config->is_empty(),
        'is_empty() is false when there were configuration values.',
    );

    my @parameter_names = $config->get_parameter_names();
    is(
        scalar @parameter_names,
        1,
        'There is one parameter name left after construction.',
    );
    is(
        $parameter_names[0],
        'custom_parameter',
        'There parameter name is the expected value.',
    );

    test_standard_parameters_undef_via_get($config);

    $config->remove('custom_parameter');
    ok(
        $config->is_empty(),
        'is_empty() is true after removing "custom_parameter".',
    );

    @parameter_names = $config->get_parameter_names();
    is(
        scalar @parameter_names,
        0,
        'There are no parameter names left after removing "custom_parameter".',
    );
}


sub test_standard_parameters_undef_via_get {
    my ($config) = @_;
    my $policy_short_name = $config->get_policy_short_name();

    foreach my $parameter (
        qw<
            set_themes
            add_themes
            severity
            maximum_violations_per_document
            _non_public_data
        >
    ) {
        is(
            $config->get($parameter),
            undef,
            qq<"$parameter" is not defined via get() for $policy_short_name.>,
        )
    }

    return;
}

# Local Variables:
#   mode: cperl
#   cperl-indent-level: 4
#   fill-column: 78
#   indent-tabs-mode: nil
#   c-indentation-style: bsd
# End:
# ex: set ts=8 sts=4 sw=4 tw=78 ft=perl expandtab shiftround :