1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
|
package Test::BDD::Cucumber::Harness::JSON;
$Test::BDD::Cucumber::Harness::JSON::VERSION = '0.75';
=head1 NAME
Test::BDD::Cucumber::Harness::JSON - Generate results to JSON file
=head1 VERSION
version 0.75
=head1 DESCRIPTION
A L<Test::BDD::Cucumber::Harness> subclass that generates JSON output file.
So that it is possible use tools like
L<"Publish pretty cucumber reports"|https://github.com/masterthought/cucumber-reporting>.
=cut
use Moo;
use Types::Standard qw( Num HashRef ArrayRef FileHandle );
use JSON::MaybeXS;
use Time::HiRes qw ( time );
extends 'Test::BDD::Cucumber::Harness::Data';
=head1 CONFIGURABLE ATTRIBUTES
=head2 fh
A filehandle to write output to; defaults to C<STDOUT>
=cut
has 'fh' => ( is => 'rw', isa => FileHandle, default => sub { \*STDOUT } );
=head2 json_args
List of options to be passed to L<JSON::MaybeXS>'s C<new()> method
=cut
has json_args => (
is => 'ro',
isa => HashRef,
default => sub { { utf8 => 1, pretty => 1 } }
);
#
has all_features => ( is => 'ro', isa => ArrayRef, default => sub { [] } );
has current_feature => ( is => 'rw', isa => HashRef );
has current_scenario => ( is => 'rw', isa => HashRef );
has step_start_at => ( is => 'rw', isa => Num );
sub feature {
my ( $self, $feature ) = @_;
$self->current_feature( $self->format_feature($feature) );
push @{ $self->all_features }, $self->current_feature;
}
sub scenario {
my ( $self, $scenario, $dataset ) = @_;
$self->current_scenario( $self->format_scenario($scenario) );
push @{ $self->current_feature->{elements} }, $self->current_scenario;
}
sub scenario_done {
my $self = shift;
$self->current_scenario( {} );
}
sub step {
my ( $self, $context ) = @_;
$self->step_start_at( time() );
}
sub step_done {
my ( $self, $context, $result ) = @_;
my $duration = time() - $self->step_start_at;
my $step_data = $self->format_step( $context, $result, $duration );
push @{ $self->current_scenario->{steps} }, $step_data;
}
sub shutdown {
my ($self) = @_;
my $json = JSON::MaybeXS->new( %{ $self->json_args } );
my $fh = $self->fh;
print $fh $json->encode( $self->all_features );
}
##################################
### Internal formating methods ###
##################################
sub format_tags {
my ( $self, $tags_ref ) = @_;
return [ map { { name => '@' . $_ } } @$tags_ref ];
}
sub format_description {
my ( $self, $description ) = @_;
return join "\n", map { $_->content } @{ $description };
}
sub format_feature {
my ( $self, $feature ) = @_;
return {
uri => $feature->name_line->filename,
keyword => $feature->keyword_original,
id => $self->_generate_stable_id( $feature->name_line ),
name => $feature->name,
line => $feature->name_line->number,
description => $self->format_description($feature->satisfaction),
tags => $self->format_tags( $feature->tags ),
elements => []
};
}
sub format_scenario {
my ( $self, $scenario, $dataset ) = @_;
return {
keyword => $scenario->keyword_original,
id => $self->_generate_stable_id( $scenario->line ),
name => $scenario->name,
line => $scenario->line->number,
description => $self->format_description($scenario->description),
tags => $self->format_tags( $scenario->tags ),
type => $scenario->background ? 'background' : 'scenario',
steps => []
};
}
sub _generate_stable_id {
my ( $self, $line ) = @_;
return $line->filename . ":" . $line->number;
}
sub format_step {
my ( $self, $step_context, $result, $duration ) = @_;
my $step = $step_context->step;
return {
keyword => $step ? $step->verb_original : $step_context->verb,
name => $step_context->text,
line => $step ? $step->line->number : 0,
result => $self->format_result( $result, $duration )
};
}
my %OUTPUT_STATUS = (
passing => 'passed',
failing => 'failed',
pending => 'pending',
undefined => 'skipped',
);
sub format_result {
my ( $self, $result, $duration ) = @_;
return { status => "undefined" } if not $result;
return {
status => $OUTPUT_STATUS{ $result->result },
error_message => $result->output,
defined $duration
? ( duration => int( $duration * 1_000_000_000 ) )
: (), # nanoseconds
};
}
=head1 SEE ALSO
L<https://github.com/masterthought/cucumber-reporting>
L<http://cucumber-reporting.masterthought.net>
L<https://www.relishapp.com/cucumber/cucumber/docs/json-output-formatter>
=cut
1;
|
