1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
=pod
=encoding utf-8
=head1 PURPOSE
Check that L<Type::Library> can extend an existing L<MooseX::Types>
type constraint library.
=head1 DEPENDENCIES
MooseX::Types 0.35; skipped otherwise.
=head1 AUTHOR
Toby Inkster E<lt>tobyink@cpan.orgE<gt>.
=head1 COPYRIGHT AND LICENCE
This software is copyright (c) 2013-2014, 2017-2023 by Toby Inkster.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
use strict;
use warnings;
use Test::More;
use Test::Requires { "MooseX::Types::Moose" => "0.35" };
use Test::TypeTiny;
use Test::Fatal;
BEGIN {
package MyTypes;
use Type::Library -base, -declare => qw(NonEmptyStr);
use Type::Utils -all;
BEGIN { extends 'MooseX::Types::Moose', 'Types::TypeTiny' };
declare NonEmptyStr, as Str, where { length($_) };
$INC{'MyTypes.pm'} = __FILE__;
};
use MyTypes -types;
should_pass("foo", Str);
should_pass("", Str);
should_pass("foo", NonEmptyStr);
should_fail("", NonEmptyStr);
should_pass({}, HashLike);
should_fail([], HashLike);
{
package MyDummy;
use Moose;
$INC{'MyDummy.pm'} = __FILE__;
package MoreTypes;
use Type::Library -base;
::like(
::exception { Type::Utils::extends 'MyDummy' },
qr/not a type constraint library/,
'cannot extend non-type-library',
);
}
BEGIN {
package MyMooseTypes;
use MooseX::Types -declare => ['RoundedInt'];
use MooseX::Types::Moose qw(Int Num);
subtype RoundedInt, as Int;
coerce RoundedInt, from Num, via { int($_) };
$INC{'MyMooseTypes.pm'} = __FILE__;
};
{
package Local::XYZ1234;
use MyMooseTypes qw(RoundedInt);
::is( RoundedInt->coerce(3.1), 3, 'MooseX::Types coercion works as expected' );
}
BEGIN {
package MyTinyTypes;
use Type::Library -base;
use Type::Utils 'extends';
extends 'MyMooseTypes';
$INC{'MyTinyTypes.pm'} = __FILE__;
};
{
package Local::XYZ12345678;
use MyTinyTypes qw(RoundedInt);
::is( RoundedInt->coerce(3.1), 3, 'Type::Tiny coercion works built from MooseX::Types extension' );
}
done_testing;
|
