File: rgbutils.pas

package info (click to toggle)
mricron 0.20140804.1~dfsg.1-3
  • links: PTS, VCS
  • area: main
  • in suites: bullseye, buster, sid
  • size: 13,508 kB
  • sloc: pascal: 114,876; sh: 49; makefile: 35
file content (184 lines) | stat: -rwxr-xr-x 4,014 bytes parent folder | download | duplicates (4)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
{
 /***************************************************************************
                                  RGBUtils.pas


 ***************************************************************************/

 *****************************************************************************
 *                                                                           *
 *  See the file COPYING.modifiedLGPL, included in this distribution,        *
 *  for details about the copyright.                                         *
 *                                                                           *
 *  This program is distributed in the hope that it will be useful,          *
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of           *
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.                     *
 *                                                                           *
 *****************************************************************************

  Author:  Tom Gregorovic (_tom_@centrum.cz)

  Abstract:
}
unit RGBUtils;

{$ifdef fpc}
  {$mode objfpc}{$H+}
{$endif} 

interface

uses
  Classes, SysUtils;
  
type
  TIntArray = array of Integer;
  
  function DivideTrunc(Src, Dest: Integer): TIntArray;
  function GetMidPoints(const A: TIntArray): TIntArray;
  function GetDifference(const A: TIntArray): TIntArray;
  
  procedure SwapInt(var A, B: Integer);
  procedure SwapPtr(var A, B: Pointer);
  procedure MinMax(var A, B: Integer);

  procedure SortRect(var X1, Y1, X2, Y2: Integer); overload;
  procedure SortRect(var R: TRect); overload;
  
  procedure ClipDimension(ClipMin, ClipMax: Integer;
    var DstPos, SrcPos, SrcSize: Integer);

  operator =(A, B: TPoint): Boolean;

implementation

(*
  DivideTrunc divides bigger value of Src and Dest into array of chunks.
  Length(Result) = Min(Src, Dest)
*)
function DivideTrunc(Src, Dest: Integer): TIntArray;
var
  I: Integer;
  VMax, VMin: Integer;
  P, D: Single;
begin
  if Dest > Src then
  begin
    VMax := Dest;
    VMin := Src;
  end
  else
  begin
    VMax := Src;
    VMin := Dest;
  end;
  SetLength(Result, VMin);

  P := 0;
  D := VMax / VMin;
  for I := 0 to High(Result) do
  begin
    Result[I] := Round(P + D) - Round(P);
    P := P + D;
  end;
end;

(*
  GetMidPoints returns array of absolute positions of the middle in each chunk.
*)
function GetMidPoints(const A: TIntArray): TIntArray;
var
  I, P, V: Integer;
begin
  SetLength(Result, Length(A));
  P := 0;
  for I := 0 to High(A) do
  begin
    V := A[I];
    Result[I] := V shr 1 + P;
    Inc(P, V);
  end;
end;

(*
  GetDifference returns array of diffences between positions.
*)
function GetDifference(const A: TIntArray): TIntArray;
var
  I, P: Integer;
begin
  SetLength(Result, Length(A));
  P := 0;
  for I := 0 to High(A) do
  begin
    Result[I] := A[I] - P;
    P := A[I];
  end;
end;

operator =(A, B: TPoint): Boolean;
begin
  Result := (A.X = B.X) and (A.Y = B.Y);
end;

procedure SwapInt(var A, B: Integer);
var
  C: Integer;
begin
  C := A;
  A := B;
  B := C;
end;

procedure SwapPtr(var A, B: Pointer);
var
  C: Pointer;
begin
  C := A;
  A := B;
  B := C;
end;

procedure MinMax(var A, B: Integer);
var
  T: Integer;
begin
  if A > B then
  begin
    T := A;
    A := B;
    B := T;
  end;
end;

procedure SortRect(var X1, Y1, X2, Y2: Integer);
begin
  MinMax(X1, X2);
  MinMax(Y1, Y2);
end;

procedure SortRect(var R: TRect);
begin
  MinMax(R.Left, R.Right);
  MinMax(R.Top, R.Bottom);
end;

procedure ClipDimension(ClipMin, ClipMax: Integer;
    var DstPos, SrcPos, SrcSize: Integer);
var
  C: Integer;
begin
  if ClipMin > DstPos then
  begin
    C := ClipMin - DstPos;
    Inc(SrcPos, C);
    Dec(SrcSize, C);
    DstPos := ClipMin;
  end;
  
  if ClipMax < DstPos + SrcSize then SrcSize := ClipMax - DstPos;
end;
  

end.