1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
|
/*******************************************************************************
*
* McStas, neutron ray-tracing package
* Copyright 1997-2002, All rights reserved
* Risoe National Laboratory, Roskilde, Denmark
* Institut Laue Langevin, Grenoble, France
*
* %I
* Written by: Kim Lefmann
* Date: October 26, 2000
* Origin: Risoe
*
* A 2D Position-sensitive monitor. The shape is cylindrical with
* the axis vertical. The monitor covers the whole cylinder (360 degrees).
*
* %D
* An (n times m) pixel PSD monitor with cylinder shape,
* vertical axis, centered at (0,0,0).
*
* Example: PSDcyl_monitor(nr=20, ny=20, filename="Output.cyl", yheight=0.2, radius=0.1)
*
* %P
* INPUT PARAMETERS:
*
* yheight: [m] Height of detector
* radius: [m] Radius of detector
* nr: [1] Number of pixel (radial) columns
* ny: [1] Number of pixel rows
* thmin: [deg] Minimum angle covered/measured
* thmax: [deg] Maximum angle covered/measured
* filename: [string] Name of file in which to store the detector image
* restore_neutron: [1] If set, the monitor does not influence the neutron state
* nowritefile: [1] If set, monitor will skip writing to disk
*
* CALCULATED PARAMETERS:
*
* PSD_N: [] Array of neutron counts
* PSD_p: [] Array of neutron weight counts
* PSD_p2: [] Array of second moments
*
* %E
******************************************************************************/
DEFINE COMPONENT Cyl_monitor
SETTING PARAMETERS (int nr=20, string filename=0, yheight=10, radius=1, int restore_neutron=0,
thmin=-180, thmax=180, int nowritefile=0)
/* Neutron parameters: (x,y,z,vx,vy,vz,t,sx,sy,sz,p) */
DECLARE
%{
DArray1d PSD_N;
DArray1d PSD_p;
DArray1d PSD_p2;
%}
INITIALIZE
%{
PSD_N = create_darr1d(nr);
PSD_p = create_darr1d(nr);
PSD_p2 = create_darr1d(nr);
// Use instance name for monitor output if no input was given
if (!strcmp(filename,"\0")) sprintf(filename,"%s",NAME_CURRENT_COMP);
%}
TRACE
%{
int i, j;
double t0, t1, phi;
if(cylinder_intersect(&t0, &t1, x, y, z, vx, vy, vz, radius, yheight) == 1) {
if(t0<0) {
if(t1>0) {
PROP_DT(t1);
/* Calculate pixel */
if (fabs(y) <= yheight/2.0) {
phi=atan2(x,z)*RAD2DEG;
if (phi >= thmin && phi <= thmax) {
i=floor((nr) * (phi-thmin)/(thmax-thmin));
double p2 = p*p;
#pragma acc atomic
PSD_N[i] = PSD_N[i]+1;
#pragma acc atomic
PSD_p[i] = PSD_p[i]+p;
#pragma acc atomic
PSD_p2[i] = PSD_p2[i]+p2;
}
}
}
}
}
if (restore_neutron) {
RESTORE_NEUTRON(INDEX_CURRENT_COMP, x, y, z, vx, vy, vz, t, sx, sy, sz, p);
}
%}
SAVE
%{
if (!nowritefile) {
DETECTOR_OUT_1D(
"Cylindrical monitor",
"radial position [deg]",
"Intensity",
"Theta",
thmin, thmax, nr,
&PSD_N[0],&PSD_p[0],&PSD_p2[0],
filename);
}
%}
FINALLY
%{
destroy_darr1d(PSD_N);
destroy_darr1d(PSD_p);
destroy_darr1d(PSD_p2);
%}
MCDISPLAY
%{
circle("xz", 0, 0, 0, radius );
%}
END
|
