File: Quoted.pm

package info (click to toggle)
libtext-quoted-perl 1.8-3
  • links: PTS
  • area: main
  • in suites: etch, etch-m68k
  • size: 124 kB
  • ctags: 240
  • sloc: perl: 583; makefile: 458
file content (277 lines) | stat: -rwxr-xr-x 7,697 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
package Text::Quoted;
our $VERSION = "1.8";
use 5.006;
use strict;
use warnings;

require Exporter;

our @ISA    = qw(Exporter);
our @EXPORT = qw(extract);

use Text::Autoformat();    # Provides the Hang package, heh, heh.

=head1 NAME

Text::Quoted - Extract the structure of a quoted mail message

=head1 SYNOPSIS

    use Text::Quoted;
    my $structure = extract($text);

=head1 DESCRIPTION

C<Text::Quoted> examines the structure of some text which may contain
multiple different levels of quoting, and turns the text into a nested
data structure. 

The structure is an array reference containing hash references for each
paragraph belonging to the same author. Each level of quoting recursively
adds another list reference. So for instance, this:

    > foo
    > # Bar
    > baz

    quux

turns into:

    [
      [
        { text => 'foo', quoter => '>', raw => '> foo' },
        [ 
            { text => 'Bar', quoter => '> #', raw => '> # Bar' } 
        ],
        { text => 'baz', quoter => '>', raw => '> baz' }
      ],

      { empty => 1 },
      { text => 'quux', quoter => '', raw => 'quux' }
    ];

This also tells you about what's in the hash references: C<raw> is the
paragraph of text as it appeared in the original input; C<text> is what
it looked like when we stripped off the quotation characters, and C<quoter>
is the quotation string.

=cut

sub extract {
    my $text  = shift;
    my @paras = classify($text);
    my @needed;
    for my $p (@paras) {
        push @needed, { map { $_ => $p->{$_} } qw(raw empty text quoter) };
    }

    return organize( "", @needed );
}

=head1 CREDITS

Most of the heavy lifting is done by a modified version of Damian Conway's
C<Text::Autoformat>.

=head1 COPYRIGHT

Copyright (C) 2002-2003 Kasei Limited
Copyright (C) 2003-2004 Simon Cozens
Copyright (C) 2004 Best Practical Solutions, LLC

This software is distributed WITHOUT ANY WARRANTY; without even the implied
warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself. 

=cut

sub organize {
    my $top_level = shift;
    my @todo      = @_;
    my @ret;

    # Recursively form a data structure which reflects the quoting
    # structure of the list.
    while (@todo) {
        my $line = shift @todo;
        if ( defn( $line->{quoter} ) eq defn($top_level) ) {

            # Just append lines at "my" level.
            push @ret, $line
              if exists $line->{quoter}
              or exists $line->{empty};
        }
        elsif ( defn( $line->{quoter} ) =~ /^\Q$top_level\E.+/ ) {

            # Find all the lines at a quoting level "below" me.
            my $newquoter = find_below( $top_level, $line, @todo );
            my @next = $line;
            push @next, shift @todo while defined $todo[0]->{quoter}
              and $todo[0]->{quoter} =~ /^\Q$newquoter/;

            # Find the 
            # And pass them on to organize()!
            #print "Trying to organise the following lines over $newquoter:\n";
            #print $_->{raw}."\n" for @next;
            #print "!-!-!-\n";
            push @ret, organize( $newquoter, @next );
        } #  else { die "bugger! I had $top_level, but now I have $line->{raw}\n"; }
    }
    return \@ret;
}

# Given, say:
#   X
#   > > hello
#   > foo bar
#   Stuff
#
# After "X", we're moving to another level of quoting - but which one?
# Naively, you'd pick out the prefix of the next line, "> >", but this
# is incorrect - "> >" is actually a "sub-quote" of ">". This routine
# works out which is the next level below us.

sub find_below {
    my ( $top_level, @stuff ) = @_;

    #print "## Looking for the next level of quoting after $top_level\n";
    #print "## We have:\n";
    #print "## $_->{raw}\n" for @stuff;

    my @prefices = sort { length $a <=> length $b } map { $_->{quoter} } @stuff;

    # Find the prefices, shortest first.

    # return $prefices[0] if $prefices[0] eq $prefices[-1];

    for (@prefices) {

        # And return the first one which is "below" where we are right
        # now but is a proper subset of the next line. 
        next unless $_;
        if ( $_ =~ /^\Q$top_level\E.+/ and $stuff[0]->{quoter} =~ /\Q$_\E/ ) {

            #print "## We decided on $_\n";
            return $_;
        }
    }
    die "Can't happen";
}

# Everything below this point is essentially Text::Autoformat.

# BITS OF A TEXT LINE

my $quotechar  = qq{[!#%=|:]};
my $quotechunk = qq{(?:$quotechar(?!\\w)|\\w*>+)};
my $quoter     = qq{(?:(?i)(?:$quotechunk(?:[ \\t]*$quotechunk)*))};

my $separator = q/(?:[-_]{2,}|[=#*]{3,}|[+~]{4,})/;

sub defn($) { return $_[0] if (defined $_[0]); return "" }

sub classify {
    my $text = shift;
    $text = "" unless defined $text;
    # If the user passes in a null string, we really want to end up with _something_

    # DETABIFY
    my @rawlines = split /\n/, $text;
    use Text::Tabs;
    @rawlines = expand(@rawlines);


    # PARSE EACH LINE

    my $pre = 0;
    my @lines;
    foreach (@rawlines) {
        push @lines, { raw => $_};
        s/\A([ \t]*)($quoter?)([ \t]*)//;
        $lines[-1]{presig} = $lines[-1]{prespace} = defn $1;
        $lines[-1]{presig} .= $lines[-1]{quoter}     = defn $2;
        $lines[-1]{presig} .= $lines[-1]{quotespace} = defn $3;
        $lines[-1]{hang} = defn( Hang->new($_) );

        s/([ \t]*)(.*?)(\s*)$//;
        $lines[-1]{hangspace} = defn $1;
        $lines[-1]{text}      = defn $2;
        $lines[-1]{empty}     = $lines[-1]{hang}->empty() && $2 !~ /\S/;
        $lines[-1]{separator} = $lines[-1]{text} =~ /^$separator$/;
    }

    # SUBDIVIDE DOCUMENT INTO COHERENT SUBSECTIONS

    my @chunks;
    push @chunks, [ shift @lines ];
    foreach my $line (@lines) {
        if ( $line->{separator}
            || $line->{quoter} ne $chunks[-1][-1]->{quoter}
            || $line->{empty}
            || @chunks && $chunks[-1][-1]->{empty} )
        {
            push @chunks, [$line];
        }
        else {
            push @{ $chunks[-1] }, $line;
        }
    }

    # REDIVIDE INTO PARAGRAPHS

    my @paras;
    foreach my $chunk (@chunks) {
        my $first = 1;
        my $firstfrom;
        foreach my $line ( @{$chunk} ) {
            if ( $first
                || $line->{quoter} ne $paras[-1]->{quoter}
                || $paras[-1]->{separator} )
            {
                push @paras, $line;
                $first     = 0;
		# We get warnings from undefined raw and text values if we don't supply alternates
                $firstfrom = length( $line->{raw} ||'' ) - length( $line->{text} || '');
            }
            else {
                my $extraspace =
                  length( $line->{raw} ) - length( $line->{text} ) - $firstfrom;
                $paras[-1]->{text} .= "\n" . q{ } x $extraspace . $line->{text};
                $paras[-1]->{raw} .= "\n" . $line->{raw};
            }
        }
    }

    my $remainder = "";

    # ALIGN QUOTERS
    # DETERMINE HANGING MARKER TYPE (BULLET, ALPHA, ROMAN, ETC.)

    my %sigs;
    my $lastquoted   = 0;
    my $lastprespace = 0;
    for my $i ( 0 .. $#paras ) {
        my $para = $paras[$i];
        if ( $para->{quoter} ) {
            if ($lastquoted) { $para->{prespace} = $lastprespace }
            else { $lastquoted = 1; $lastprespace = $para->{prespace} }
        }
        else {
            $lastquoted = 0;
        }
    }

    # Reapply hangs
    for (@paras) {
        next unless my $hang = $_->{hang};
        next unless $hang->stringify;
        $_->{text} = $hang->stringify . " " . $_->{text};
    }
    return @paras;
}

sub val { return "" }
1;