File: ps-to-png.scm

package info (click to toggle)
lilypond 2.19.83-1~exp1
  • links: PTS, VCS
  • area: main
  • in suites: experimental
  • size: 76,396 kB
  • sloc: cpp: 79,385; ansic: 75,071; lisp: 59,263; xml: 31,196; python: 22,406; sh: 8,159; yacc: 3,872; perl: 3,507; asm: 1,587; lex: 1,408; makefile: 1,048; tcl: 457; awk: 199; php: 53; csh: 50
file content (177 lines) | stat: -rw-r--r-- 6,332 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
;;;; This file is part of LilyPond, the GNU music typesetter.
;;;;
;;;; Copyright (C) 2005--2015 Jan Nieuwenhuizen <janneke@gnu.org>
;;;;
;;;; LilyPond is free software: you can redistribute it and/or modify
;;;; it under the terms of the GNU General Public License as published by
;;;; the Free Software Foundation, either version 3 of the License, or
;;;; (at your option) any later version.
;;;;
;;;; LilyPond is distributed in the hope that it will be useful,
;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;;; GNU General Public License for more details.
;;;;
;;;; You should have received a copy of the GNU General Public License
;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.

(define-module (scm ps-to-png))

(use-modules
 (ice-9 optargs)
 (ice-9 regex)
 (ice-9 rw)
 (srfi srfi-1)
 (srfi srfi-13)
 (srfi srfi-14)
 (lily)
 )

(define (re-sub re sub string)
  (regexp-substitute/global #f re string 'pre sub 'post))

(define-public (gulp-file file-name . max-size)
  (ly:gulp-file file-name (if (pair? max-size) (car max-size))))

(define (search-pngtopam)
  (search-executable
   (if (eq? PLATFORM 'windows)
       '("pngtopam.exe" "pngtopnm.exe")
       '("pngtopam" "pngtopnm"))))

(define (search-pamscale)
  (search-executable
   (if (eq? PLATFORM 'windows)
       '("pamscale.exe" "pnmscale.exe")
       '("pamscale" "pnmscale"))))

(define (search-pnmtopng)
  (search-executable
   (if (eq? PLATFORM 'windows)
       '("pnmtopng.exe")
       '("pnmtopng"))))

(define (scale-down-image factor file)
  (let* ((port-tmp1 (make-tmpfile))
         (tmp1-name (port-filename port-tmp1))
         (port-tmp2 (make-tmpfile))
         (tmp2-name (port-filename port-tmp2))
         ;; Netpbm commands (pngtopnm, pnmscale, pnmtopng)
         ;; outputs only standard output instead of a file.
         ;; So we need pipe and redirection.
         ;; However, ly:system can't handle them.
         ;; Therefore, we use ly:system-with-shell.
         (cmd
          (ly:format
           "~a \"~a\" | ~a -reduce ~a | ~a -compression 9 > \"~a\""
           (search-pngtopam) tmp1-name
           (search-pamscale) factor
           (search-pnmtopng)
           tmp2-name)))

    (close-port port-tmp1)
    (close-port port-tmp2)
    (ly:debug (_ "Copying `~a' to `~a'...") file tmp1-name)
    (copy-binary-file file tmp1-name)
    (ly:system-with-shell cmd)
    (ly:debug (_ "Copying `~a' to `~a'...") tmp2-name file)
    (copy-binary-file tmp2-name file)
    (ly:debug (_ "Deleting `~a'...") tmp1-name)
    (delete-file tmp1-name)
    (ly:debug (_ "Deleting `~a'...") tmp2-name)
    (delete-file tmp2-name)))

(define-public (ps-page-count ps-name)
  (let* ((byte-count 10240)
         (header (gulp-file ps-name byte-count))
         (first-null (string-index header #\nul))
         (match (string-match "%%Pages: ([0-9]+)"
                              (if (number? first-null)
                                  (substring header 0 first-null)
                                  header))))
    (if match (string->number (match:substring match 1)) 0)))

(define-public (make-ps-images base-name tmp-name is-eps . rest)
  (let-keywords*
   rest #f
   ((resolution 90)
    (page-width  100)
    (page-height 100)
    (rename-page-1 #f)
    (be-verbose (ly:get-option 'verbose))
    (pixmap-format 'png16m)
    (anti-alias-factor 1))

   (let* ((format-str (format #f "~a" pixmap-format))
          (extension (cond
                      ((string-contains format-str "png") "png")
                      ((string-contains format-str "jpg") "jpeg")
                      ((string-contains format-str "jpeg") "jpeg")
                      (else
                       (ly:error "Unknown pixmap format ~a" pixmap-format))))
          (png1 (format #f "~a.~a" base-name extension))
          (pngn (format #f "~a-page%d.~a" base-name extension))
          (page-count (ps-page-count tmp-name))
          (multi-page? (> page-count 1))

          ;; Escape `%' (except `page%d') for ghostscript
          (base-name-gs (string-join
                         (string-split base-name #\%)
                         "%%"))
          (png1-gs (format #f "~a.~a" base-name-gs extension))
          (pngn-gs (format #f "~a-page%d.~a" base-name-gs extension))
          (output-file (if multi-page? pngn-gs png1-gs))

          (*unspecified* (if #f #f))
          (cmd
           (remove (lambda (x) (eq? x *unspecified*))
                   (list
                    (search-gs)
                    (if (ly:get-option 'verbose) *unspecified* "-q")
                    (if (or (ly:get-option 'gs-load-fonts)
                            (ly:get-option 'gs-load-lily-fonts)
                            (eq? PLATFORM 'windows))
                        "-dNOSAFER"
                        "-dSAFER")

                    (if is-eps
                        "-dEPSCrop"
                        (ly:format "-dDEVICEWIDTHPOINTS=~$" page-width))
                    (if is-eps
                        *unspecified*
                        (ly:format "-dDEVICEHEIGHTPOINTS=~$" page-height))
                    "-dGraphicsAlphaBits=4"
                    "-q"
                    "-dTextAlphaBits=4"
                    "-dNOPAUSE"
                    "-dBATCH"
                    (ly:format "-sDEVICE=~a" pixmap-format)
                    "-dAutoRotatePages=/None"
                    "-dPrinted=false"
                    (string-append "-sOutputFile=" output-file)
                    (ly:format "-r~a" (* anti-alias-factor resolution))
                    (string-append "-f" tmp-name))))
          (files '()))

     (ly:system cmd)

     (set! files
           (if multi-page?
               (map
                (lambda (n)
                  (format #f "~a-page~a.png" base-name (1+ n)))
                (iota page-count))
               (list (format #f "~a.png" base-name))))

     (if (and rename-page-1 multi-page?)
         (begin
           (rename-file (re-sub "%d" "1" pngn) png1)
           (set! files
                 (cons png1
                       (cdr files)))
           ))

     (if (not (= 1 anti-alias-factor))
         (for-each
          (lambda (f) (scale-down-image anti-alias-factor f)) files))
     files)))