1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
|
# Copyright (c) 2021 Maarten L. Hekkelman
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are met:
# 1. Redistributions of source code must retain the above copyright notice, this
# list of conditions and the following disclaimer
# 2. Redistributions in binary form must reproduce the above copyright notice,
# this list of conditions and the following disclaimer in the documentation
# and/or other materials provided with the distribution.
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
# WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
# DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR
# ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
# (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
# LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
# ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
# SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
cmake_minimum_required(VERSION 3.10)
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
# set the project name
project(mrc VERSION 1.3.16)
include(CTest)
include(CPM)
set(CXX_EXTENSIONS OFF)
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
if(MSVC)
# make msvc standards compliant...
add_compile_options(/permissive-)
endif()
if(WIN32)
# Windows is always little endian, right?
add_compile_definitions(LITTLE_ENDIAN)
# And we certainly don't need those pesky min/max macro's
add_compile_definitions(NOMINMAX)
# Find out the processor type for the target
if(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "AMD64")
set(COFF_TYPE "x64")
elseif(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "i386")
set(COFF_TYPE "x86")
elseif(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "ARM64")
set(COFF_TYPE "arm64")
else()
message(FATAL_ERROR "Unsupported or unknown processor type ${CMAKE_SYSTEM_PROCESSOR}")
endif()
set(COFF_SPEC "--coff=${COFF_TYPE}")
message(STATUS "Using COFF spec: ${COFF_SPEC}")
endif()
set(CPM_USE_LOCAL_PACKAGES ON)
CPMAddPackage("https://forge.hekkelman.net/maarten/mcfp.git@1.4.1")
include(VersionString)
write_version_header(${PROJECT_SOURCE_DIR}/src/)
add_custom_command(OUTPUT ${CMAKE_BINARY_DIR}/mrc-rsrc.obj
COMMAND $<TARGET_FILE:mrc-bootstrap> -o ${CMAKE_BINARY_DIR}/mrc-rsrc.obj ${PROJECT_SOURCE_DIR}/src/mrsrc.h ${COFF_SPEC}
DEPENDS ${PROJECT_SOURCE_DIR}/src/mrsrc.h mrc-bootstrap
)
add_executable(mrc ${PROJECT_SOURCE_DIR}/src/mrc.cpp ${CMAKE_BINARY_DIR}/mrc-rsrc.obj)
add_executable(mrc-bootstrap ${PROJECT_SOURCE_DIR}/src/mrc.cpp ${PROJECT_SOURCE_DIR}/src/dummy.cpp)
target_link_libraries(mrc mcfp::mcfp)
target_link_libraries(mrc-bootstrap mcfp::mcfp)
if(BUILD_TESTING)
CPMAddPackage("gh:catchorg/Catch2@3.5.0")
file(GLOB UNIT_TEST_RSRC LIST_DIRECTORIES true ${PROJECT_SOURCE_DIR}/rsrc/*)
add_custom_command(OUTPUT mrc-unit-test-rsrc.obj
COMMAND $<TARGET_FILE:mrc-bootstrap> -o mrc-unit-test-rsrc.obj ${UNIT_TEST_RSRC} ${COFF_SPEC}
DEPENDS ${UNIT_TEST_RSRC} mrc-bootstrap
)
add_executable(mrc-unit-test ${PROJECT_SOURCE_DIR}/src/mrc-unit-test.cpp ${CMAKE_BINARY_DIR}/mrc-unit-test-rsrc.obj)
if(TARGET Catch2::Catch2WithMain)
target_link_libraries(mrc-unit-test Catch2::Catch2WithMain)
add_test(NAME unit-test COMMAND $<TARGET_FILE:mrc-unit-test> WORKING_DIRECTORY .)
else()
message(WARNING "No Catch2::Catch2WithMain target, something is wrong")
endif()
endif()
install(TARGETS mrc)
if(WIN32)
install(FILES cmake/mrc-config.cmake DESTINATION cmake)
install(FILES doc/mrc-manual.pdf DESTINATION doc)
else()
install(FILES cmake/mrc-config.cmake DESTINATION share/mrc/cmake)
install(FILES doc/mrc.1 DESTINATION share/man/man1)
endif()
install(DIRECTORY examples DESTINATION share/doc/mrc PATTERN build EXCLUDE)
# add_subdirectory(examples/simple)
|
