1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
|
use strict;
use warnings;
use Test::More 'no_plan';
use Test::TempDir::Tiny;
use Set::Object;
{
# this will be a default class, for now I'm keeping them separate
package MyGIN;
use Moose;
# in memory index:
#with qw(
# Search::GIN::DelegateToIndexed
# Search::GIN::Driver::Hash
#);
# on disk index:
with (
qw(
Search::GIN::Core
Search::GIN::Driver::Hash
Search::GIN::SelfIDs
),
'Search::GIN::DelegateToIndexed' => {
-excludes => "objects_to_ids", # SelfIDs
},
);
}
{
# you create the query objects, the GIN implementation uses them
# consistently with the index
package MyTagQuery;
use Moose::Role;
use MooseX::Types::Set::Object;
with qw(Search::GIN::Query);
has tags => (
isa => "Set::Object",
is => "ro",
coerce => 1,
required => 1,
);
sub extract_values {
my $self = shift;
return (
values => [ $self->tags->members ],
);
}
}
{
package MyTagQuery::Intersection;
use Moose;
with qw(MyTagQuery);
sub consistent {
my ( $self, $index, $item ) = @_;
return $self->tags->subset($item->tags);
}
around extract_values => sub {
my ( $next, $self, @args ) = @_;
return (
method => "all",
$self->$next(@args),
);
};
__PACKAGE__->meta->make_immutable;
}
{
package MyTagQuery::Union;
use Moose;
with qw(MyTagQuery);
sub consistent {
my ( $self, $index, $item ) = @_;
return $self->tags->intersection($item->tags)->size >= 1;
}
__PACKAGE__->meta->make_immutable;
}
{
# this is an indexable object
package MyObject;
use Moose;
use overload '""' => sub { $_[0]->id }, fallback => 1; # is_deeply diagnosis
use MooseX::Types::Set::Object;
with qw(Search::GIN::Indexable);
has id => (
isa => "Str",
is => "ro",
);
sub gin_id { shift->id }
has tags => (
isa => "Set::Object",
is => "ro",
coerce => 1,
default => sub { Set::Object->new },
);
sub gin_extract_values {
my $self = shift;
$self->tags->members;
}
__PACKAGE__->meta->make_immutable;
}
my $gin = MyGIN->new(
manager => {
home => tempdir(),
create => 1,
},
file => "foo.idx",
distinct => 1,
);
my @objs = map { MyObject->new(%$_) } (
{
id => "aaaaaaaaaaaaaaaa",
tags => [ qw(foo bar baz donkey) ],
},
{
id => "aaaaaaaaaaaaaaab",
tags => [ qw(bar gorch baz) ],
},
{
id => "aaaaaaaaaaaaaaac",
tags => [ qw(zot urf donkey gorch) ],
},
);
$gin->insert(@objs);
{
my @res = $gin->query( MyTagQuery::Intersection->new( tags => [qw(foo)] ) )->all;
is_deeply( [ @res ], [ $objs[0] ] );
}
{
my @res = $gin->query( MyTagQuery::Union->new( tags => [qw(foo)] ) )->all;
is_deeply( [ @res ], [ $objs[0] ] );
}
{
my @res = $gin->query( MyTagQuery::Intersection->new( tags => [qw(bar)] ) )->all;
is_deeply( [ sort @res ], [ sort @objs[0, 1] ] );
}
{
my @res = $gin->query( MyTagQuery::Intersection->new( tags => [qw(gorch)] ) )->all;
is_deeply( [ sort @res ], [ sort @objs[1, 2] ] );
}
{
my @res = $gin->query( MyTagQuery::Intersection->new( tags => [qw(bar gorch)] ) )->all;
is_deeply( [ @res ], [ $objs[1] ] );
}
{
my @res = $gin->query( MyTagQuery::Union->new( tags => [qw(bar gorch)] ) )->all;
is_deeply( [ sort @res ], [ sort @objs ] );
}
|
