File: gen_decision_forest.gni

package info (click to toggle)
llvm-toolchain-14 1%3A14.0.6-12
  • links: PTS, VCS
  • area: main
  • in suites: bookworm
  • size: 1,496,180 kB
  • sloc: cpp: 5,593,972; ansic: 986,872; asm: 585,869; python: 184,223; objc: 72,530; lisp: 31,119; f90: 27,793; javascript: 9,780; pascal: 9,762; sh: 9,482; perl: 7,468; ml: 5,432; awk: 3,523; makefile: 2,538; xml: 953; cs: 573; fortran: 567
file content (46 lines) | stat: -rw-r--r-- 1,070 bytes parent folder | download | duplicates (19) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
 
template("gen_decision_forest") {
  model = invoker.model
  filename = invoker.filename
  cpp_class = invoker.cpp_class
  if (defined(invoker.deps)) {
    extra_deps = invoker.deps
  } else {
    extra_deps = []
  }

  action("${target_name}Cpp") {
    script = "//clang-tools-extra/clangd/quality/CompletionModelCodegen.py"
    outputs = [
      "$target_gen_dir/$filename.cpp",
      "$target_gen_dir/$filename.h",
    ]
    inputs = [
      "$model/features.json",
      "$model/forest.json",
    ]
    args = [
      "--model",
      rebase_path(model, root_build_dir),
      "--output_dir",
      rebase_path(target_gen_dir, root_build_dir),
      "--filename",
      filename,
      "--cpp_class",
      cpp_class,
    ]
  }

  config("${target_name}Config") {
    cflags = [ "-Wno-unused-label" ]
  }

  source_set(target_name) {
    configs += [
      "//llvm/utils/gn/build:clang_code",
      ":${target_name}Config",
    ]
    deps = [ ":${target_name}Cpp" ] + extra_deps
    include_dirs = [ "." ]
    sources = get_target_outputs(":${target_name}Cpp")
  }
}