1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
|
# $Id: Person.pm,v 1.3 2004/05/08 13:20:58 btrott Exp $
package XML::Atom::Person;
use strict;
use XML::Atom;
use base qw( XML::Atom::ErrorHandler );
use XML::Atom::Util qw( first );
use constant NS => 'http://purl.org/atom/ns#';
sub new {
my $class = shift;
my $person = bless {}, $class;
$person->init(@_) or return $class->error($person->errstr);
$person;
}
sub init {
my $person = shift;
my %param = @_;
my $elem;
unless ($elem = $param{Elem}) {
if (LIBXML) {
my $doc = XML::LibXML::Document->createDocument('1.0', 'utf-8');
$elem = $doc->createElementNS(NS, 'author'); ## xxx
$doc->setDocumentElement($elem);
} else {
$elem = XML::XPath::Node::Element->new('author'); ## xxx
my $ns = XML::XPath::Node::Namespace->new('#default' => NS);
$elem->appendNamespace($ns);
}
}
$person->{elem} = $elem;
$person;
}
sub elem { $_[0]->{elem} }
sub get {
my $person = shift;
my($name) = @_;
my $node = first($person->elem, NS, $name) or return;
my $val = LIBXML ? $node->textContent : $node->string_value;
if ($] >= 5.008) {
require Encode;
Encode::_utf8_off($val);
}
$val;
}
sub set {
my $person = shift;
my($name, $val) = @_;
my $elem;
unless ($elem = first($person->elem, NS, $name)) {
if (LIBXML) {
$elem = XML::LibXML::Element->new($name);
$elem->setNamespace(NS);
} else {
$elem = XML::XPath::Node::Element->new($name);
my $ns = XML::XPath::Node::Namespace->new('#default' => NS);
$elem->appendNamespace($ns);
}
$person->elem->appendChild($elem);
}
if (LIBXML) {
$elem->removeChildNodes;
$elem->appendChild(XML::LibXML::Text->new($val));
} else {
$elem->removeChild($_) for $elem->getChildNodes;
$elem->appendChild(XML::XPath::Node::Text->new($val));
}
$val;
}
sub as_xml {
my $person = shift;
if (LIBXML) {
my $doc = XML::LibXML::Document->new('1.0', 'utf-8');
$doc->setDocumentElement($person->elem);
return $doc->toString(1);
} else {
return '<?xml version="1.0" encoding="utf-8"?>' . "\n" .
$person->elem->toString;
}
}
sub DESTROY { }
use vars qw( $AUTOLOAD );
sub AUTOLOAD {
(my $var = $AUTOLOAD) =~ s!.+::!!;
no strict 'refs';
*$AUTOLOAD = sub {
@_ > 1 ? $_[0]->set($var, @_[1..$#_]) : $_[0]->get($var)
};
goto &$AUTOLOAD;
}
1;
__END__
=head1 NAME
XML::Atom::Person - Author or contributor object
=head1 SYNOPSIS
my $author = XML::Atom::Person->new;
$author->email('foo@example.com');
$author->name('Foo Bar');
$entry->author($author);
=head1 DESCRIPTION
I<XML::Atom::Person> represents an author or contributor element in an
Atom feed or entry.
=cut
|
