File: man-arg-systemdsystemunitdir.m4

package info (click to toggle)
man-db 2.13.1-1
  • links: PTS, VCS
  • area: main
  • in suites: trixie
  • size: 23,332 kB
  • sloc: ansic: 82,993; sh: 7,868; lex: 1,555; makefile: 970; perl: 141; sed: 16
file content (24 lines) | stat: -rw-r--r-- 928 bytes parent folder | download | duplicates (3)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
# man-arg-systemdsystemunitdir.m4 serial 3
dnl MAN_ARG_SYSTEMDSYSTEMUNITDIR
dnl Add a --with-systemdsystemunitdir option.

AC_DEFUN([MAN_ARG_SYSTEMDSYSTEMUNITDIR],
[
AC_REQUIRE([AC_CANONICAL_HOST])
AC_ARG_WITH([systemdsystemunitdir],
[AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files (disable with "no")])],
	[], [dnl
	# The default is not prefix-sensitive, since systemd's prefix is not
	# necessarily the same as man-db's.
	case $host_os in
	linux*)
		m4_pushdef([AC_ARG_VAR])dnl No need for precious variable handling.
		PKG_CHECK_VAR([with_systemdsystemunitdir], [systemd], [systemdsystemunitdir],
			      [], [with_systemdsystemunitdir=/lib/systemd/system])
		m4_popdef([AC_ARG_VAR])
		;;
	*)	with_systemdsystemunitdir=no ;;
	esac])
AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
AM_CONDITIONAL([INSTALL_SYSTEMD_TIMER], [test "$with_systemdsystemunitdir" != "no"])
])