File: check-spacing.pl

package info (click to toggle)
libvirt 7.0.0-3
  • links: PTS, VCS
  • area: main
  • in suites: bullseye
  • size: 143,760 kB
  • sloc: ansic: 502,517; xml: 180,512; python: 8,627; sh: 3,992; perl: 2,763; makefile: 509; javascript: 116; cpp: 22
file content (162 lines) | stat: -rwxr-xr-x 4,984 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
#!/usr/bin/env perl
#
# check-spacing.pl: Report any usage of 'function (..args..)'
# Also check for other syntax issues, such as correct use of ';'
#
# This library is free software; you can redistribute it and/or
# modify it under the terms of the GNU Lesser General Public
# License as published by the Free Software Foundation; either
# version 2.1 of the License, or (at your option) any later version.
#
# This library is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# Lesser General Public License for more details.
#
# You should have received a copy of the GNU Lesser General Public
# License along with this library.  If not, see
# <http://www.gnu.org/licenses/>.

use strict;
use warnings;

my $ret = 0;
my $incomment = 0;

foreach my $file (@ARGV) {
    open FILE, $file;

    while (defined (my $line = <FILE>)) {
        my $data = $line;
        # For temporary modifications
        my $tmpdata;

        # Kill any quoted , ; = or "
        $data =~ s/'[";,=]'/'X'/g;

        # Kill any quoted strings
        $data =~ s,"(?:[^\\\"]|\\.)*","XXX",g;

        next if $data =~ /^#/;

        # Kill contents of multi-line comments
        # and detect end of multi-line comments
        if ($incomment) {
            if ($data =~ m,\*/,) {
                $incomment = 0;
                $data =~ s,^.*\*/,*/,;
            } else {
                $data = "";
            }
        }

        # Kill single line comments, and detect
        # start of multi-line comments
        if ($data =~ m,/\*.*\*/,) {
            $data =~ s,/\*.*\*/,/* */,;
        } elsif ($data =~ m,/\*,) {
            $incomment = 1;
            $data =~ s,/\*.*,/*,;
        }

        # We need to match things like
        #
        #  int foo (int bar, bool wizz);
        #  foo (bar, wizz);
        #
        # but not match things like:
        #
        #  typedef int (*foo)(bar wizz)
        #
        # we can't do this (efficiently) without
        # missing things like
        #
        #  foo (*bar, wizz);
        #
        # We also don't want to spoil the $data so it can be used
        # later on.
        $tmpdata = $data;
        while ($tmpdata =~ /(\w+)\s\((?!\*)/) {
            my $kw = $1;

            # Allow space after keywords only
            if ($kw =~ /^(?:if|for|while|switch|return)$/) {
                $tmpdata =~ s/(?:$kw\s\()/XXX(/;
            } else {
                print "Whitespace after non-keyword:\n";
                print "$file:$.: $line";
                $ret = 1;
                last;
            }
        }

        # Require whitespace immediately after keywords
        if ($data =~ /\b(?:if|for|while|switch|return)\(/) {
            print "No whitespace after keyword:\n";
            print "$file:$.: $line";
            $ret = 1;
        }

        # Forbid whitespace between )( of a function typedef
        if ($data =~ /\(\*\w+\)\s+\(/) {
            print "Whitespace between ')' and '(':\n";
            print "$file:$.: $line";
            $ret = 1;
        }

        # Forbid whitespace following ( or prior to )
        # but allow whitespace before ) on a single line
        # (optionally followed by a semicolon)
        if (($data =~ /\s\)/ && not $data =~ /^\s+\);?$/) ||
            $data =~ /\((?!$)\s/) {
            print "Whitespace after '(' or before ')':\n";
            print "$file:$.: $line";
            $ret = 1;
        }

        # Forbid whitespace before ";" or ",". Things like below are allowed:
        #
        # 1) The expression is empty for "for" loop. E.g.
        #   for (i = 0; ; i++)
        #
        # 2) An empty statement. E.g.
        #   while (write(statuswrite, &status, 1) == -1 &&
        #          errno == EINTR)
        #       ;
        #
        if ($data =~ /\s[;,]/) {
            unless ($data =~ /\S; ; / ||
                    $data =~ /^\s+;/) {
                print "Whitespace before semicolon or comma:\n";
                print "$file:$.: $line";
                $ret = 1;
            }
        }

        # Require EOL, macro line continuation, or whitespace after ";".
        # Allow "for (;;)" as an exception.
        if ($data =~ /;[^	 \\\n;)]/) {
            print "Invalid character after semicolon:\n";
            print "$file:$.: $line";
            $ret = 1;
        }

        # Require EOL, space, or enum/struct end after comma.
        if ($data =~ /,[^ \\\n)}]/) {
            print "Invalid character after comma:\n";
            print "$file:$.: $line";
            $ret = 1;
        }

        # Require spaces around assignment '=', compounds and '=='
        if ($data =~ /[^ ]\b[!<>&|\-+*\/%\^=]?=/ ||
            $data =~ /=[^= \\\n]/) {
            print "Spacing around '=' or '==':\n";
            print "$file:$.: $line";
            $ret = 1;
        }
    }
    close FILE;
}

exit $ret;