1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101
|
title(exp):=block(clearscreen(),disp(dpart(exp)))$
(title("A CLASSICAL TEXTBOOK EXAMPLE OF DIFFERENTIATION"))$
X^X^X;
DIFF(%,X);
(title("DIFFERENTIATION OF A NESTED FUNCTION"))$
ERF(TAN(ACOS(LOG(X))));
DIFF(%,X);
title("EXPANDING AND FACTORIZING A UNIVARIATE POLYNOMIAL")$
(X-1)*(2*X-1)*(3*X-1)^7;
EXPAND(%);
FACTOR(%);
title("FACTORIZATION OF CYCLOTOMIC POLYNOMIALS - WHICH FORM OF AN EXPRESSION IS MORE SIMPLE?")$
X^600-1;
FACTOR(%);
title("FACTORIZATION OF A MULTIVARIATE POLYNOMIAL")$
(Y^3-X^2)^4*(X+Y+Z)^2;
EXPAND(%);
FACTOR(%);
title(" ALGEBRAIC SIMPLIFICATION EXAMPLE")$
(SQRT(R^2+A^2)+A)*(SQRT(R^2+B^2)+B)/R^2
-(SQRT(R^2+B^2)+SQRT(R^2+A^2)+B+A)/(SQRT(R^2+B^2)+SQRT(R^2+A^2)-B-A);
RATSIMP(%);
title(" ALGEBRAIC SIMPLIFICATION EXAMPLE")$
(Z^5-Y*Z^4+X*Z^4-2*Y*Z^3-6*X*Z^3+2*Y^2*Z^2+4*X*Y*Z^2-6*X^2*Z^2+Y^2*Z+
6*X*Y*Z+9*X^2*Z-Y^3-5*X*Y^2-3*X^2*Y+9*X^3)/(-Z^2+Y+3*X)^2;
RATSIMP(%);
title("INTEGRATION OF A NON-TABULATED FUNCTION")$
1/(X^3+A*X^2+X);
INTEGRATE(%,X);
DIFF(%,X),RATSIMP;
title("LOGARITHMIC SUBCASE OF RISCH'S INTEGRATION ALGORITHM")$
(LOG(X)-1)/(LOG(X)^2-X^2);
INTEGRATE(%,X);
title("TAYLOR SERIES EXAMPLE")$
SIN(X+A*X^3);
TAYLOR(%,X,0,19);
title("TAYLOR SERIES EXAMPLE - PUISEUX")$
SQRT(LOG(1+X)+SIN(X));
TAYLOR(%,X,0,17);
title("MACSYMA to FORTRAN conversion - optimized routine not yet available")$
EXP:-GAMMA^5+DELTA*GAMMA^4+2*DELTA^2*GAMMA^3-ALPHA^3*GAMMA^3-3*ALPHA^2*GAMMA^3
-3*ALPHA*GAMMA^3-GAMMA^3-2*DELTA^3*GAMMA^2+3*ALPHA^3*DELTA*GAMMA^2
+9*ALPHA^2*DELTA*GAMMA^2+9*ALPHA*DELTA*GAMMA^2+3*DELTA*GAMMA^2
+ALPHA^2*GAMMA^2-2*ALPHA*GAMMA^2+GAMMA^2-DELTA^4*GAMMA-3*ALPHA^3*DELTA^2*GAMMA
-9*ALPHA^2*DELTA^2*GAMMA-9*ALPHA*DELTA^2*GAMMA-3*DELTA^2*GAMMA
+2*ALPHA^2*DELTA*GAMMA-4*ALPHA*DELTA*GAMMA+2*DELTA*GAMMA+DELTA^5
+ALPHA^3*DELTA^3+3*ALPHA^2*DELTA^3+3*ALPHA*DELTA^3+DELTA^3+ALPHA^2*DELTA^2
-2*ALPHA*DELTA^2+DELTA^2+ALPHA^5+ALPHA^4-2*ALPHA^3-2*ALPHA^2+ALPHA+1;
FORTRAN(%);
FACTORSUM(EXP);
FORTRAN(%);
title("BIGNUM ARITHMETIC AND ARBITRARY PRECISION FLOATING POINT ARITHMETIC")$
6427752177035961102167848369364650410088811975131171341205503;
%^5;
2535301200456458802993406410751;
%TH(3)/%;
SQRT(%PI),NUMER;
FPPREC:50;
BFLOAT(SQRT(%PI));
/* at the moment this runs pretty slowly but would be a nice example of bignums
title("LARGE NUMBERS - THE LARGEST KNOWN PRIME NUMBER")$
2^(44497)-1; */
title("VANDERMOND'S MATRIX")$
MAT1:MATRIX([1,X,X^2,X^3],[1,Y,Y^2,Y^3],[1,Z,Z^2,Z^3],[1,W,W^2,W^3]);
FACTOR(DETERMINANT(MAT1));
MINOR(MAT1,4,4);
%^^-1,FACTOR;
title("SOLVING ALGEBRAIC EQUATIONS")$
Q^2*X^2+P^2*Q*X-P*Q*X-P^3=0;
SOLVE(%,X);
title("APPLICATION OF CUBIC FORMULA")$
(BREAKUP:FALSE,EQ:4*X^3+A*X+10*B= 0);
H:SOLVE(EQ,X)$
FIRST_ROOT:FIRST(H);
SECOND_ROOT:PART(H,2);
THIRD_ROOT:LAST(H);
title("SOLUTION OF SET OF SIMULTANEOUS LINEAR EQUATIONS")$
[3*A+5*B+7*C+11*D+13*E=17*R,19*A+23*B+29*C+31*D+37*E=41*S,43*A+47*B+53*C+59*D+61*E=67*T,
71*A+73*B+79*C+83*D+89*E=97*X,101*A+103*B+107*C+109*D+113*E=127*Y];
SOLVE(%,[A,B,C,D,E]);
title("SOLUTION OF SET OF SIMULTANEOUS NON-LINEAR EQUATIONS")$
[X*Y*Z = 42,-Z+Y+X = -2,-3*Z+2*Y+3*X = -9];
SOLVE(%);
title("FINDING EIGENVALUES")$
MATRIX([0,6,-10,-8],[6,0,8,10],[-10,8,15*A,6],[-8,10,6,15*A]);
SOLVE(CHARPOLY(%,L),L);
title("TWO DIMENSIONAL PLOT")$
PLOTNUM:100$
PLOT(X*SIN(X^2),X,0,4,PLOT(X*SIN(X^2),X,0,4));
title("TWO DIMENSIONAL PARAMETRIC PLOT")$
PLOTNUM:400;
PARAMPLOT(S*SIN(S),S*COS(S),S,0,80,PARAMPLOT(S*SIN(S),S*COS(S),S,0,80));
title("THREE DIMENSIONAL CARTESIAN PLOT OF A BESSEL FUNCTION")$
PLOTNUM:20$
PLOT3D(J0(SQRT(X^2+Y^2)),X,-12,12,Y,-12,12,PLOT3D(J0(SQRT(X^2+Y^2)),X,-12,12,Y,-12,12));
title("THREE DIMENSIONAL POLAR PLOT OF THE SAME BESSEL FUNCTION")$
PLOT3D(J0(R),TH,0,2*%PI,R,0,12,POLAR,PLOT3D(J0(R),TH,0,2*%PI,R,0,12,POLAR));
title("THREE DIMENSIONAL PLOT OF X*EXP(-X^2-Y^2)")$
PLOT3D(X*EXP(-X^2-Y^2),X,-2,2,Y,-2,2,PLOT3D(X*EXP(-X^2-Y^2),X,-2,2,Y,-2,2));
|