1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
|
/*******************************************************************************
*
* McStas, neutron ray-tracing package
* Copyright 1997-2002, All rights reserved
* Risoe National Laboratory, Roskilde, Denmark
* Institut Laue Langevin, Grenoble, France
*
* Component: PSD_monitor_psf
*
* %I
* Written by: Kim Lefmann, Linda Udby
* Date: Feb 3, 1998
* Updated: Oct 15, 2007 (with psf)
* Origin: Risoe
*
* Position-sensitive monitor.
*
* %D
* An (n times m) pixel PSD monitor. This component may also be used as a beam
* detector. Models 1/k behaviour and efficiency, based on user defined k0 and eff parameters.
*
* Example: PSD_monitor(xmin=-0.1, xmax=0.1, ymin=-0.1, ymax=0.1, nx=90, ny=90, filename="Output.psd")
*
* %P
* INPUT PARAMETERS:
*
* xmin: [m] Lower x bound of detector opening
* xmax: [m] Upper x bound of detector opening
* ymin: [m] Lower y bound of detector opening
* ymax: [m] Upper y bound of detector opening
* xwidth: [m] Width/diameter of detector (x). Overrides xmin, xmax
* yheight: [m] Height of detector (y). Overrides ymin, ymax
* nx: [1] Number of pixel columns
* ny: [1] Number of pixel rows
* filename: [string] Name of file in which to store the detector image
* restore_neutron: [1] If set, the monitor does not influence the neutron state
* psf: [m] Point spread function, ray (x,y) coordinate randomized by gaussion of sigma psf
* k0: [AA^-1] Numerator in k0/k weighting
* eff: [1] Detector efficiency
* nowritefile: [1] If set, monitor will skip writing to disk
*
* CALCULATED PARAMETERS:
*
* PSD_N: [] Array of neutron counts
* PSD_p: [] Array of neutron weight counts
* PSD_p2: [] Array of second moments
*
* %E
*******************************************************************************/
DEFINE COMPONENT PSD_monitor_psf_eff
SETTING PARAMETERS (int nx=90, int ny=90, string filename=0, xmin=0, xmax=0, ymin=0, ymax=0, int nowritefile=0,
xwidth=0, yheight=0, psf=0, k0=1, eff=1, int restore_neutron=0)
DECLARE
%{
DArray2d PSD_N;
DArray2d PSD_p;
DArray2d PSD_p2;
double weight;
%}
INITIALIZE
%{
if (xwidth > 0) { xmax = xwidth/2; xmin = -xmax; }
if (yheight > 0) { ymax = yheight/2; ymin = -ymax; }
if ((xmin >= xmax) || (ymin >= ymax)) {
printf("PSD_monitor: %s: Null detection area !\n"
"ERROR (xwidth,yheight,xmin,xmax,ymin,ymax). Exiting",
NAME_CURRENT_COMP);
exit(0);
}
PSD_N = create_darr2d(nx, ny);
PSD_p = create_darr2d(nx, ny);
PSD_p2 = create_darr2d(nx, ny);
// Use instance name for monitor output if no input was given
if (!strcmp(filename,"\0")) sprintf(filename,"%s",NAME_CURRENT_COMP);
%}
TRACE
%{
int i,j;
double xp,yp;
PROP_Z0;
xp = x + psf*randnorm();
yp = y + psf*randnorm();
if (xp>xmin && xp<xmax && yp>ymin && yp<ymax)
{
weight = eff * k0 / (V2K*sqrt(vx*vx + vy*vy + vz*vz));
i = floor((xp - xmin)*nx/(xmax - xmin));
j = floor((yp - ymin)*ny/(ymax - ymin));
double p2w = p*p*weight*weight;
double pw = p*weight;
#pragma acc atomic
PSD_N[i][j] = PSD_N[i][j]+1;
#pragma acc atomic
PSD_p[i][j] = PSD_p[i][j]+pw;
#pragma acc atomic
PSD_p2[i][j] = PSD_p2[i][j]+p2w;
SCATTER;
}
if (restore_neutron) {
RESTORE_NEUTRON(INDEX_CURRENT_COMP, x, y, z, vx, vy, vz, t, sx, sy, sz, p);
}
%}
SAVE
%{
if (!nowritefile) {
DETECTOR_OUT_2D(
"PSD monitor",
"X position [cm]",
"Y position [cm]",
xmin*100.0, xmax*100.0, ymin*100.0, ymax*100.0,
nx, ny,
&PSD_N[0][0],&PSD_p[0][0],&PSD_p2[0][0],
filename);
}
%}
FINALLY
%{
destroy_darr2d(PSD_N);
destroy_darr2d(PSD_p);
destroy_darr2d(PSD_p2);
%}
MCDISPLAY
%{
multiline(5, (double)xmin, (double)ymin, 0.0,
(double)xmax, (double)ymin, 0.0,
(double)xmax, (double)ymax, 0.0,
(double)xmin, (double)ymax, 0.0,
(double)xmin, (double)ymin, 0.0);
%}
END
|
