1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
-*
Copyright 2020, Luigi Ferraro, Federico Galetto,
Francesca Gandini, Hang Huang, Matthew Mastroeni, Xianglong Ni.
You may redistribute this file under the terms of the GNU General Public
License as published by the Free Software Foundation, either version 2 of
the License, or any later version.
*-
-------------------------------------------
--- LinearlyReductiveAction methods -------
-------------------------------------------
LinearlyReductiveAction = new Type of GroupAction
linearlyReductiveAction = method()
linearlyReductiveAction (Ideal, Matrix, PolynomialRing) :=
linearlyReductiveAction (Ideal, Matrix, QuotientRing) := LinearlyReductiveAction => (A, M, Q) -> (
R := ambient Q;
if not isField coefficientRing R then (error "linearlyReductiveAction: Expected the third argument to be a polynomial ring over a field.");
if (numColumns M =!= numRows M) or (numRows M =!= #(gens R)) then (error "linearlyReductiveAction: Matrix size does not match polynomial ring.");
if coefficientRing ring A =!= coefficientRing R then (error "linearlyReductiveAction: Group and polynomial ring not defined over same field.");
new LinearlyReductiveAction from {
cache => new CacheTable,
(symbol groupIdeal) => A,
(symbol actionMatrix) => M,
(symbol ring) => Q
}
)
-------------------------------------------
net LinearlyReductiveAction := V -> (
stack {(net V.ring)|" <- "|(net ring V.groupIdeal)|"/"|(net V.groupIdeal)|" via ",
"", net V.actionMatrix}
)
actionMatrix = method()
actionMatrix LinearlyReductiveAction := Matrix => V -> V.actionMatrix
groupIdeal = method()
groupIdeal LinearlyReductiveAction := Ideal => V -> V.groupIdeal
---------------------------------------------
hilbertIdeal = method(Options => {
DegreeLimit => {},
SubringLimit => infinity
})
hilbertIdeal LinearlyReductiveAction := Ideal => opts -> V -> (
if opts.DegreeLimit === {} and opts.SubringLimit === infinity and V.cache#?hilbertIdeal then (
return V.cache#hilbertIdeal;
);
A := groupIdeal V;
M := actionMatrix V;
R := ambient ring V;
U := ideal ring V;
if (numColumns M =!= numRows M) or (numRows M =!= #(gens R)) then print "Matrix size does not match polynomial ring";
n := #(gens R);
K := coefficientRing(R);
l := #(gens ring M);
x := local x, y := local y, z := local z;
S := K[z_1..z_l, x_1..x_n, y_1..y_n, MonomialOrder=>Eliminate l];
M' := sub(M, apply(l, i -> (ring M)_i => z_(i+1)));
A' := sub(A, apply(l, i -> (ring M)_i => z_(i+1)));
Ux' := sub(U, apply(n, i -> R_i => x_(i+1)));
Uy' := sub(U, apply(n, i -> R_i => y_(i+1)));
J' := apply(n, i -> y_(i+1) - sum(n, j -> M'_(j,i) * x_(j+1)));
J := A' + ideal(J') + Ux' + Uy';
if opts.DegreeLimit === {} and opts.SubringLimit === infinity then (
I := eliminate(apply(l, i -> z_(i+1)),J);
) else (
I = ideal selectInSubring(1,
gens gb(J,DegreeLimit=>opts.DegreeLimit,SubringLimit=>opts.SubringLimit)
);
);
II := sub(I, apply(n, i -> y_(i+1) => 0));
II = trim(sub(II, join(apply(n, i -> x_(i+1) => (ring V)_i),apply(n, i -> y_(i+1) => 0), apply(l, i -> z_(i+1) => 0))));
if opts.DegreeLimit === {} and opts.SubringLimit === infinity then (
V.cache#hilbertIdeal = II;
);
return II;
)
|
