File: gen_decision_forest.gni

package info (click to toggle)
llvm-toolchain-19 1%3A19.1.7-3
  • links: PTS, VCS
  • area: main
  • in suites: forky, sid, trixie
  • size: 1,998,520 kB
  • sloc: cpp: 6,951,680; ansic: 1,486,157; asm: 913,598; python: 232,024; f90: 80,126; objc: 75,281; lisp: 37,276; pascal: 16,990; sh: 10,009; ml: 5,058; perl: 4,724; awk: 3,523; makefile: 3,167; javascript: 2,504; xml: 892; fortran: 664; cs: 573
file content (46 lines) | stat: -rw-r--r-- 1,070 bytes parent folder | download | duplicates (19)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
template("gen_decision_forest") {
  model = invoker.model
  filename = invoker.filename
  cpp_class = invoker.cpp_class
  if (defined(invoker.deps)) {
    extra_deps = invoker.deps
  } else {
    extra_deps = []
  }

  action("${target_name}Cpp") {
    script = "//clang-tools-extra/clangd/quality/CompletionModelCodegen.py"
    outputs = [
      "$target_gen_dir/$filename.cpp",
      "$target_gen_dir/$filename.h",
    ]
    inputs = [
      "$model/features.json",
      "$model/forest.json",
    ]
    args = [
      "--model",
      rebase_path(model, root_build_dir),
      "--output_dir",
      rebase_path(target_gen_dir, root_build_dir),
      "--filename",
      filename,
      "--cpp_class",
      cpp_class,
    ]
  }

  config("${target_name}Config") {
    cflags = [ "-Wno-unused-label" ]
  }

  source_set(target_name) {
    configs += [
      "//llvm/utils/gn/build:clang_code",
      ":${target_name}Config",
    ]
    deps = [ ":${target_name}Cpp" ] + extra_deps
    include_dirs = [ "." ]
    sources = get_target_outputs(":${target_name}Cpp")
  }
}