File: makemake

package info (click to toggle)
mozilla-firefox 1.0.4-2sarge17
  • links: PTS
  • area: main
  • in suites: sarge
  • size: 255,356 kB
  • ctags: 267,207
  • sloc: cpp: 1,623,961; ansic: 792,828; xml: 85,380; makefile: 41,934; perl: 27,802; asm: 14,884; sh: 14,807; cs: 4,507; python: 4,398; java: 4,004; yacc: 1,380; lex: 409; pascal: 354; php: 244; csh: 132; objc: 73; ada: 44; sql: 4
file content (38 lines) | stat: -rwxr-xr-x 760 bytes parent folder | download | duplicates (9) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 
#!/bin/csh
# makemake: Dumb script to make Makefile from Makefile.in
#           (recursively, if -r is specified)
# Usage: makemake [-r]

if ($#argv == 0) then
   set makelist = (./Makefile.in)
else
   set makelist = (`find . -name Makefile.in -print`)
endif

foreach makefile ($makelist)
   set dir=${makefile:h}
   pushd $dir

   set wd=`pwd`
   echo $wd

   set top_srcdir = ""
   while (("$wd" != "") && (${wd:t} != "mozilla"))
      if ("$top_srcdir" == "") then
         set top_srcdir = ".."
      else
         set top_srcdir = "../$top_srcdir"
      endif
      set wd=${wd:h}
   end

   /bin/cp Makefile.in Makefile
   ex -s Makefile << /EOF
set nomagic
g%@srcdir@%s%@srcdir@%.%gp
g%@top_srcdir@%s%@top_srcdir@%${top_srcdir}%gp
wq
/EOF

   popd
end