File: BUILD.gn

package info (click to toggle)
llvm-toolchain-15 1%3A15.0.6-4
  • links: PTS, VCS
  • area: main
  • in suites: bookworm
  • size: 1,554,644 kB
  • sloc: cpp: 5,922,452; ansic: 1,012,136; asm: 674,362; python: 191,568; objc: 73,855; f90: 42,327; lisp: 31,913; pascal: 11,973; javascript: 10,144; sh: 9,421; perl: 7,447; ml: 5,527; awk: 3,523; makefile: 2,520; xml: 885; cs: 573; fortran: 567
file content (39 lines) | stat: -rw-r--r-- 812 bytes parent folder | download 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
import("//llvm/utils/gn/build/compiled_action.gni")

template("gen") {
  compiled_action(target_name) {
    tool = "//clang-tools-extra/pseudo/gen:clang-pseudo-gen"
    inputs = [ "../lib/cxx/cxx.bnf" ]
    outputs = [ "$target_gen_dir/$target_name" ]
    args = [
      "--grammar",
      rebase_path(inputs[0], root_build_dir),
      "-o",
      rebase_path(outputs[0], root_build_dir),
      invoker.flag,
    ]
  }
}

gen("CXXSymbols.inc") {
  flag = "--emit-symbol-list"
}

gen("CXXBNF.inc") {
  flag = "--emit-grammar-content"
}

config("cxx_gen_config") {
  visibility = [ ":cxx_gen" ]
  include_dirs = [ target_gen_dir ]
}

group("cxx_gen") {
  deps = [
    ":CXXSymbols.inc",
    ":CXXBNF.inc",
  ]

  # Let targets depending on this find the generated files.
  public_configs = [ ":cxx_gen_config" ]
}